struct PS_INPUT {
    float2 uv: TEXCOORD0;
};

struct PS_OUTPUT {
    float4 color_0: SV_TARGET0;
};

uniform sampler2D texture_divergence;
uniform float2 texel_size;

float unpack_pressure(float2 data) {return data.x + (data.y / 255.0);}
float2 pack_pressure(float data) {return float2(floor(data * 255.0) / 255.0, frac(data * 255.0));}
float unpack_divergence(float2 data) {return data.x + (data.y / 255.0);}
float2 pack_divergence(float data) {return float2(floor(data * 255.0) / 255.0, frac(data * 255.0));}

void main(in PS_INPUT IN, out PS_OUTPUT OUT) {
    float velocity_range = 10.0;
    float pressure_range = 10.0;

    float right = unpack_pressure(tex2D(gm_BaseTexture, IN.uv + float2(texel_size.x, 0.0)).xy) * pressure_range;
    float left = unpack_pressure(tex2D(gm_BaseTexture, IN.uv - float2(texel_size.x, 0.0)).xy) * pressure_range;
    float bottom = unpack_pressure(tex2D(gm_BaseTexture, IN.uv + float2(0.0, texel_size.y)).xy) * pressure_range;
    float top = unpack_pressure(tex2D(gm_BaseTexture, IN.uv - float2(0.0, texel_size.y)).xy) * pressure_range;

    float divergence = (unpack_divergence(tex2D(texture_divergence, IN.uv).xy) - 128.0 / 255.0) * velocity_range;

    float pressure = (left + right + top + bottom - divergence) * 0.25;

    OUT.color_0 = float4(pack_pressure(saturate(pressure / pressure_range)), 0.0, 0.0);
}