Shadow Curves shader

Shader "ShadowCurves"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.uv = v.uv;
                return o;
            }

            sampler2D _MainTex;
            float _factorScreen;

            float4 frag (v2f i) : SV_Target
            {
                float2 uv = i.uv;
                uv -= float2(0.5,0.5);
                uv.x *= _factorScreen;

                float dist,dist1,dist2,mask,l,final = 1.0;
                float s = 0.07;
                float amp,freq;
                uv.x-=_factorScreen;
                for(float f = -_factorScreen;f<_factorScreen;f+=s){
                    uv.x+=s;
                    freq = 5.0*exp(-20.0*(f*f));
                    amp = 0.12*exp(-10.0*(f*f));
                    dist = amp*pow(sin(freq*uv.y+2.0*_Time.y+100.0*sin(122434.0*f)),2.0)*exp(-5.0*uv.y*uv.y)-uv.x;
                    mask = 1.0-smoothstep(0.0,0.005,dist);

                    dist1 = abs(dist);
                    dist1 = smoothstep(0.003,0.005,dist1);

                    dist2 =abs(dist);
                    dist2 = smoothstep(0.0,0.03,dist2);
                    dist2 = lerp(0.7,1.0,dist2);
                    dist2 *= mask;

                    l = lerp(dist1,dist2,mask);
                    final=lerp(l,l*final,mask);
                }


                return float4(final,final,final,1.0);
            }
            ENDCG
        }
    }
}