Microsoft Dynamics AX 2012 Class: ACTDMFDefinitionGroupCopy

Exportfile for AOT version 1.0 or later
Formatversion: 1

***Element: CLS

; Microsoft Dynamics AX Class: ACTDMFDefinitionGroupCopy descargados
; --------------------------------------------------------------------------------
  CLSVERSION 1

  CLASS #ACTDMFDefinitionGroupCopy
    PROPERTIES
      Name                #ACTDMFDefinitionGroupCopy
      Extends             #RunBase
      Origin              #{C566D936-9791-474E-8E02-7BAD0D239D78}
    ENDPROPERTIES

    METHODS
      SOURCE #classDeclaration
        #class ACTDMFDefinitionGroupCopy extends RunBase
        #{
        #    DialogField             dlgDMFDefinitionGroupNameDestination,
        #                            dlgReplaceValue1,
        #                            dlgReplaceValue2,
        #                            dlgDMFDefinitionGroupNameSource;
        #    str                     replaceValue1,
        #                            replaceValue2;
        #    DMFDefinitionGroup      dmfDefinitionGroup;
        #    DMFDefinationGroupName  dmfDefinitionGroupNameDestination,
        #                            dmfDefinitionGroupNameSource;
        #
        #    #define.CurrentVersion(1)
        #    #localmacro.CurrentList
        #        replaceValue1,
        #        replaceValue2,
        #        dmfDefinitionGroupNameSource
        #    #endmacro
        #}
      ENDSOURCE
      SOURCE #dialog
        #protected Object dialog()
        #{
        #    DialogRunbase ret;
        #
        #    ret = super();
        #
        #    if (this.parmDMFDefinitionGroup())
        #        ret.addText(this.parmDMFDefinitionGroup().DefinationGroupName);
        #    else
        #        dlgDMFDefinitionGroupNameDestination = ret.addFieldValue(extendedTypeStr(DMFDefinationGroupName), dmfDefinitionGroupNameDestination);
        #
        #    dlgReplaceValue1 = ret.addFieldValue(extendedTypeStr(String30), replaceValue1, "@SYS81169");
        #    dlgReplaceValue2 = ret.addFieldValue(extendedTypeStr(String30), replaceValue2, "@SYS68002");
        #    dlgDMFDefinitionGroupNameSource = ret.addFieldValue(extendedTypeStr(DMFDefinationGroupName), dmfDefinitionGroupNameSource, "@DMF106");
        #
        #    return ret;
        #}
      ENDSOURCE
      SOURCE #getFromDialog
        #public boolean getFromDialog()
        #{
        #    boolean ret;
        #
        #    ret = super();
        #    if (dlgDMFDefinitionGroupNameDestination != null)
        #    {
        #        dmfDefinitionGroupNameDestination  = dlgDMFDefinitionGroupNameDestination.value();
        #        dmfDefinitionGroup      = DMFDefinitionGroup::find(dmfDefinitionGroupNameDestination);
        #    }
        #    replaceValue1 = dlgReplaceValue1.value();
        #    replaceValue2 = dlgReplaceValue2.value();
        #    dmfDefinitionGroupNameSource = dlgDMFDefinitionGroupNameSource.value();
        #    return ret;
        #}
      ENDSOURCE
      SOURCE #pack
        #public container pack()
        #{
        #    return [#CurrentVersion,#CurrentList];
        #}
      ENDSOURCE
      SOURCE #parmDMFDefinitionGroup
        #DMFDefinitionGroup parmDMFDefinitionGroup(DMFDefinitionGroup _dmfDefinitionGroup = dmfDefinitionGroup)
        #{
        #    dmfDefinitionGroup = _dmfDefinitionGroup;
        #    return dmfDefinitionGroup;
        #}
      ENDSOURCE
      SOURCE #run
        #public void run()
        #{
        #    DMFDefinitionGroup          dmfDefinitionGroupSource = DMFDefinitionGroup::find(dmfDefinitionGroupNameSource);
        #    DMFDefinitionGroupEntity    dmfDefinitionGroupEntitySource,
        #                                dmfDefinitionGroupEntityDestination;
        #    Counter                     iCnt;
        #    boolean                     execption;
        #    super();
        #
        #    ttsBegin;
        #    while select dmfDefinitionGroupEntitySource where dmfDefinitionGroupEntitySource.DefinitionGroup == dmfDefinitionGroupSource.DefinationGroupName
        #    {
        #        dmfDefinitionGroupEntityDestination.clear();
        #        dmfDefinitionGroupEntityDestination.initValue();
        #        buf2Buf(dmfDefinitionGroupEntitySource, dmfDefinitionGroupEntityDestination);
        #        dmfDefinitionGroupEntityDestination.DefinitionGroup = dmfDefinitionGroupNameDestination;
        #
        #        // Replace
        #        if (strLen(replaceValue1) > 0)
        #        {
        #            if (strLen(dmfDefinitionGroupEntityDestination.QueryForODBC) > 0)
        #            {
        #                if (strscan(dmfDefinitionGroupEntityDestination.QueryForODBC, replaceValue1, 1, strLen(dmfDefinitionGroupEntityDestination.QueryForODBC)))
        #                {
        #                    dmfDefinitionGroupEntityDestination.QueryForODBC = strReplace(dmfDefinitionGroupEntityDestination.QueryForODBC, replaceValue1, replaceValue2);
        #                }
        #            }
        #            else if (strLen(dmfDefinitionGroupEntityDestination.SampleFilePath) > 0)
        #            {
        #                if (strscan(dmfDefinitionGroupEntityDestination.SampleFilePath, replaceValue1, 1, strLen(dmfDefinitionGroupEntityDestination.SampleFilePath)))
        #                {
        #                    dmfDefinitionGroupEntityDestination.SampleFilePath = strReplace(dmfDefinitionGroupEntityDestination.SampleFilePath, replaceValue1, replaceValue2);
        #                }
        #            }
        #        }
        #
        #        if (dmfDefinitionGroupEntityDestination.validateWrite())
        #        {
        #            dmfDefinitionGroupEntityDestination.insert();
        #            iCnt++;
        #
        #            // Validate, generate mapping
        #            if(DMFDataSource::find(dmfDefinitionGroupEntityDestination.Source).Type == DMFSourceType::ODBC)
        #            {
        #                execption = DMFDefinitionGroupEntity::validateStatus(dmfDefinitionGroupEntityDestination);
        #            }
        #            if(!execption)
        #            {
        #                DMFXmlGeneration::generateMapping(dmfDefinitionGroupEntityDestination);
        #            }
        #
        #            if (DMFHierarchyValidation::validateMandatoryFieldsMapping(dmfDefinitionGroupEntityDestination.Entity, dmfDefinitionGroupEntityDestination.DefinitionGroup))
        #            {
        #                throw error("@DMF899");
        #            }
        #
        #            if(DMFEntity::find(dmfDefinitionGroupEntityDestination.Entity).ParentEntityName !='')
        #            {
        #                DMFHierarchyValidation::compositEntityValidation(dmfDefinitionGroupEntityDestination);
        #            }
        #            DMFHierarchyValidation::definitionEntityValidation(dmfDefinitionGroupEntityDestination,tableName2id(tableStr(DMFDefinitionGroupEntity)),'',true);
        #        }
        #        else
        #        {
        #            setprefix(dmfDefinitionGroupEntitySource.DefinitionGroup + " - " + dmfDefinitionGroupEntitySource.Entity);
        #            throw error(strFmt("@SYS117281",tableId2PName(tableNum(DMFDefinitionGroup))));
        #        }
        #    }
        #    ttsCommit;
        #    info("@SYS60762" + " - " + int2str(iCnt) + " " + "@SYS25782");
        #}
      ENDSOURCE
      SOURCE #unpack
        #public boolean unpack(container packedClass)
        #{
        #    Version version = RunBase::getVersion(packedClass);
        #    switch (version)
        #    {
        #        case #CurrentVersion:
        #            [version,#CurrentList] = packedClass;
        #            break;
        #        default:
        #            return false;
        #    }
        #    return true;
        #}
      ENDSOURCE
      SOURCE #validate
        #public boolean validate(Object calledFrom = null)  // The object/form which calls the method
        #{
        #    boolean ret;
        #    DMFDefinitionGroupEntity dmfDefinitionGroupEntity;
        #
        #    ret = super(calledFrom);
        #
        #    if (strLen(dmfDefinitionGroupNameDestination) == 0)
        #        ret = ret && checkFailed(strFmt("@SYS84378",new SysDictType(extendedtypenum(DMFDefinationGroupName)).label()));
        #
        #    if (!dmfDefinitionGroup)
        #        ret = ret && checkFailed(strFmt("@SYS76877",tableId2PName(tableNum(DMFDefinitionGroup))));
        #
        #    if (strLen(dmfDefinitionGroupNameSource) == 0)
        #        ret = ret && checkFailed(strFmt("@SYS84378","@DMF106"));
        #
        #    if (!DMFDefinitionGroup::find(dmfDefinitionGroupNameSource))
        #        ret = ret && checkFailed(strFmt("@SYS76877",tableId2PName(tableNum(DMFDefinitionGroup))));
        #
        #    select firstOnly1 dmfDefinitionGroupEntity where dmfDefinitionGroupEntity.DefinitionGroup == dmfDefinitionGroupNameDestination;
        #    if (dmfDefinitionGroupEntity)
        #    {
        #        ret = ret && checkFailed("@SYS57612");
        #    }
        #
        #    return ret;
        #}
      ENDSOURCE
      SOURCE #main
        #static void main(Args args)
        #{
        #    ACTDMFDefinitionGroupCopy clz = new ACTDMFDefinitionGroupCopy();
        #    ;
        #
        #    if (args && args.dataset() == tablenum(DMFDefinitionGroup))
        #    {
        #        clz.parmDMFDefinitionGroup(args.record().dataSource());
        #    }
        #    if(clz.prompt())
        #    {
        #        clz.run();
        #    }
        #}
      ENDSOURCE
    ENDMETHODS
  ENDCLASS

***Element: END