AETemplate_scrollField

global proc ShotOverrideNode_ShotOverrideTemplateNew(string $attr)
{
    scrollField -h 800 -nl 25
        -ec ("ShotOverrideNode_AE_UpdateOverrideText " + $attr)
        -kpc ("ShotOverrideNode_AE_UpdateOverrideText " + $attr)
        -cc ("ShotOverrideNode_AE_UpdateOverrideText " + $attr)
        ShotOverrideNode_AT_ShotOverrideText;
    ShotOverrideNode_ShotOverrideTemplateReplace $attr;
}

global proc ShotOverrideNode_ShotOverrideTemplateReplace(string $attr)
{
    string  $txt = `getAttr $attr`;
    $txt = `strip $txt`;
    scrollField -e -text $txt ShotOverrideNode_AT_ShotOverrideText;
    scrollField -e
        -ec ("ShotOverrideNode_AE_UpdateOverrideText " + $attr)
        -kpc ("ShotOverrideNode_AE_UpdateOverrideText " + $attr)
        -cc ("ShotOverrideNode_AE_UpdateOverrideText " + $attr)
        ShotOverrideNode_AT_ShotOverrideText;
}

global proc ShotOverrideNode_AE_UpdateOverrideText(string $attr)
{
    string $txt = `scrollField -q -tx ShotOverrideNode_AT_ShotOverrideText`;
    setAttr -type "string" $attr $txt;
}


global proc AEShotOverrideNodeTemplate ( string $nodeName )
{
    editorTemplate -beginScrollLayout;
        editorTemplate -beginLayout "ShotOverride" -collapse 0;
            editorTemplate -ccu "ShotOverrideNode_ShotOverrideTemplateNew"
                    "ShotOverrideNode_ShotOverrideTemplateReplace" "ShotOverride";

        editorTemplate -endLayout;
        editorTemplate -addExtraControls;
    editorTemplate -endScrollLayout;
}