Gornik_Menu_v-2.1.5.txt

; Nazwa: Gornik_Menu_v-2.1.5.txt
; Autor: Janusz [Frisky]
;============ OPIS ==================
; UWAGA !!
; W przypadku innych wersji systemu niz Windows XP
; trzeba uruchamiac EasyUO jako administrator
;
; Skrypt Testowany na systemach Windows XP SP3 oraz Windows 7 SP1
;
; -------------------------------------------
; Wybierasz miasto z listy i rudy jakie maja byc wywalane
; ----
; Skrypt dziala tylko na jednego juczniaka !!
; Kwity przezuci do plecaka w magazynie wiec do zmiennej %ID_Plecaka_Na_Kwity trzba wpisac id tego plecaka
; Jak to zrobic? Otwierasz plecak na kwity i w zmiennej #CONTID masz literki ktore trzeba przepisac lub skopiowac
; za tekstem/zmienna %ID_Plecaka_Na_Kwity tak jak jest to nizej.
; ----
; Jesli twoja postac ma wyuczona jakas walke to: z listy rozwijanej na dole wybierz bron ktorej uzywasz
; Jesli masz walke to w momencie gdy zywiolak ziemi lub szlam pojawi sie obok ciebie postac sama
; podbiegnie do niego wyciagnie bron i krzyknie do straznika, gdy zywiol padnie postac wroci
; w miejsce gdzie ostatnio kopala zalozy ponownie kilof i bedzie dalej kopac.
; --
; W przypadku gdy nie masz walki postac podbiegnie do straznika krzyknie do niego i po chwili wroci na miejsce kopania.
; Jesli zywiol cie zrani, a masz w plecaku bandaze i potrafisz sie leczyc postac sie uzdrowi.
; Jesli nie potrafisz sie uzdrwiac to nie trzymaj bandazy w plecaku.
; -- Przyciski:
; Przetop - jesli stoisz przy piecu przetopi rude z wyjatkiem royalu
; Magazyn - przezuci sztabki i rude do magazynu i jesli ktoregos rodzaju sztabek lub rudy jest wiecej
;         niz 2000 wypisza na nie kwit
; Wszystko - zanacza wszystkie rudy do wywalenie oprocz royala
; Nic - odznacza zaznaczone rudy
; Jesli z listy Miasta wybierzesz Dzika kopalnia wtedy skrypt umozliwia przezucanie rudy lub sztab do
; bezpiecznej skrzyni w domku robi to przycisk Magazyn.

