# Contributor: Todd Musall
# Contributor: dront78 (Ivan)
# Maintainer: Victor Noel
pkgname=('heimdall')
pkgver=1.4.0
pkgrel=1
pkgdesc="Heimdall is a cross-platform open-source utility to flash firmware (aka ROMs) onto Samsung Galaxy S devices."
arch=('i686' 'x86_64')
url="http://www.glassechidna.com.au/products/heimdall/"
license=('MIT')
depends=('libusb' 'qt4')
optdepends=('android-udev: Udev rules to connect Android devices to your linux box')
makedepends=('gcc')
#source=("heimdall-${pkgver}.tar.gz::http://github.com/Benjamin-Dobell/Heimdall/tarball/v${pkgver}"
#source=("heimdall-${pkgver}.tar.gz::http://github.com/Benjamin-Dobell/Heimdall/tarball/e0e84b2f7a28bd188f104f51a845dc4ed8a9b7ea"
source=("heimdall-${pkgver}.tar.gz::http://github.com/Benjamin-Dobell/Heimdall/tarball/910ae1d1fed7b608239b344b6d92c9165a0b8d52"
        'heimdall.desktop')

build() {
  cd ${srcdir}/Benjamin-Dobell-Heimdall-*

  # Build libpit which is needed for compiling heimdall
  cd libpit/
  ./configure --prefix=/usr
  # Default makefile removes libpit.1.4.a which is needed by frontend
  #sed -i '/rm -f libpit-1.4.a/d' Makefile
  make

  # Build heimdall command line tool
  cd ../heimdall/

  ./configure --prefix=/usr
  make

  # Build heimdall GUI front end
  cd ../heimdall-frontend/

  env OUTPUTDIR="/usr/bin" qmake-qt4 heimdall-frontend.pro
  make
}

package() {
  cd ${srcdir}/Benjamin-Dobell-Heimdall-*

  # Install heimdall command line tool
  cd heimdall/

  # Prevent make install from trying to reload udev
  # We'll do this the Arch way at package install time
  mv Makefile Makefile.orig
  sed -e 's/sudo service udev restart/echo sudo service udev restart/' <Makefile.orig >Makefile

  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}/lib/"
#  install -m644 -D LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  # Install heimdall GUI front end
  cd ../heimdall-frontend
  # hack to place heimdall-frontend in /usr/bin
  sed -i 's|local\/||g' Makefile
  make INSTALL_ROOT="${pkgdir}/" install
  install -m644 -D "${srcdir}/heimdall.desktop" "${pkgdir}/usr/share/applications/heimdall.desktop"
}
md5sums=('72c203839571d9c4e4adf798cc89fe4c'
         '6c4de9e74c0d9e7ab4d50af21303b78a')