file-roller2

# Maintainer: Spyros Stathopoulos <foucault.online@gmail.com>
# Contributor: Alessio Sergi <asergi at archlinux dot us>

pkgname=file-roller2
_pkgname=file-roller
pkgver=2.32.2
pkgrel=3
pkgdesc="Archive manipulator for GNOME"
arch=('i686' 'x86_64')
url="http://www.gnome.org"
license=('GPL')
depends=('desktop-file-utils' 'gconf' 'gtk2' 'hicolor-icon-theme')
makedepends=('gnome-doc-utils' 'intltool')
optdepends=('arj: ARJ archiver'
            'p7zip: 7zip compression utility'
            'unace: extraction tool for ace archive format'
            'unrar: the RAR uncompression program'
            'unzip: unpacks .zip archives'
            'xz: managing LZMA and XZ compressed files'
            'zip: creates PKZIP-compatible .zip files')
provides=(${_pkgname})
conflicts=(${_pkgname})
options=('!libtool' '!emptydirs')
install=${pkgname}.install
source=(http://ftp.gnome.org/pub/gnome/sources/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.bz2)
sha256sums=('3ddbe4e4134eab4ff8e97789a1626aec6cbc588190f2f520850d0697037e5755')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  ./configure --prefix=/usr --sysconfdir=/etc \
              --libexecdir=/usr/lib/file-roller \
              --localstatedir=/var --disable-static \
              --disable-scrollkeeper \
              --disable-schemas-install \
              --disable-packagekit
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install

  install -d -m755 "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${_pkgname}.schemas" \
    --domain "${_pkgname}" "${pkgdir}"/etc/gconf/schemas/*.schemas
  rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas
}



######
file-roller2.install
######

pkgname=file-roller

post_install() {
  usr/sbin/gconfpkg --install ${pkgname}
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
  update-desktop-database -q
}

pre_upgrade() {
  pre_remove
}

post_upgrade() {
  post_install
}

pre_remove() {
  usr/sbin/gconfpkg --uninstall ${pkgname}
}

post_remove() {
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
  update-desktop-database -q
}