/*ChoppedWood by goreae
 *This will automagically create recipes for provided wood and axes.
 *To add to the log list, simply put the log in the front of the logs array and the planks in the front of the planks array.
 *To add to the axe list, add the desired axe to the oreDict, ensuring the axes name has wildcard damage, like <exampleMod:shitAze:*>
*/

import minetweaker.item.IItemStack;
import minetweaker.item.IIngredient;

val logs = [<minecraft:log>, <minecraft:log:1>, <minecraft:log:2>, <minecraft:log:3>, <minecraft:log2>, <minecraft:log2:1>, <witchery:witchlog>, <witchery:witchlog:1>, <witchery:witchlog:2>, <erebus:logBaobab>, <erebus:logEucalyptus>, <erebus:logMahogany>, <erebus:logMossbark>, <erebus:logAsper>, <erebus:logCypress>, <erebus:logRotten>, <erebus:log_scorched>] as IItemStack[];
val plank = [<minecraft:planks>, <minecraft:planks:1>, <minecraft:planks:2>, <minecraft:planks:3>, <minecraft:planks:4>, <minecraft:planks:5>, <witchery:witchwood>, <witchery:witchwood:1>, <witchery:witchwood:2>, <erebus:planks>, <erebus:planks:1>, <erebus:planks:2>, <erebus:planks:3>, <erebus:planks:4>, <erebus:planks:5>, <erebus:planks:9>, <erebus:planks_scorched>] as IItemStack[];

val axe = <ore:axe>;
axe.add(<minecraft:wooden_axe:*>);
axe.add(<minecraft:stone_axe:*>);
axe.add(<minecraft:iron_axe:*>);
axe.add(<minecraft:golden_axe:*>);
axe.add(<minecraft:diamond_axe:*>);
axe.add(<Botania:manasteelAxe:*>);
axe.add(<Botania:elementiumAxe:*>);
axe.add(<EnderIO:item.darkSteel_axe:*>);
axe.add(<ThermalExpansion:tool.axeInvar:*>);
axe.add(<appliedenergistics2:item.ToolCertusQuartzAxe:*>);
axe.add(<appliedenergistics2:item.ToolNetherQuartzAxe:*>);
axe.add(<bluepower:ruby_axe:*>);
axe.add(<bluepower:sapphire_axe:*>);
axe.add(<bluepower:amethyst_axe:*>);
axe.add(<erebus:axeJade:*>);
axe.add(<Railcraft:tool.steel.axe:*>);

for i, log in logs {
        recipes.remove(plank[i]);
        recipes.addShapeless(plank[i]*4, [log, axe.transformDamage()]);
}