QuestionBot (by AzkarGames)

///////////////QuestionBot Filterscript//////////////////
//| Made by AzkarGames Reallife                       |//
//| Credits bitte nicht entfernen                     |//
/////////////////////////////////////////////////////////

#include <a_samp>
#define DIALOG_ASKBOT 20 // Dialog-Definition für die Inputbox (Wichtig: Kann sich mit dem Gamemode Schneiden. Unbedingt abgleichen!)
#define DIALOG_BOTANSWER 21 // Dialog-Definition für die möglichen Antworten (Wichtig: Kann sich ebenfalls schneiden!)

#define COLOR_BOT 0xFFC100FF

#define MAX_TOPICS 10 // Hier wird die maximale Anzahl an 'Themen' definiert

enum row_settings
{
	title[64],
	keywords[128],
	information[256]
}
new Bot_R_Info[MAX_TOPICS][row_settings];


stock CreateABotTopic(tnumber,ttitle[64],tkeywords[128],tinformation[256])
{
	if(!strlen(ttitle)) return print("Fehler: Es kann kein Thema ohne Titel erstellt werden."); //Fehlerausgabe falls kein Titel vorhanden ist
	if(!strlen(tkeywords)) return print("Fehler: Es Kann kein Thema ohne Schluesselwoerter erstellt werden."); //Fehlerausgabe falls kein Schlüsselwort vorhanden ist
	if(!strlen(tinformation)) return print("Fehler: Es kann kein Thema ohne Textwiedergabe erstellt werden."); //Fehlerausgabe falls keine Infos vorhanden sind
	Bot_R_Info[tnumber][title] = ttitle; // Zuordnung zum jeweiligen 'Topic' unter der Sparte 'title'
	Bot_R_Info[tnumber][keywords]= tkeywords; //Zuordnung zum jeweiligen 'Topic' unter der Sparte 'keywords'
	Bot_R_Info[tnumber][information] = tinformation; //Zuordnung zum jweiligen 'Topic' unter der Sparte 'information'
	new pInfo[512];
	format(pInfo,sizeof(pInfo),"Neues Thema erstellt. \n Titel: %s \n Schluesselwoerter: %s \n Infotext: %s",ttitle,tkeywords,tinformation); //Info für die Serverkonsole!
	print(pInfo);
	return 1;
}

public OnFilterScriptInit()
{
	print("\n--------------------------------------");
	print(" Bothilfe-Script by AzkarGames");
	print("--------------------------------------\n");

	CreateABotTopic(0,"Testnummer 0","finde mich","Dies ist das Thema mit der Nummer 0! Du hast mich gefunden."); // Erstellt den BotTopic mit der Nummer 0.
	CreateABotTopic(1,"Testnummer 1","finde mich auch","Dies ist das Thema mit der Nummer 1! Du hast mich gefunden."); //Erstellt den BotTopic mit der Nummer 1.
	return 1;
}

public OnFilterScriptExit()
{
	return 1;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
	if(dialogid == DIALOG_ASKBOT)
	{
	    if(response == 0) return 1;
	    if(!strlen(inputtext)) return SendClientMessage(playerid,COLOR_BOT,"Du musst ein Stichwort angeben");
	    new answer[1028];
	    for(new n = 0; n < MAX_TOPICS; n++)
	    {
	        if(strfind(Bot_R_Info[n][keywords],inputtext,true) != -1)
	        {
	            new add[512];
	            format(add,sizeof(add),"{FFC100}Ergebnis %d:{FFFFFF} \n Titel: %s \n Information: \n %s \n Stichpunkte: \n %s \n",n,Bot_R_Info[n][title],Bot_R_Info[n][information],Bot_R_Info[n][keywords]);
				format(answer,sizeof(answer),"%s \n %s",answer,add);
			}
	    }
	    if(!strlen(answer)) format(answer,sizeof(answer),"Kein Ergebnis gefunden");
	    ShowPlayerDialog(playerid,DIALOG_BOTANSWER,DIALOG_STYLE_MSGBOX,"Antworten",answer,"Ok","");
	}
	return 1;
}
public OnPlayerCommandText(playerid, cmdtext[])
{
    if(strcmp("/bothilfe",cmdtext, true, 10) == 0)
	{
	    ShowPlayerDialog(playerid,DIALOG_ASKBOT,DIALOG_STYLE_INPUT,"Hilfe-System","Gib bitte ein Stichwort ein!","Suchen","Abbrechen");
	    return 1;
	}
	return 0;
}