ffmpeg bat converter

@echo off
set num=
set name=
set ext=.mkv

set pass=

set ss=
set to=

set bv=1000
set ba=100
::c для copy, n для an/vn, 500-64 если пусты

set scale=
::Например -1:720

set sub=
::Например boku no pico.ass

set speed=

set namevideo=
::отсюда возьмется видео, а из %name%%ext% аудио

set ss0=
set t=

set outf=
set title=
set delete_an=

set si=
::номер дорожки вшитых в мкв сабов

set mapa=
set var1=
set var2=

set frame_duration=60

if "%name%" == "" ( set name=%~nx1)
if "%sub%" == "" ( set sub=%~nx2)
::Для перетаскивания файлов на этот батник

set path1=D:\w\f\c\

::==================================================================================::

if not "%t%" == "" (set t=-t %t%)
if not "%to%" == "" (set to=-to %to%)
if not "%ss0%" == "" (set ss0=-ss %ss0%)
if not "%ss%" == "" (set ss=-ss %ss%)

if "%bv%" == "" (set bv=-b:v 500k) else if "%bv%" == "c" (set bv=-c:v copy) else ^
if "%bv%" == "n" (set bv=-vn) else (set bv=-b:v %bv%k)
if "%ba%" == "" (set ba=-b:a 64k) else if "%ba%" == "c" (set ba=-c:a copy) else ^
if "%ba%" == "n" (set ba=-an) else (set ba=-b:a %ba%k)


if not "%scale%" == "" (set scale=scale=%scale%:flags=lanczos
set vf=-vf %scale%)

if not "%si%" == "" (set sub=%name%%ext%:si=%si%)

if not "%sub%" == "" ( if not "%vf%" == "" (set vf=%vf%,subtitles="%sub%") ^
else (set vf=-vf subtitles="%sub%") )

if not "%speed%" == "" (set speed=-speed %speed%)
if "%mapa%" == "" (set mapa=-map 0:a)

if not "%frame_duration%" == "" (set frame_duration=-frame_duration %frame_duration%)

set log=-passlogfile "%path1%logs\log%name%%num%"
if not "%title%" == "" (set title=%title%) else (set title=%name%)

set outname=%title%%num%
if "%outf%" == "" (set outf=webm) else (set outf=%outf%)
set outext=.%outf%

@echo on

if not "%pass%" == "" (goto %pass%)
:1
	ffmpeg %ss0% -i "%name%%ext%" %vf% %ss% %to% %t%  %log% %speed% %bv%  %var1% %var2% -an -sn -frame-parallel 0 -pass 1 -tile-columns 0 -threads 1 -y -f %outf% NUL
:2
	ffmpeg %ss0% -i "%name%%ext%" %ss% %to% %t% %vf% %log% %speed%  %bv%  %var1% %var2% -an -sn -frame-parallel 0 -pass 2 -tile-columns 0 -threads 1 -metadata title="%title%" -y "%outname%-an%outext%"

if "%ba%"==-an (ren "%outname%"-an%outext% %outname%"%outext%
goto 4)
set namevideo=%outname%-an%outext%

:3
 	ffmpeg  %ss% %ss0% -i "%name%%ext%"  -i "%namevideo%" %ba%  %var1% %var2% ^
%mapa% -map 1:v -c:v copy -metadata title="%title%" %frame_duration% -shortest -ac 2 -y "%outname%%outext%"

if "%delete_an%"==1 (del "%name%-an%outext%")

:4
pause