//============================================================
//= Auto MVP Summoner
//===== By: =======================Modified By:=========
//= xMachina / Acetito      Emistry / Myzter
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: =====================================
//= eA SVN 5000+
//===== Additional Comments: =================================
//= v1.0 Testing Mode
//============================================================


prontera,147,164,5  script  MVP Attack  437,{
    if (getgmlevel() < 20) {
        mes "[ ^0065DFxMachina^000000 ]";
        if (!.Event) {
            mes "There is no MVP Attack Event now.";
        } else {
            mes "There is a MVP Attack Event on now!";
            mes "Location: ^ff0000" + $@Map$ + "^000000";
        }
        close;
    }
    set .@ItsOK,0;
    set .@SpecialMVP, $@SpecialMVP;
    set .@NormalMVP, $@NormalMVP;
    set .@Amount, $@Amount;
    set .@ItemID, $@ItemID;
    set .@Map$, $@Map$;
    while(!.@Configuring) {
        mes "[ ^0065DFxMachina^000000 ]";
        mes "Customizing MVP Attack Event:";
        mes "> MVP Item: " + (.@Amount?"^0000ff" + .@Amount:"^ff0000<Undefined>") + "^000000 x " + (getitemname(.@ItemID) == "null"?"^ff0000<Item>":"^0000ff" + getitemname(.@ItemID)) + "^000000";
        mes "> Location: " + (getstrlen(.@Map$)?"^0000ff" + .@Map$:"^ff0000<Undefined>") + "^000000";
        mes "> Special MVP: " + (.@SpecialMVP?"^0000ff" + .@SpecialMVP:"^ff0000<None>") + "^000000";
        mes "> Normal MVP: " + (.@NormalMVP?"^0000ff" + .@NormalMVP:"^ff0000<None>") + "^000000";
        mes "> Status: " + (.Event?"^ff44ffActive^000000":"^ff0000Inactive^000000");
        next;

        set .@ItsOK, getitemname(.@ItemID)!="null" && getstrlen(.@Map$) && getstrlen(.@Map$) < 24 && .@Amount && .@SpecialMVP && .@NormalMVP;

        if (.Event) {
            set .@Menu$, "^ff0000[·] Stop Event^000000:::::[x] ^ff0000Exit^000000";
        } else {
            set .@Menu$, (.Event?":":(.@ItsOK?"^0000ff[!] Start Event^000000:":":") + "- Set MVP Item:- Set Location:- Special MVP Count:- Normal MVP Count:[x] ^ff0000Exit^000000");
        }

        switch(select(.@Menu$)) {
            case 1:
                mes "[ ^0065DFxMachina^000000 ]";
                mes "Are you sure you want to " + (.Event?"Stop the Event":"Start the Event") + "?";
                next;
                set .@Configuring, select("No:Yes")-1;
                break;
            case 2:
                mes "[ ^0065DFxMachina^000000 ]";
                mes "What item to be given to MVP Killer ?";
                next;
                do {
                    message strcharinfo(0),"Enter a VALID itemID. Example 501 - Red Potion.";
                    input .@ItemID,501,32767;
                } while (getitemname(.@ItemID) == "null");
                mes "[ ^0065DFxMachina^000000 ]";
                mes "Input the Amount of ^0000ff" + getitemname(.@ItemID) + "^000000 to be Rewarded for Special MVP Killer.";
                next;
                input .@Amount,1,30000;
                break;
            case 3:
                mes "[ ^0065DFxMachina^000000 ]";
                mes "Which map would you like me to host this event?";
                mes "Input a ^FF0000VALID^000000 mapname.";
                next;
                do {
                    message strcharinfo(0),"Enter a VALID map. Example - izlude.";
                    input .@Map$;
                    monster .@Map$,0,0,".",1084,1,strnpcinfo(3)+"::OnNormalKill";
                    sleep2 100;
                    set .@MC, mobcount(.@Map$,strnpcinfo(3)+"::OnNormalKill");
                    killmonster .@Map$,strnpcinfo(3)+"::OnNormalKill";
                } while (.@MC<1);
                break;
            case 4:
                mes "[ ^0065DFxMachina^000000 ]";
                mes "How many ^FF0000Special^000000 MVP would you like me to summon?";
                next;
                input .@SpecialMVP;
                break;
            case 5:
                mes "[ ^0065DFxMachina^000000 ]";
                mes "How many ^FF0000Normal^000000 MVP would you like me to summon?";
                next;
                input .@NormalMVP;
                break;
            case 6:
                mes "[ ^0065DFxMachina^000000 ]";
                mes "See you later.";
                close;
        }
    }
    if (!.Event) {
        set .Event,1;
        set $@SpecialMVP, .@SpecialMVP;
        set $@NormalMVP, .@NormalMVP;
        set $@Amount, .@Amount;
        set $@ItemID, .@ItemID;
        set $@Map$, .@Map$;

        monster $@Map$,0,0,"--ja--",-3,$@SpecialMVP,strnpcinfo(3)+"::OnSpecialKill";
        monster $@Map$,0,0,"--ja--",-3,$@NormalMVP,strnpcinfo(3)+"::OnNormalKill";
        announce "Map Invasion Begin : " + $@SpecialMVP + " Special MVP has invaded in " + $@Map$ + ". Hurry Up..",bc_all,0x98FB98;
    } else {
        set .Event,0;
        announce "The MVP Attack Event is now over!",0,0x98FB98;
        killmonster $@Map$,"All";
    }
    mes "[ ^0065DFxMachina^000000 ]";
    mes (.Event?"Starting":"Stopping") + " the event now...";
    close;

OnClock0000:
OnClock0400:
OnClock0800:
OnClock1200:
OnClock1600:
OnClock2000:
    if (!.Event) {
        set .Event,1;
        monster $@Map$,0,0,"--ja--",-3,$@SpecialMVP,strnpcinfo(3)+"::OnSpecialKill";
        monster $@Map$,0,0,"--ja--",-3,$@NormalMVP,strnpcinfo(3)+"::OnNormalKill";
        announce "Map Invasion Begin : "+$@SpecialMVP+" Special MVP has invaded in " + $@Map$ + ". Hurry Up..",bc_all,0x98FB98;
    }

OnSpecialKill:
    set .@MobCnt, mobcount($@Map$,strnpcinfo(3)+"::OnSpecialKill");
    if (playerattached()) {
        if (!.@MobCnt) {
            announce $@Map$ + ": " + strcharinfo(0) + " has killed the last Special MVP",bc_all;
        } else {
            announce $@Map$ + ": " + strcharinfo(0) + " has killed 1 Special MVP and Gained Mystery Items - Remaining Special MVP: " + .@MobCnt,(!rand(3)?bc_all:bc_map);
        }
        getitem $@ItemID,$@Amount;
    }
    if (!.@MobCnt) {
        set .Event,0;
        killmonster $@Map$,"All";
        sleep 5000;
        mapannounce $@Map$, "The MVP Attack Event is now over!",bc_all,0x98FB98;
    }
    end;

OnNormalKill:
    if (playerattached()) dispbottom "You killed Normal MVP ( No Reward ).  Special MVP Left : "+mobcount($@Map$,strnpcinfo(3)+"::OnSpecialKill")+" .";
    end;
}