Display latest Reuters Picture in ASCII

#! /usr/bin/perl -w
use strict;
use warnings;
use WebService::ReutersConnect qw/:demo/;
use Log::Log4perl qw/:easy/;
use Text::AAlib;
use Imager;
Log::Log4perl->easy_init($WARN);

my $reuters = WebService::ReutersConnect->new({ username => REUTERS_DEMOUSER,
                                                password => REUTERS_DEMOPASSWORD
                                              });
my ( $item )  = $reuters->fetch_search({ limit => 1, media_types => [ 'P' ], sort => 'date' });

## Load preview image
my $res = $reuters->user_agent->get($item->preview_url());
unless( $res->is_success() ){
  die $res->status_line();
}

## Build and scale image
my $bin_image = $res->content();
my $img = Imager->new( data => $bin_image , type => 'jpeg' ) || die Imager->errstr();
$img = $img->convert( preset => 'grey' );
$img = $img->scaleX(scalefactor => 2);
$img = $img->scale(scalefactor => 0.5);


## Build ASCII Version
my ($width, $height) = ($img->getwidth, $img->getheight);
my $aa = Text::AAlib->new( width  => $width, height => $height );
$aa->put_image(image => $img);

## Print ASCII Image
print $aa->render( dither => 0 ,
                   gamma => 1.83,
                   bright => 50,
                   contrast => 60,
                   color => 0
                 );

## And some info
print "\n    ".$item->date_created().' : '.$item->headline()." \n";
print "\n    ".$item->preview_url()."\n";