void calibrate_doCalibration()
{
  Serial.println("Doing calibration.");
  Serial.print("machineWidth: "); Serial.print(machineWidth);
  Serial.print(",stepsPerMM: "); Serial.print(stepsPerMM);
  Serial.print(",pageWidth: "); Serial.println(pageWidth);

  penlift_penUp();
  releaseMotors();
  motorA.enableOutputs();
  motorA.setCurrentPosition(0);

  // get a baseline from the endstop detector in case it's already at the stop
  byte endStopSignal = digitalRead(ENDSTOP_X_MIN);
  Serial.print("Reading X Endstop:");
  Serial.println(endStopSignal);

  motorA.setAcceleration(10000);
  if (endStopSignal == 0)
  {
    // it's already there! God what a mess!
    // what we'll do is wind forwards until it changes back
    Serial.println("Already at X Endstop, winding motorA forward");
    while (endStopSignal == 0)
    {
      motorA.move(stepMultiplier);
      while (motorA.distanceToGo() != 0)
        motorA.run();
      endStopSignal = digitalRead(ENDSTOP_X_MIN);
      Serial.println(endStopSignal);
    }
    Serial.println("motorA: at endstop, jumping a bit more");
    motorA.move(stepMultiplier * motorStepsPerRev);     // then jump a bit more - one rev
    while (motorA.distanceToGo() != 0)  motorA.run();
  }
  delay(400);

  Serial.println("motorA: wind backwards until we hit endstop X");
  // so wind backwards until hitting the stop.
  while (endStopSignal != 0)
  {
    motorA.move(-1);
    while (motorA.distanceToGo() != 0)
      motorA.run();
    endStopSignal = digitalRead(ENDSTOP_X_MIN);
  }
  Serial.print("motorA: at endstop X, saving position for motorA, resting at ");
  motorARestPoint = abs(motorA.currentPosition()) + (ENDSTOP_X_MIN_POSITION * stepsPerMM);
  Serial.println(motorARestPoint);
  Serial.print(", current position ");
  motorA.setCurrentPosition(ENDSTOP_X_MIN_POSITION * stepsPerMM);
  Serial.println(motorA.currentPosition());

  delay(1000);
  reportPosition();

  //Serial.print("moving motorA to ");
  //Serial.println(pageWidth/20);
  //motorA.moveTo(pageWidth/20);
  //motorA.setAcceleration(currentAcceleration);
  //while (motorA.distanceToGo() != 0)
  //  motorA.run();

  Serial.println("repeating process for motorB, moving motorA with it");
  // now do above for motorB
  motorB.enableOutputs();
  motorB.setCurrentPosition(0);
  motorB.setAcceleration(10000);

  // get a baseline from the endstop detector in case it's already at the stop
  endStopSignal = digitalRead(ENDSTOP_Y_MIN);

  Serial.println("motorB: wind backwards until we hit endstop Y, move motorA with it");
  motorA.setAcceleration(10000);  // make it slightly faster to allow for slack
  motorA.setSpeed(motorA.speed());
  motorB.setSpeed(motorB.speed()*.99);

  delay(400);
  while (endStopSignal != 0)
  {
    motorB.move(-1);
    motorA.move(1);
    while (motorB.distanceToGo() != 0) {
      motorB.run();
      motorA.run();
    }
    endStopSignal = digitalRead(ENDSTOP_Y_MIN);
  }
  Serial.print("motorB: at endstop Y, saving position for motorB, resting at ");
  motorBRestPoint = abs(motorB.currentPosition()) + (ENDSTOP_Y_MIN_POSITION * stepsPerMM);
  Serial.print(motorBRestPoint);
  Serial.print(", current position ");
  motorB.setCurrentPosition(ENDSTOP_Y_MIN_POSITION * stepsPerMM);
  Serial.println(motorB.currentPosition());

  reportPosition();

  // now return to the place where you started.
  Serial.print("move motorA and motorB to ");
  Serial.print(motorARestPoint);
  Serial.print(",");
  Serial.println(motorBRestPoint);

  motorB.setSpeed(motorA.speed());
  motorA.setMaxSpeed(currentMaxSpeed);
  motorB.setMaxSpeed(currentMaxSpeed);
  motorA.setAcceleration(currentAcceleration);
  motorB.setAcceleration(currentAcceleration);


  motorA.moveTo(motorARestPoint);
  motorB.moveTo(motorARestPoint);

  while (motorA.distanceToGo() != 0 || motorB.distanceToGo() != 0)
  {
    motorA.run();
    motorB.run();
  }

  Serial.println("motors at final position, calibrated");
  reportPosition();
  powerIsOn = true;
  isCalibrated = true;

}