; == KOPANIE PIASKU ==
;Kopie rude w kopalni lub piasek na plazy.
;Do kopania piasku trzeba miec lopate w plecaku postaci, a postac musi miec puste rece.
;Bo inaczej dostaniek komunikat ze tu nic nie wykopiesz.
;--------------------------------
set %path C:\Gornik-id_juczniaka.txt ; Plik w ktorym zostanie zapisane id juczniaka, sciezka do pliku nie moze zawierac spacji
set %ID_Plecaka_Na_Kwity ZNUVYMD ;Tu wpisz id plecaka na kwity w magazynie. Skad wziac to id: Otworz plecak na kwity rozwin galaz zmiennych Container Info i wklej zamiast mojego id to co jest w #CONTID
set %wyzucaj_mapki 0 ;1 - wyzuca postrzepione mapy, 0 - nie wyrzuca
set %SciezkaDoDzwieku D:\sciezka_do_dzwieku1.wav
set %SciezkaDoDzwieku2 D:\sciezka_do_dzwieku2.wav
set %KwityDoPlecakaMagazyn 1 ;1 - wrzuca kwity do plecaka na kwity 0 - nie wrzuca
set %sztab_na_raz 200  ; tu wpisz ile sztab na raz ma byc przezucane: to jest po to by ci sie gnaty nie polamaly jesli bedziesz mial lagi
set %stack_naraz 0 ;0 - przezuca w malych ilosciach zdefiniowanych w zmiennej %sztab_na_raz 1 - przezuca cala kupke na raz a bynajmniej powinien ja nie testowalem :p
set %JestCoWywalac 0   ;tego nie ruszac
set %OpoznienieWyrzucaniaRudy 5
set %zapis_do_pliku 0
set %Wydobycie nie  ; to ustawia sie w menu wiec tu nie zmieniac
set %ToSamoMiejsce nie ; nie zmieniac
set %BiegnijZaZywiolem 0  ;1 - jesli masz bron i umiesz walczyc to postac bedzie biegla za wyziolem jesli ten bedzie uciekal; 0 - nie biegnie za zywiolem
;-- Jesli Skrypt dziala dobrze to nie zmieniaj ponizszych wartosci --
set %Click_Przerwij_X 187
set %Click_Przerwij_Y 165
set %click_X_UstawieniaZamknij 473
set %click_Y_UstawieniaZamknij 73
set %click_X_Ustawienia 134
set %click_Y_Ustawienia 287
set %WydobycieRazKolorNie 7551256
set %WydobycieRazKolorTak 3242752
set %Click_ZamknijPJ_X ( 200 + #CLILEFT )
set %Click_ZamknijPJ_Y ( 180 + #CLITOP )
set %Click_PrzeniesPJ_X ( 73 + #CLILEFT )
set %Click_PrzeniesPJ_Y ( 87 + #CLITOP )
set %Skrzynia_Magazyn_X ( 623 + #CLILEFT )
set %Skrzynia_Magazyn_Y ( 348 + #CLITOP )
set %Plecak_Juczniaka_X ( 597 + #CLILEFT )
set %Plecak_Juczniaka_Y ( 394 + #CLITOP )
set %Click_Pojemnik_X ( 127 + #CLILEFT )
set %Click_Pojemnik_Y ( 251 + #CLITOP )
set %Plecak_Postaci_X ( 602 + #CLILEFT )
set %Plecak_Postaci_Y ( 590 + #CLITOP )
set %Zamknij_Magazyn_X ( 744 + #CLILEFT )
set %Zamknij_Magazyn_Y ( 416 + #CLITOP )
;-------------------------------
set %nrmok 1
set #lpc 2000
menu clear
menu window color btnface
menu window size 220 280
menu window title Gornik 2.1.5
;=================== miasta =====================
menu font size 8
menu text mtmiasto 5 1 Wybierz miasto:
menu text mtskil 110 1 Wybierz skil:
menu text mtbron 10 235 Wybierz bron ktora sie poslugujesz:
menu font size 9
menu font bgcolor white
menu combo create mcmiasto 10 17 95
menu combo add mcmiasto Minoc
menu combo add mcmiasto Mistas
menu combo add mcmiasto Karak Hirin
menu combo add mcmiasto Dzika Kopalnia
menu combo select mcmiasto 1
;=================== skil =======================
menu combo create mcskil 110 17 100
menu combo add mcskil Zaden
menu combo add mcskil Ukrywanie
menu combo add mcskil Wykrywanie
menu combo select mcskil 1
;=================== bron =======================
menu combo create mcBron 10 250 200
menu combo add mcBron Zadena
menu combo add mcBron Wakizashi
menu combo add mcBron Tasak
menu combo select mcBron 1
;=================== miejsce kopania ================
menu font size 9
menu font bgcolor btnface
menu text mtomk 5 155 Nr. miejsca:
menu edit mekopanie 80 152 30 %nrmok ; numer miejsca w kopalni
;=================== wydobywaj raz ================
menu check mcWydobywajRaz 115 155 120 15 #false Wydobywaj raz
;=================== przyciski =================
menu font color black
menu font style b
menu button mbwszystko 10 180 75 20 Wszystko
menu button mbnic 95 180 30 20 Nic
menu button mbpiec 135 180 75 20 Przetop

menu button mbstart 10 205 60 24 Start
menu button mbstop 75 205 60 24 Stop
menu button mbMagazyn 140 205 70 24 Magazyn
;=================== rudy ======================
menu font style
menu font size 8
menu check mczelazo 10 67 90 15 #false zelazo
menu check mcsrebro 10 87 90 15 #false srebro
menu check mczloto 10 107 90 15 #false zloto
menu check mcblack 10 127 90 15 #false black
;------------------------------------------------------
menu check mcagapit 80 67 90 15 #false agapit
menu check mcvaloryt 80 87 90 15 #false valoryt
menu check mcveryt 80 107 90 15 #false veryt ;85 67 90 15
menu check mcmyth 80 127 90 15 #false myth
;------------------------------------------------------
menu check mcblood 145 67 60 15 #false blood
menu check mcazuryt 145 87 60 15 #false azuryt
;------------------------------------------------------
menu check mcgrafit 145 107 50 15 #false grafit
menu check mcmapki 145 127 55 15 #false mapki
;=================== info o rudach ==================
menu shape msopis_rud 5 46 205 17 3 7 1 blue 2 blue
menu text mtopis_rudy 6 47 Zaznacz rude do wyrzucenia:
menu shape msrudy 5 63 205 85 3 7 1 black 2 black
menu font size 9
menu show
menu hideEUO
;====================================================
set #lpc 100
set #menubutton n/a
;=================== petla ===========================
repeat
  if #menubutton = CLOSED ;wcisnieto przycisk X
    {
    menu hide
    set #menubutton N/A
    halt
    }
  if #menubutton = mbMagazyn ;wcisnieto przycisk X
    {
    set #menubutton N/A
    gosub domagazynu
    }
  if #menubutton = mbstart
    {
    set %TuWcisnietoStart_X #charposx
    set %TuWcisnietoStart_Y #charposy
    set %JakisKontener #backpackid
    set #menubutton n/a
    menu delete mbstart
    menu delete mbinfo
    menu font bgcolor btnface
    menu get mcskil
    set %skill #menures - 1
    menu get mcmiasto
    if #menures = 1
       set %swich 2
    if #menures = 2
       set %swich 2
    if #menures = 3
       set %swich 3
    if #menures = 4
       {
       set %swich 2
       set %SkrzyniaWDomku_TYP IIF  ; jesli chcesz rude do magazyniera oddac uzun typ
       }
    menu getnum mekopanie
    set %kop #menures ;pobiera nr pozycji kopania z menu

    menu get mcBron
    if #menures = 1
       set %Bron N/A
    if #menures = 2
       set %Bron VAP
    if #menures = 3
       set %Bron HFR
    gosub menucheck
    set %ToSamoMiejsce nie
    gosub Wskaz_juczniaka
    if #RESULT = ZmiennejNiema
       gosub Wskaz_juczniaka
    move %TuWcisnietoStart_X %TuWcisnietoStart_Y 0 20s
    menu get mcWydobywajRaz
    if #menures = #true
    {
       set %Wydobycie tak
    }
    else
    {
       set %Wydobycie nie
    }
    gosub WydobywajTylkoRaz %Wydobycie
    if #RESULT = BrakPiksela
    {
       Display ok Nie widze okna ustawien. Moze cos je zaslania.
       halt
    }
    gosub Przygotowania
    gosub start
    }
  if #menubutton = mbpiec
    {
    set #menubutton n/a
    gosub przetapianie
    }
  if #menubutton = mbstop
    {
    menu button mbstart 10 205 60 24 Start
    set #menubutton n/a
    }
  if #menubutton = mbwszystko
    {
    gosub wszystko mczelazo mcsrebro mczloto mcblack mcagapit mcvaloryt mcveryt mcmyth mcblood mcazuryt mcgrafit mcmapki
    set #menubutton n/a
    }
  if #menubutton = mbnic
    {
    gosub nic mczelazo mcsrebro mczloto mcblack mcagapit mcvaloryt mcveryt mcmyth mcblood mcazuryt mcgrafit mcmapki
    set #menubutton n/a
    }
until #false
;================= pola wyboru =======================
sub menucheck
  set %WyzucajCos 0
  ;set #lpc 200
  menu get mczelazo
  if #menures = #true
     {
     set %mc1 zelazo
     set %JestCoWywalac 1
     }
  else
     {
     set %mc1
     }

  menu get mcsrebro
  if #menures = #true
     {
     set %mc2 srebro
     set %JestCoWywalac 1
     }
  else
     {
     set %mc2
     }

  menu get mczloto
  if #menures = #true
     {
     set %mc3 zloto
     set %JestCoWywalac 1
     }
  else
     {
     set %mc3
     }

  menu get mcblack
  if #menures = #true
     {
     set %mc4 black
     set %JestCoWywalac 1
     }
  else
     {
     set %mc4
     }

  menu get mcagapit
  if #menures = #true
     {
     set %mc5 agapit
     set %JestCoWywalac 1
     }
  else
     {
     set %mc5
     }

  menu get mcvaloryt
  if #menures = #true
     {
     set %mc6 valoryt
     set %JestCoWywalac 1
     }
  else
     {
     set %mc6
     }

  menu get mcveryt
  if #menures = #true
     {
     set %mc7 veryt
     set %JestCoWywalac 1
     }
  else
     {
     set %mc7
     }

  menu get mcmyth
  if #menures = #true
     {
     set %mc8 myth
     set %JestCoWywalac 1
     }
  else
     {
     set %mc8
     }

  menu get mcblood
  if #menures = #true
     {
     set %mc9 blood
     set %JestCoWywalac 1
     }
  else
     {
     set %mc9
     }

  menu get mcazuryt
  if #menures = #true
     {
     set %mc10 azuryt
     set %JestCoWywalac 1
     }
  else
     {
     set %mc10
     }

  menu get mcgrafit
  if #menures = #true
     {
     set %mc11 grafit
     set %JestCoWywalac 1
     }
  else
     {
     set %mc11
     }

  menu get mcmapki
  if #menures = #true
     {
     set %mc12 mapki
     set %JestCoWywalac 1
     }
  else
     {
     set %mc12
     }
  set %pominlame 0
return
;--------------------------------------------------------------
sub Przygotowania
  menu getnum mekopanie
  set %kop #menures ;pobiera nr pozycji kopania z menu
  menu getnum mcskil
  set %skil #menures
  call %path
  if %kop = 1
    {
      finditem bo_wn_yab G_2 ;szuka jucznego konia, jucznej lamy i golema
      for %i 1 #findcnt
        {
        finditem bo_wn_yab G_2
        if #findid <> %Id_juczniaka1
           {
           ignoreitem #findid
           event macro 1 0 podejdzcie
           ;goto od_nastepnego_miejsca
           }
        else
            {
            break
            }
          }
      if %JestCoWywalac = 1
         {
         set #lobjectid %Id_juczniaka1
         set #NEXTCPOSX %Plecak_Juczniaka_X
         set #NEXTCPOSY %Plecak_Juczniaka_Y
         event macro 17
         }
    }
  if %JestGolem = 1
     event macro 1 0 Golem chron mnie.
return
;-----------------------------------------------------------------------
sub start
  repeat
      set %NoweMiejsce 0
      ;set #lpc 200
      if nie in %ToSamoMiejsce
         {
         gosub miejsce
         }
      gosub kilof
      if #RESULT = KilofaBrak
         {
          set #sysmsgcol 1080
          event sysmessage Nie ma kilofa szukam lopaty.
          gosub lopata
          if #RESULT = LopatyBrak
             {
             set #sysmsgcol 1080
             event sysmessage Nie ma lopaty ani kilofa.
             set #menubutton n/a
             menu font style b
             menu button mbstart 10 205 60 24 Start
             return
             }
         }
      set #ltargetkind %swich
      set #sysmsgcol 1264
      event sysmessage Zaczynam kopac w miejscu nr: %kop
      set %jindex #jindex
      set *JINDEX %jindex
      menu Set mekopanie %kop
      set %czascel #SCNT2 + 10
      event macro 22
      repeat
        if %czascel < #SCNT2 && #targcurs = 1
           {
           event macro 22
           set %czascel #SCNT2 + 10
           }
        scanjournal 1
        if Wlozyl in #journal || W_tym_miejscu in #journal || _zaszkodzilo in #journal
           break
        if #menubutton = mbstop
          {
          menu button mbstart 10 205 60 24 Start
          set #menubutton n/a
          return
          }
      until Zaczynasz in #sysmsg
      gosub PetlaKopania
      if #RESULT = KoniecKopania
         return
  until #false
return
;======================== Petla kopania ===========================
sub PetlaKopania
  set #lpc 100
  set %chpx #charposx
  set %chpy #charposy
  if %WydobywajRaz = 1
  {
     gosub wyzuc_rude
  }
  repeat
      gosub buttonstop ;KoniecKopania
      if #RESULT = KoniecKopania
         return KoniecKopania
      set %time1 #SCNT + 10
      scanjournal 1
      if Nie_widzisz in #journal
         {
         if %kop >= 25
            {
            set %kop 1
            gosub koniec  ;sprawdzic co to robi
            return KoniecKopania
            }
         set %kop %kop + 1
         return
         }

      finditem ED_VE_AHB G_3 ;ED - zywiolak ziemi VE - szlam  AHB - piaskowy wir???
      if #findtype = ED || #findtype = VE || #findtype = AHB ;#findkind <> -1
         gosub Zywiolak #findid
      if #RESULT = StraznikaBrak
         {
         set *WAIT 0
         repeat
         until *STOP = 0
         if %WydobywajRaz = 1
            {
            set %ToSamoMiejsce tak
            }
         return
         }
      if #RESULT = KilofaBrak
         {
         set *WAIT 0
         repeat
         until *STOP = 0
         return KoniecKopania
         }
      if *STOP = 1
         {
          if %WydobywajRaz = 0
          {
             click %Click_Przerwij_X %Click_Przerwij_Y
          }
          if %WydobywajRaz = 1
          {
             wait 5s
             set %ToSamoMiejsce tak
          }
          set *WAIT 0 ; skrypt glodu poczeka 6 sek.
          repeat
          until *STOP = 0
          return
         }
      set %ji #jindex - %jindex
      if %WydobywajRaz = 1 && %ji > 0
         {
          set *JI %ji
          for %i 1 %ji
            {
             set *i %i
             gosub buttonstop
             if #RESULT = KoniecKopania
                return KoniecKopania
             scanjournal %i
             if Wlozyl in #journal
                {
                set %ToSamoMiejsce tak
                scanjournal 1
                if kilofem_w_reke in #journal
                   wait 15s
                return
                }
             if W_tym_miejscu_nie_ma_juz_rudy. in #journal || Nie_widzisz_tego in #journal || Tu_nic_nie_wykopiesz in #journal || That_is_out in #journal
                {
                if *STOP = 1
                   {
                    set *WAIT 0
                    repeat
                    until *STOP = 0
                   }
                set %kop %kop + 1
                set %licz %licz + 1
                if %licz > 1
                   {
                   set %licz 0
                   gosub WyborSkila
                   }
                if #RESULT = WrocDoPetlaPrzyciskow
                   return KoniecKopania
                set %NoweMiejsce 1
                set %ToSamoMiejsce nie
                break
                }
             if Nie_masz_miejsca_w_plecaku in #journal
                {
                gosub koniec
                return KoniecKopania
                }
             }
         }
      if Wlozyl in #sysmsg && %WydobywajRaz = 0
         {
         gosub wyzuc_rude
         }
      if %kop > 25
         {
          gosub koniec
          return KoniecKopania
         }
      if %chpx <> #charposx && %chpy <> #charposy
         gosub ucieczka
      if #RESULT = WrocDoStart
         return
      if #RESULT = WrocDoPetlaPrzyciskow
         return KoniecKopania

      set %ji #jindex - %jindex
      if %WydobywajRaz = 0 && %ji > 0
      {
      for %i 1 %ji
         {
         ;set #lpc 200 ;0
         gosub buttonstop
         if #RESULT = KoniecKopania
            return KoniecKopania
         scanjournal %i
         if W_tym_miejscu in #journal || Nie_widzisz in #journal || Tu_nic_nie_wykopiesz in #journal || That_is_out in #journal
            {
            if *STOP = 1
               {
                set *WAIT 0
                repeat
                until *STOP = 0
               }
            set %kop %kop + 1
            set %licz %licz + 1
            if %licz > 1
               {
               set %licz 0
               gosub WyborSkila
               }
            if #RESULT = WrocDoPetlaPrzyciskow
               return KoniecKopania
            set %NoweMiejsce 1
            break
            }
         if Nie_masz_miejsca_w_plecaku in #journal
            {
            gosub koniec
            return KoniecKopania
            }
         }
      }
      if %NoweMiejsce = 1
         {
         ;event sysmessage nowe miejsce
         break
         }
  until #false
return
;-----------------------------------------------------
sub miejsce
  ;set #lpc 200
  if %kop = 1
   {
     set #ltargetx #charposx
     set #ltargety #charposy
   }
  if %kop = 2
   {
     set #ltargetx #charposx
     set #ltargety #charposy + 1
   }
  if %kop = 3
   {
     set #ltargetx #charposx - 1
     set #ltargety #charposy
   }
  if %kop = 4
   {
     set #ltargetx #charposx
     set #ltargety #charposy - 1
   }
  if %kop = 5
   {
     set #ltargetx #charposx + 1
     set #ltargety #charposy
   }
  if %kop = 6
   {
     set #ltargetx #charposx + 1
     set #ltargety #charposy + 1
   }
  if %kop = 7
   {
     set #ltargetx #charposx
     set #ltargety #charposy + 2
   }
  if %kop = 8
   {
     set #ltargetx #charposx - 1
     set #ltargety #charposy + 1
   }
  if %kop = 9
   {
     set #ltargetx #charposx - 2
     set #ltargety #charposy
   }
  if %kop = 10
   {
     set #ltargetx #charposx - 1
     set #ltargety #charposy - 1
   }
  if %kop = 11
   {
     set #ltargetx #charposx
     set #ltargety #charposy - 2
   }
  if %kop = 12
   {
     set #ltargetx #charposx + 1
     set #ltargety #charposy - 1
   }
  if %kop = 13
   {
     set #ltargetx #charposx + 2
     set #ltargety #charposy
   }
  if %kop = 14
   {
     set #ltargetx #charposx + 2
     set #ltargety #charposy + 1
   }
  if %kop = 15
   {
     set #ltargetx #charposx + 2
     set #ltargety #charposy + 2
   }
  if %kop = 16
   {
     set #ltargetx #charposx + 1
     set #ltargety #charposy + 2
   }
  if %kop = 17
   {
     set #ltargetx #charposx - 1
     set #ltargety #charposy + 2
   }
  if %kop = 18
   {
     set #ltargetx #charposx - 2
     set #ltargety #charposy + 2
   }
  if %kop = 19
   {
     set #ltargetx #charposx - 2
     set #ltargety #charposy + 1
   }
  if %kop = 20
   {
     set #ltargetx #charposx - 2
     set #ltargety #charposy - 1
   }
  if %kop = 21
   {
     set #ltargetx #charposx - 2
     set #ltargety #charposy - 2
   }
  if %kop = 22
   {
     set #ltargetx #charposx - 1
     set #ltargety #charposy - 2
   }
  if %kop = 23
   {
     set #ltargetx #charposx + 1
     set #ltargety #charposy - 2
   }
  if %kop = 24
   {
     set #ltargetx #charposx + 2
     set #ltargety #charposy - 2
   }
  if %kop = 25
   {
     set #ltargetx #charposx + 2
     set #ltargety #charposy - 1
   }
return
;------------------------------------------------------
sub wyzuc_rude
  if #contid <> %Id_juczniaka1
     {
     set #LOBJECTID %Id_juczniaka1
     set %TimeJuki #scnt2 + 20
     event macro 17
     repeat
       if %TimeJuki < #scnt2
          {
          set %TimeJuki #scnt2 + 20
          event macro 17
          }
       finditem wn_bo_yab G_2
       if #findkind = -1
          {
          event macro 1 0 podejdzcie
          return
          }
     until #contid = %PlecakJuczniaka
     wait 3
     contpos %Plecak_Juczniaka_X %Plecak_Juczniaka_Y
     }

  ignoreitem reset
  finditem dwj_enk C_ , %PlecakJuczniaka
  for #FINDINDEX 1 #FiNDCNT
      {
      event Property #findid
      if %mc1 in #Property || %mc2 in #Property || %mc3 in #Property || %mc4 in #Property || %mc5 in #Property || %mc6 in #Property || %mc7 in #Property || %mc8 in #Property || %mc9 in #Property || %mc10 in #Property || %mc11 in #Property
         {
         if #findstack = 0
            exevent dtag #findid 1
         else
            exevent drag #findid #findstack
         wait %OpoznienieWyrzucaniaRudy
         exevent dropg #charposx #charposy #charposz
         wait %OpoznienieWyrzucaniaRudy
         }
      }
    finditem bo_wn_yab G_2 ;szuka jucznego konia, jucznej lamy i golema
    for #FINDINDEX 1 #FiNDCNT
      {
      if #findid <> %Id_juczniaka1
         {
         ignoreitem #findid
         event macro 1 0 podejdzcie
         wait 8
         }
      else
          {
          break
          }
      }
  if %mc12 = mapki
     {
      finditem RVH C_ , %PlecakJuczniaka
      for #FINDINDEX 1 #FiNDCNT
          {
           exevent drag #findid 1
           wait %OpoznienieWyrzucaniaRudy
           exevent dropg #charposx #charposy #charposz
           wait %OpoznienieWyrzucaniaRudy
          }
     }
  ignoreitem reset
return
;---------------------------------------------
sub zapis
  scanjournal 1
  if #sysmsg = Zapisywanie_Stanu_Swiata. || #journal = Zapisywanie_Stanu_Swiata.
    {
    set %time #SCNT + 14
    repeat
       scanjournal 1
    until Koniec_Zapisywania in #journal
    }
return
;---------------------------------------------
sub WyborSkila
  if %skill = 1
     event macro 13 21
  if %skill = 2
     event macro 13 14
return ;WrocDoStart
;---------------------------------------------
sub Wskaz_juczniaka
  ;pause
  set %ZmiennaIstnieje 0
  if %zapis_do_pliku = 0
     call %path
  if N/A in %Id_juczniaka1
    set %zapis_do_pliku 1 ; jesli nie ma pliku; nastapi utworzenie nowego i zapis do niego
  if N/A notin %Id_juczniaka1 ;&& %zapis_do_pliku = 0
    {  ;jesli plik jest i zmienne sa ustawione poprawnie
    set %zapis_do_pliku 0
    event macro 1 0 podejdzcie
    set %ZamknijPJ_X ( %Plecak_Juczniaka_X + 70 )
    set %ZamknijPJ_Y ( %Plecak_Juczniaka_Y + 70 )
    wait 1s
    click %ZamknijPJ_X %ZamknijPJ_Y r f
    ;move %TuWcisnietoStart_X %TuWcisnietoStart_Y 0 20s
    set %ZmiennaIstnieje 1
    }
  if %ZmiennaIstnieje = 0
     {
      gosub WybierzPojemnik
      repeat
         scanjournal 1
         if Wybierz_pojemnik in #journal || Stoisz_za_daleko in #journal
            gosub WybierzPojemnik
      until #TargCurs = 0 && Ustawiono_pojemnik in #journal
      set %Id_juczniaka1 #ltargetid
      set *GOLEM %Id_juczniaka1
      set #NEXTCPOSX %Plecak_Juczniaka_X
      set #NEXTCPOSY %Plecak_Juczniaka_Y
      set %Plecak_Jucz_X #NEXTCPOSX + 70
      set %Plecak_Jucz_Y #NEXTCPOSY + 70
      set #lobjectid %Id_juczniaka1
      set %TimeOJ #scnt2 + 20
      event macro 17
      repeat
         if %TimeOJ < #scnt2
            {
             set #lobjectid %Id_juczniaka1
             event macro 17
             set %TimeOJ #scnt2 + 20
            }
      until %Plecak_Juczniaka_X = #contposx && %Plecak_Juczniaka_Y = #contposy
      set %PlecakJuczniaka #contid
      set %zapis_do_pliku 1
     }
  if %ZmiennaIstnieje = 1
     {
     set %zapis_do_pliku 0
     set #NEXTCPOSX %Plecak_Juczniaka_X
     set #NEXTCPOSY %Plecak_Juczniaka_Y
     set %Plecak_Jucz_X #NEXTCPOSX + 70
     set %Plecak_Jucz_Y #NEXTCPOSY + 70
     set #lobjectid %Id_juczniaka1
     set %TimeOJ #scnt2 + 10
     set %czas_otwarcia_juki #scnt2 + 30
     event macro 17
     repeat
        if %TimeOJ < #scnt2
           {
           set #lobjectid %Id_juczniaka1
           event macro 17
           set %TimeOJ #scnt2 + 10
           }
        if %czas_otwarcia_juki < #scnt2
           {
           set %zapis_do_pliku 1
           set %Id_juczniaka1 N/A
           return ZmiennejNiema
           }
     until %Plecak_Juczniaka_X = #contposx && %Plecak_Juczniaka_Y = #contposy
     ;click %Plecak_Jucz_X %Plecak_Jucz_Y
     set %PlecakJuczniaka #contid
     }
  if %zapis_do_pliku = 1
     {
     event sysmessage UWAGA!! NASTAPI ZAPIS DANYCH JUKI. WYSKOCZY OKIENKO.
     wait 2s
     execute cmd.exe /c "del %path && echo s , et , #spc , % , Id_juczniaka1 , #spc , %Id_juczniaka1 >> %path && echo exi , t >> %path "
     set %zapis_do_pliku 0
     }
  if #LOBJECTTYPE = YAB
     set %JestGolem 1
return
;---------------------------------------------
sub przetapianie
  if N/A in %Id_juczniaka1
     gosub Wskaz_juczniaka
  if #RESULT = ZmiennejNiema
     gosub Wskaz_juczniaka
  finditem bo_wn_yab G_1 ;szuka jucznego konia, jucznej lamy i golema
  for #findindex 1 #findcnt
    {
    if #findid <> %Id_juczniaka1
       {
       ignoreitem #findid
       event macro 1 0 podejdzcie
       wait 1s
       }
    else  ;jesli znalazl swojego juczniaka wyskocz
        {
        break
        }
      }
  ignoreitem reset
  set %czasPJ #scnt2 + 40 ;czas plecaka juczniaka
  set #LOBJECTID %Id_juczniaka1
  event macro 17
  repeat
     if %czasPJ < #scnt
        {
        set #LOBJECTID %Id_juczniaka1
        event macro 17
        }
  until #contid = %PlecakJuczniaka
  wait 3
  contpos %Plecak_Juczniaka_X %Plecak_Juczniaka_Y
  wait 5
  ignoreitem reset
  innaruda:
  finditem * C_ , %PlecakJuczniaka
  for #findindex 1 #findcnt
      {
      if #CONTID <> %PlecakJuczniaka ;jesli plecak juczniaka nie jest otwarty
         {
          set #LOBJECTID %Id_juczniaka1
          set %Time_juki #scnt2 + 40
          event macro 17
          repeat
             if %Time_juki < #scnt
                {
                event macro 1 0 podejdzcie
                wait 1s
                set #LOBJECTID %Id_juczniaka1
                event macro 17
                }
          until #CONTID = %PlecakJuczniaka
          wait 3
          contpos %Plecak_Juczniaka_X %Plecak_Juczniaka_Y
         }
      if #FINDCOL = 1209  ;royal
         {
         ignoreitem #findid
         continue
         }
       if #findtype = dwj
          {
          set %time_przetop #scnt2 + 20
          set #LOBJECTID #FINDID
          event macro 17
          repeat
             if %time_przetop < #scnt
                continue
          until Rozpocz in #sysmsg  ; #journal
          set %jindex #jindex
          repeat
            gosub SprawdzGumpa
          until %WyjdzZPetli = 1 ;Przetopil in #sysmsg || Zniszczyl in #sysmsg
          set %WyjdzZPetli 0
          }
      }
  event sysmessaga RUDA PRZETOPIONA
return
;------------------------------------------------
sub kilof
  ignoreitem reset
  finditem npf C_ , #charid
  for #findindex 1 #findcnt
      {
         set #lobjectid #findid
         event macro 17
         if #targcurs = 1
         {
            return
         }
         set %TimeCelownik #scnt2 + 10
         repeat
            if %TimeCelownik < #scnt2
               {
               set %TimeCelownik #scnt2 + 10
               set #lobjectid #findid
               event macro 17 0
               }
         until #targcurs = 1
         return
      }
return KilofaBrak
;------------------------------------------------
sub lopata
   ignoreitem reset
   finditem TWF C_ , #backpackid
   for #findindex 1 #findcnt
       {
           set #lobjectid #findid
           event macro 17 0
           if #targcurs = 1
           {
              return
           }
           set %TimeCelownik #scnt2 + 20
           repeat
              if %TimeCelownik < #scnt2
                 {
                 set %TimeCelownik #scnt2 + 20
                 set #lobjectid #findid
                 event macro 17 0
                 }
           until #targcurs = 0
           return
       }
return LopatyBrak
;------------------------------------------------
sub WybierzPojemnik
  event sysmessage Poczekaj na celownik i wyceluj w juczniaka.
  set %TimePojemnik #scnt2 + 20
  event macro 1 0 .pojemnik
  repeat
     if %TimePojemnik < #scnt2
        {
        set %TimePojemnik #scnt2 + 20
        event macro 1 0 .pojemnik
        }
  until #ContSize = 250_180 && generic_gump in #CONTNAME

  set %Pojemnik_X #CONTPOSX + 28
  set %Pojemnik_Y #CONTPOSY + 150
  click %Pojemnik_X %Pojemnik_Y mc
return
;------------------------------------------------
sub buttonstop
  if #menubutton = mbstop
    {
     set #menubutton n/a
     menu font color black
     menu font style b
     menu button mbstart 10 205 60 24 Start
     menu font color black
     click %Click_Przerwij_X %Click_Przerwij_Y
     gosub wyzuc_rude
     click %ZamknijPJ_X %ZamknijPJ_Y r f
     set #menubutton n/a
     return KoniecKopania
    }
return
;-----------------------------------------------
sub ucieczka
  set #menubutton n/a
  gosub RysujPrzyciskStart
  event sysmessage Oddaliles sie od miejs w ktorym kopales.
  event sysmessage Wroc na miejsce i wcisnij Start.
  repeat
     if #menubutton = mbstop
        return WrocDoPetlaPrzyciskow
  until #menubutton = mbstart
  set #menubutton n/a
  menu delete mbstart
return WrocDoStart
;-----------------------------------------------
sub koniec
  gosub wyzuc_rude
  set #sysmsgcol 1080
  event sysmessage Skonczono kopac
  sound %SciezkaDoDzwieku
  set #menubutton n/a
  menu font style b
  menu button mbstart 10 205 60 24 Start
  set %nrmok 1
  menu set mekopanie %nrmok
  click %ZamknijPJ_X %ZamknijPJ_Y r f
return
;-----------------------------------------------
sub wszystko
  for %i 1 %0
      {
      menu Set % . %i #true
      }
return
;-----------------------------------------------
sub nic
  for %i 1 %0
      {
      menu Set % . %i #false
      }
return
;-----------------------------------------------
sub zerowanie
  for %i 1 %0
      {
      menu Set % . %i
      }
  for %i 1 20
      {
      set %s . %i
      }
return
;----------------------------------------------------------
sub domagazynu   ;otwiera magazyn
  set %TuWcisnietoStart_X #charposx
  set %TuWcisnietoStart_Y #charposy
  if N/A in %Id_juczniaka1
     gosub Wskaz_juczniaka
  if #RESULT = ZmiennejNiema
     gosub Wskaz_juczniaka
  move %TuWcisnietoStart_X %TuWcisnietoStart_Y 0 20s
  if %SkrzyniaWDomku_TYP <> N/A
     set %SkrzyniaDom 1
  if %SkrzyniaDom <> 1
    {
    repeat
       finditem * G_5  ;szuka wszystkiego
       event Property #findid
       ignoreitem #findid
    until Magazynier in #property
    ignoreitem reset
    move #findx #findy 1 30s
    event macro 1 0 Podejdzcie.
    wait 5
    szmag:
    set #NEXTCPOSX %Skrzynia_Magazyn_X
    set #NEXTCPOSY %Skrzynia_Magazyn_Y
    event macro 1 0 Magazynier otworz moja skrzynie
    }
  SkrzyniaDom:
  if %SkrzyniaWDomku_TYP <> N/A
     {
     event sysmessage Szukam skrzyni.
     finditem %SkrzyniaWDomku_TYP G_2
     for #findindex 1 #findcnt
        {
        if %SkrzyniaWDomku_TYP = #findtype
           {
           event pathfind #findx #findy #findz
           wait 3s
           }
        }
     set #lobjectid #findid
     event macro 17
     }
  repeat
     wait 5
  until #CONTSIZE = 180_240
  wait 3
  set %SkrzyniaMagazyn #CONTID
  contpos %Skrzynia_Magazyn_X %Skrzynia_Magazyn_Y
  wait 3
  set %Magazyn_contx #CONTPOSX + 100
  set %Magazyn_conty #CONTPOSY + 100
  if #contid <> %PlecakJuczniaka
     {
     set #LOBJECTID %Id_juczniaka1
     event macro 17
     set %czas #SCNT2 + 30
     repeat
        if %czas < #SCNT
           {
           set #LOBJECTID %Id_juczniaka1
           event macro 17
           }
     until #contid = %PlecakJuczniaka
     wait 3
     contpos %Click_PrzeniesPJ_X %Click_PrzeniesPJ_Y
     wait 3
     set %Jucznia_Nr1_contx #CONTPOSX + 100
     set %Jucznia_Nr1_conty #CONTPOSY + 100
     }
    ;przezucanie rudy royal
    finditem dwj C_ , %PlecakJuczniaka
    for #findindex 1 #findcnt
        {
        if #findtype = dwj
           {
           exevent drag #findid #findstack
           wait %OpoznienieWyrzucaniaRudy
           exevent dropc %SkrzyniaMagazyn
           wait %OpoznienieWyrzucaniaRudy
           ignoreitem #findid
           }
        }
    ignoreitem reset
    ignoreitem #backpackid
    set %czas #scnt + 5
    set %RudyNima 0
    finditem enk C_ , %PlecakJuczniaka
    repeat
         event sysmessage Ilosc sztab w juczniaku: #findstack
         if %stack_naraz = 1
            {
            gosub zapis_stanu_swiata
            exevent drag #findid #findstack
            wait %OpoznienieWyrzucaniaRudy
            exevent dropc %SkrzyniaMagazyn
            wait %OpoznienieWyrzucaniaRudy
            continue
            }
         exevent drag #findid %sztab_na_raz ;#findstack
         wait %OpoznienieWyrzucaniaRudy
         exevent dropc %SkrzyniaMagazyn
         wait %OpoznienieWyrzucaniaRudy
         finditem enk C_ , %PlecakJuczniaka
         if #findkind = -1
            set %RudyNima 1
    until %RudyNima = 1
    ignoreitem reset
    finditem SZF_VZF_RVF_RVH C_ , %PlecakJuczniaka
    for #findindex 1 #findcnt
       {
        exevent drag #findid #findstack
        wait %OpoznienieWyrzucaniaRudy
        exevent dropc #backpackid
        wait %OpoznienieWyrzucaniaRudy
       }
  click %Click_ZamknijPJ_X %Click_ZamknijPJ_Y mc r
  wait 8
  if %SkrzyniaWDomku_ID = N/A || N/A in %SkrzyniaWDomku_ID
     gosub Sztaby_do_kwitow
  gosub buttonstop
return
;--------------------------------------------------------
sub Sztaby_do_kwitow
  ;--- tworzenie wiazki 2000 sztab
  finditem enk_dwj C_ , %SkrzyniaMagazyn
  set %StartX_kupki 0
  set %StartY_kupki 150
  set %X_kupki %StartX_kupki + 10
  set %Y_kupki 150
  for #findindex 1 #findcnt
    {
    if #findstack > 2000
       {
       set %Wielokrotnosc2k ( #findstack / 2000 )
       event sysmessage Kupek po 2k: %Wielokrotnosc2k
       set %ID_starej_kupki #findid
       for %c 1 %Wielokrotnosc2k
         {
         set %X_kupki %X_kupki + 20
         exevent drag #findid 2000
         wait 5
         if dwj in #findtype
            exevent dropc %SkrzyniaMagazyn 200 150
         else
            exevent dropc %SkrzyniaMagazyn %X_kupki %Y_kupki
         wait 5
         finditem enk_dwj C_ , %SkrzyniaMagazyn
         }
       }
    }
;---- wypisywanie kwitu
  wait 5
  ignoreitem reset
  finditem ENK_DWJ C_ , %SkrzyniaMagazyn
  for #findindex 1 #findcnt
    {
    if #findstack = 2000
       {
       event macro 1 0 wypisz kwit
       repeat
       until #targcurs = 1
       wait 3
       set %x #findx + 15
       set %y #findy + 15
       click %x %y mc
       wait 15
       event macro 1 0 tak
       wait 1s
       ignoreitem #findid
       continue
       }
    }
;---- przenoszenie kwitu
  finditem TVH C_ , #backpackid
  for #findindex 1 #findcnt
    {
    exevent drag #findid 1
    wait 3
    if %KwityDoPlecakaMagazyn = 1
      {
      set #lobjectid %ID_Plecaka_Na_Kwity
      event macro 17
      wait 5
      exevent dropc %ID_Plecaka_Na_Kwity
      wait 3
      continue
      }
    else
      exevent dropc %SkrzyniaMagazyn 10 200
    }
  finditem TVH C_ , %ID_Plecaka_Na_Kwity
  event sysmessage Kwitow: #findcnt
return
;---------------------------------------------
sub SprawdzGumpa
  set #lpc 2000
  scanjournal 1 ;%i
  set %dziennik #journal
  ;event sysmessage dziennik %dziennik
  str Pos %dziennik )
  set %Pozycja_nawiasu #StrRes
  set %end %Pozycja_nawiasu - 2
  str Mid %dziennik 2 %end
  set %Tyle_z_Tylu #StrRes
  str Pos %Tyle_z_Tylu z
  set %z_end #StrRes - 2
  str Mid %Tyle_z_Tylu 1 %z_end
  set %Pierwsza_wartosc #StrRes
  ;event sysmessage Pierwsza_wartosc %Pierwsza_wartosc
  str Pos %Tyle_z_Tylu _
  set %__start #StrRes + 3
  str Len %Tyle_z_Tylu
  set %Dlugosc #StrRes
  str Mid %Tyle_z_Tylu %__start %Dlugosc
  set %Druga_wartosc #StrRes
  if %Pierwsza_wartosc = %Druga_wartosc
     {
     scanjournal 1
     if #JCOLOR = 40
        {
        click %Click_Przerwij_X %Click_Przerwij_Y
        wait 6s
        }
     set %WyjdzZPetli 1
     }
  else
     {
     set #lpc 100
     return
     }
   }
  set #lpc 100
return
;---------------------------------------------
sub RysujPrzyciskStart
  menu font size 9
  menu font color black
  menu font style b
  menu button mbstart 10 205 60 24 Start
return
;---------------------------------------------
sub Zywiolak
  set %ID_Zywolu %1
  set %M_Kopania_X #charposx
  set %M_Kopania_Y #charposy
  set %ZdejmijBron 0
  if *STOP = 1
     set *WAIT 1
  wait 1s
  if %Bron = N/A || N/A in %Bron ;nie ma broni wiec wola straz
    {
      click %Click_Przerwij_X %Click_Przerwij_Y
      set %SzukajDrugiRaz 0
      SzukajDrugiRaz:
      set %Straznik_Cnt 0
      ignoreitem #findid
      set %i 1
      finditem MMB_GQG_HHH_SMGEG_ANGEG_BKERD_WJERD_XJERD_ZDDK G ;_15  ;szuka straznikow
      for #findindex 1 #findcnt
          {
          if #findid = MMB || #findid = GQG || #findid = HHH || #findid = SMGEG || #findid = ANGEG || #findid = BKERD || #findid = WJERD || #findid = XJERD || #findid = ZDDK  ;Straznik in #property || Obronca in #property
             {
             set %Straznik_ID_ . %i #findid
             set %Straznik_X_ . %i #findx
             set %Straznik_Y_ . %i #findy
             set %Straznik_Dist_ . %i #finddist
             set %Straznik_Cnt %i
             ignoreitem #findid
             set %i %i + 1
             }
          }
      ignoreitem reset
      if %Straznik_Cnt > 0
         {
         if N/A in %Straznik_Dist_2
            {
            set %Straznik_Dist_2 100
            }
         set %TimeStraznik #scnt + 10
         if %Straznik_Dist_1 > %Straznik_Dist_2  ;jesi straznik 1 jest dalej od 2 biegnij do 2
            {
            event Pathfind %Straznik_X_2 %Straznik_Y_2 #charposz
            repeat
               if *STOP = 1
                  set *WAIT 1
               if %TimeStraznik < #scnt
                  break
               wait 1s
               event Pathfind %Straznik_X_2 %Straznik_Y_2 #charposz
               finditem %Straznik_ID_2 G_1
            until %Straznik_ID_2 = #findid
            }
         if %Straznik_Dist_1 < %Straznik_Dist_2 ;jesli straznik 2 jest dalej niz 1 to biegnij do 1
            {
            event Pathfind %Straznik_X_1 %Straznik_Y_1 #charposz
            repeat
               if *STOP = 1
                  set *WAIT 1
               if %TimeStraznik < #scnt
                  break
              wait 1s
              event Pathfind %Straznik_X_1 %Straznik_Y_1 #charposz
              finditem %Straznik_ID_1 G_1
              ;wait 2
            until %Straznik_ID_1 = #findid
            }
         }
      else
         {
         event macro 4 4 Straz!! Pomocy!! Morduja!!
         return StraznikaBrak
         }
      ;set #lpc 200
      event macro 4 4 Straz!! Pomocy!! Morduja!!
      wait 1s
      event Pathfind %M_Kopania_X %M_Kopania_Y #charposz  ;wraca na miejsce kopania
      repeat
          if *STOP = 1
             set *WAIT 1
          wait 2s
          event Pathfind %M_Kopania_X %M_Kopania_Y #findz
      until %M_Kopania_X = #charposx && %M_Kopania_Y = #charposy
      event macro 1 0 za mna
      wait 5
      event macro 1 0 podejdzcie
      wait 2s
      return StraznikaBrak
    }
    else  ;postac ma bron w plecaku i potrafi sie nia bronic
    {
      click %Click_Przerwij_X %Click_Przerwij_Y
      set %WrocNaMiejsceKopania 0
      event Pathfind #findx #findy #charposz
      wait 1s
      if *STOP = 1
         set *WAIT 1
      finditem %Bron C_ , #backpackid ;szuka widel
      set #lobjectid #findid
      set %BronID #findid
      event macro 17
      event macro 1 0 Straznik zostaw sam to zabije.
      set %TimeZalozBron #scnt2 + 20
      repeat
         if *STOP = 1
            set *WAIT 1
         if %TimeZalozKilof < #scnt2
            {
            set #lobjectid %BronID
            event macro 17 0
            set %TimeZalozBron #scnt2 + 20
            }
         finditem %Bron C_ , #charid
      until %BronID = #findid
      repeat
           if *STOP = 1
              set *WAIT 1
           if #HITS < #MAXHITS
              gosub Leczenie
           finditem ED_VE G ;ED - zywiolak ziemi VE - szlam
           if #finddist > 1 && %BiegnijZaZywiolem = 1
              event Pathfind #findx #findy #findz
           if %ID_Zywolu <> #findid
              break
      until #false
      event macro 1 0 podejdzcie
      move %M_Kopania_X %M_Kopania_Y 0 20s
      event sysmessage Odpoczywam po walce
      wait 6s
    }
     finditem TWF_NPF C_ , #backpackid
     for #findindex 1 #findcnt
         {
          if #findtype = TWF
             {
              set %ZdejmijBron 1
              break
             }
          if #findtype = NPF
             {
              set %ZdejmijBron 1
              break
             }
         }
     if *STOP = 1
        set *WAIT 1
     if %ZdejmijBron = 0
        {
         set #sysmsgcol 1080
         event sysmessage Nie znalazlem lopaty ani kolofa.
         event sysmessage Koniec kopania.
         return KilofaBrak
        }
     if %ZdejmijBron = 1
        {
        finditem %Bron C_ , #charid
        exevent drag #findid 1
        wait 5
        exevent dropc #backpackid
        wait 5
        event macro 1 0 podejdzcie
        if *STOP = 1
           set *WAIT 1
        finditem NPF C_ , #backpackid
        set #lobjectid #findid
        event macro 17 0
        set %TimeZalozKilof #scnt2 + 20
        set %KilofID #findid
        repeat
           if %TimeZalozKilof < #scnt2
              {
              set #lobjectid %KilofID
              event macro 17 0
              set %TimeZalozKilof #scnt2 + 20
              }
           finditem NPF C_ , #charid
        until %KilofID = #findid
        wait 1s
        return StraznikaBrak
        }
return
;--------------------------------------------
sub Leczenie
  if #hits = #maxhits
     return
  finditem ZLF C_ , #backpackid  ;czyste bandarze
  for #findindex 1 #findcnt
      {
        if #findtype = ZLF
           {
             if #findstack < 10
                event sysmessage Koncza Ci sie bandaze. Zostalo #findstack bandazy!!!
             set #lobjectid #findid
             event macro 17
             set %cel_time #scnt2 + 20
             repeat
                if %cel_time < #scnt2
                   {
                   set #lobjectid #findid
                   event macro 17
                   set %cel_time #scnt2 + 20
                   }
             until #targcurs = 1
             set %cel_time #scnt2 + 20
             event macro 23
             repeat
                if %cel_time < #scnt2
                   {
                   set %cel_time #scnt2 + 20
                   event macro 23
                   }
                if Ta_osoba_jest_w_pelni in #sysmsg
                   return
             until Zaczynasz in #sysmsg
             set %licznik 0
             set %czas #scnt2 + 9
             set %jindex #jindex
             ;set #lpc 200
             set %czas_hp #scnt + 1
             repeat
                set #sysmsgcol 1088
                if %czas < #scnt2
                   {
                   set %licznik %licznik + 1
                   if %licznik > 14 || #hits = #maxhits
                      {
                      return
                      }
                   set %czas #scnt2 + 9
                   }
               set %ji #jindex - %jindex
               for %i 1 %ji
                   {
                   scanjournal %i
                   if Wyleczyl in #journal || palec in #journal || Nie_udalo in #journal || przestal in #journal || Anulowano. in #journal || Ta_osoba in #journal
                      {
                      return
                      }
                   }
                if #hits < 20 && #charghost = no && %czas_hp < #scnt
                   {
                   set #sysmsgcol 1080
                   event sysmessage MASZ #hits HP!!!
                   set %czas_hp #scnt + 1
                   }
             until Wyleczyl in #sysmsg || palec in #sysmsg || Nie_udalo in #sysmsg || przestal in #sysmsg || Anulowano. in #sysmsg || Ta_osoba in #journal
             return
           }
      }
  set #sysmsgcol 1080
  event sysmessage NIE MASZ BANDAZY !!!
return
;-----------------------------------------------------------------------
sub WydobywajTylkoRaz ;( nie - 50 powtorzen lub tak - po 1 sztuce )
  event macro 1 0 .ustawienia
  set %TimeUstaw #scnt2 + 20
  repeat
     if %TimeUstaw < #scnt2
        {
        event macro 1 0 .ustawienia
        set %TimeUstaw #scnt2 + 20
        }
  until 500_430 in #CONTSIZE || ( #CONTSIZEX = 500 && #CONTSIZEY = 430 )
  wait 1s
  if nie in %1  ; sprawdza czy bedzie kul do 50 powtorzen
    {
    set %WydobywajRaz 0  ;bedzie kul do 50 powtorzen
    savepix %click_X_Ustawienia %click_Y_Ustawienia 1
    if #pixcol = %WydobycieRazKolorNie
       {
       click %click_X_UstawieniaZamknij %click_Y_UstawieniaZamknij
       return
       }
    if #pixcol = %WydobycieRazKolorTak
       {
       click %click_X_Ustawienia %click_Y_Ustawienia
       repeat
       until 500_430 in #CONTSIZE || ( #CONTSIZEX = 500 && #CONTSIZEY = 430 )
       wait 1s
       savepix %click_X_Ustawienia %click_Y_Ustawienia 1
       if #pixcol = %WydobycieRazKolorNie
          {
          click %click_X_UstawieniaZamknij %click_Y_UstawieniaZamknij
          return
          }
       }
    }
  if tak in %1  ; sprawdza czy bedzie kul do 50 powtorzen
    {
    set %WydobywajRaz 1  ;bedzie kul po 1 sztuce
    savepix %click_X_Ustawienia %click_Y_Ustawienia 1
    if #pixcol = %WydobycieRazKolorTak
       {
       click %click_X_UstawieniaZamknij %click_Y_UstawieniaZamknij
       return
       }
    if #pixcol = %WydobycieRazKolorNie
       {
       click %click_X_Ustawienia %click_Y_Ustawienia
       repeat
       until 500_430 in #CONTSIZE || ( #CONTSIZEX = 500 && #CONTSIZEY = 430 )
       wait 1s
       savepix %click_X_Ustawienia %click_Y_Ustawienia 1
       if #pixcol = %WydobycieRazKolorTak
          {
          click %click_X_UstawieniaZamknij %click_Y_UstawieniaZamknij
          return
          }
       }
    }
return BrakPiksela