LOGO - Silba 2012 - Zadatak Element :: Kristijan Burnik

to element :l :path
	(local "pozicija "putanja "spremnik)
	; promijenimo oblik putanje iz "|/a/b/c| u "|a/b/c/|
	make "path word (bf :path) "|/|

	; krecemo s praznim spremnikom
	make "spremnik "


	; ovdje biljezimo putanju "do sada"
	make "putanja "


	; jedan obilazak po putanji
	foreach :path [
		; slash nam je signal za praznjenje spremnika
		ifelse ? = "|/| [
			; pozicija u listi je zapisana u spremniku (bufferu)
			make "pozicija :spremnik

			; praznimo spremnik
			make "spremnik "

			; provjera: da li je moguce doci do trazenog elementa?
			ifelse  and (:pozicija > 0) (:pozicija <= (count :l) )  [
				; ako je, onda "ulazimo" u tu podlistu
				make "l item :pozicija :l
			][
				; inace je greska u pitanju: pa ju ispisujemo, skupa sa dosadašnjom putanjom
				pr ( se [element ne postoji] "|(| (word "|/| :putanja) "|)| )
				stop
			]
		][
			; ostale znakove lijepimo na spremnik (brojke, tj. slažemo poziciju)
			make "spremnik word :spremnik ?

		]
		; čitavo vrijeme pratimo putanju (prepisujemo sa izvora) radi
		make "putanja word :putanja ?
	]

	; vrati traženi element
	op :l

end