ArchLinux TrafficServer 3.2.5

# Maintainer: Galen Sampson <galen.sampson at gmail dot com>
# Contributor: David Roheim <david dot roheim at gmail dot com>

pkgname=('trafficserver')
pkgver=3.2.5
pkgrel=1
pkgdesc="Apache Traffic Server"
url="http://trafficserver.apache.org/"
license=('Apache')
arch=('i686' 'x86_64')
depends=('openssl' 'tcl' 'hwloc')
makedepends=('flex')

source=(
    http://apache.tradebit.com/pub/${pkgname}/${pkgname}-${pkgver}.tar.bz2
    trafficserver.tmpfiles
    config.layout.patch
    trafficserver.service.in.patch)

md5sums=(bc76c68589389a453e4e4967c42636d6
         fc8ab2b6d01e22fb376832fb13137db1
         9ca01c6833ebbde4644a255c8bf802ce
         74ba08091f580f8984eee8db0f7e4d27)

install=${pkgname}.install
changelog=${pkgname}.changelog

backup=(
    etc/${pkgname}/congestion.config
    etc/${pkgname}/logs_xml.config
    etc/${pkgname}/hosting.config
    etc/${pkgname}/parent.config
    etc/${pkgname}/records.config
    etc/${pkgname}/socks.config
    etc/${pkgname}/trafficserver-release
    etc/${pkgname}/splitdns.config
    etc/${pkgname}/vaddrs.config
    etc/${pkgname}/ae_ua.config
    etc/${pkgname}/cluster.config
    etc/${pkgname}/storage.config
    etc/${pkgname}/mgr.cnf
    etc/${pkgname}/volume.config
    etc/${pkgname}/plugin.db
    etc/${pkgname}/icp.config
    etc/${pkgname}/update.config
    etc/${pkgname}/remap.config
    etc/${pkgname}/ssl_multicert.config
    etc/${pkgname}/cache.config
    etc/${pkgname}/body_factory/default/access#ssl_forbidden
    etc/${pkgname}/body_factory/default/transcoding#unsupported
    etc/${pkgname}/body_factory/default/request#syntax_error
    etc/${pkgname}/body_factory/default/connect#failed_connect
    etc/${pkgname}/body_factory/default/default
    etc/${pkgname}/body_factory/default/response#bad_version
    etc/${pkgname}/body_factory/default/interception#no_host
    etc/${pkgname}/body_factory/default/cache#not_in_cache
    etc/${pkgname}/body_factory/default/response#bad_response
    etc/${pkgname}/body_factory/default/request#scheme_unsupported
    etc/${pkgname}/body_factory/default/connect#dns_failed
    etc/${pkgname}/body_factory/default/README
    etc/${pkgname}/body_factory/default/redirect#moved_temporarily
    etc/${pkgname}/body_factory/default/timeout#activity
    etc/${pkgname}/body_factory/default/timeout#inactivity
    etc/${pkgname}/body_factory/default/access#denied
    etc/${pkgname}/body_factory/default/cache#read_error
    etc/${pkgname}/body_factory/default/request#no_content_length
    etc/${pkgname}/body_factory/default/request#cycle_detected
    etc/${pkgname}/body_factory/default/access#proxy_auth_required
    etc/${pkgname}/body_factory/default/.body_factory_info
    etc/${pkgname}/body_factory/default/urlrouting#no_mapping
    etc/${pkgname}/body_factory/default/request#no_host
    etc/${pkgname}/body_factory/default/connect#hangup
    etc/${pkgname}/body_factory/default/congestion#retryAfter
    etc/${pkgname}/body_factory/default/access#redirect_url
    etc/${pkgname}/plugin.config
    etc/${pkgname}/stats.config.xml
    etc/${pkgname}/log_hosts.config
    etc/${pkgname}/ip_allow.config)

build() {
    cd ${pkgname}-${pkgver}
    patch -Np0 -u -i ../config.layout.patch
    patch -Np0 -u -i ../trafficserver.service.in.patch
    ./configure --with-user=tserver --enable-layout=Arch
    make
}

check() {
    cd ${srcdir}/${pkgname}-${pkgver}
    make check
}

package() {
    cd ${srcdir}/${pkgname}-${pkgver}
    make install DESTDIR=${pkgdir}

    # Remove libtool files
    rm -f ${pkgdir}/usr/lib/libtsmgmt.la
    rm -f ${pkgdir}/usr/lib/libtsutil.la
    rm -f ${pkgdir}/usr/lib/${pkgname}/regex_remap.la
    rm -f ${pkgdir}/usr/lib/${pkgname}/conf_remap.la
    rm -f ${pkgdir}/usr/lib/${pkgname}/stats_over_http.la
    rm -f ${pkgdir}/usr/lib/${pkgname}/header_filter.la

    rm -rf ${pkgdir}/run

    install -D -m 644 ${srcdir}/trafficserver.tmpfiles \
                      ${pkgdir}/usr/lib/tmpfiles.d/trafficserver.conf

    install -D -m 644 ${srcdir}/${pkgname}-${pkgver}/rc/${pkgname}.service \
                      ${pkgdir}/usr/lib/systemd/system/${pkgname}.service
}