Platnerz_Menu_sety_exp_v-1.6

; Platnerz_Menu_sety_exp_v-1.6.txt
; Autor: Janusz [Frisky/Fris]
; Sugestie: xthailen
;============ OPIS ==================
; UWAGA !!
; W przypadku innych wersji systemu niz Windows XP
; trzeba uruchamiac EasyUO jako administrator
;
; Skrypt Testowany na systemach Windows XP SP3 oraz Windows 7 SP1
;------------------------------------
; Skrypt ten wspolpracuje ze skryptem Glod_v-2.0 mojego autorstwa.
; Jesli postac zglodnieje makro zostanie zatrzymane i bedzie czekac, az
; skrypt Glod_v-2.0 nakarmi postac. Gdy postac zostanie nakarmiona Skrypt
; Platnerz_Menu_sety_exp_v-1.4 wznowi prace od miejsca w ktorym skonczyl.
;------------------------------------
; Skrypt dziala w kazdym miejscu w ktorym piec jest oddalony od kowadla o 6 krokow (kratek).
; Po wybraniu rodzaju setu do wykucia zostaniesz poproszony o wycelowanie celownika w juke
; w celu zapisania informacji o plecaku. Podazaj zgodnie ze wskazuwkami w komunikatach.
;----
; W plecaku postaci trzeba miec Silne Preparaty Antykorozyjne i Tchnienia Khardana w ilosci
; wystarczajacej do wykucia conajmniej jednej puszki.
;----
; Lista rozwijana: "Wytwarzaj tylko raz" daje mozliwosc wyboru czy postac ma kuc do 50 powtorzen/sztuk,
; czy kuc po jednym przedmiocie.
; Domyslnie ustawienie to: "Nie - Kuj do 50 szt." czyli bedzie kuc do 50 sztuk danego przedmiotu.
; Ewentualna zmiana na tej liscie zadziala dopiero po wcisnieciu przycisku Start.
; Czyli jesli juz cos kujesz musisz najpierw wcisnac Stop, poczekac az przestanie kuc i dopiero wcisnac przycisk Start.
;----
; Po wcisnieciu Start skrypt zacznie kuc elementy setu po kazdym wyjatku zatrzyma kucie
; przezuci wyjatek do plecaka juczniaka i zacznie kuc kolejny element zbroi.
; I tak w kolko az wykuje wszystkie elementy danej zbroi.
; Gdy wykuje wszystkie elementy setu podejdzie do pieca przetopi zwykle elementy zbroi i zatrzyma skrypt.
;----
; Skrypt nie kuje pawezy do setow. Ale mozna je przetopic wciskajac przycisk Przetop.
;----
; Przycisk Stop dziala tylko podczas kucia i po przetopieniu przedmiotow.
; Wiec jesli wcisniesz Stop podczas przetapiania skrypt zatrzyma sie dopiero po przetopieniu i
; podejsciu do kowadla.
;-------------------------------------------
; Dodac:
;
; Bledy:
;
;=====================================================
;-- Zmiennych od tego miejsca w dol nie zmieniac --
set %click_X_PrzerwanieSzycia 188
set %click_Y_PrzerwanieSzycia 168
set %click_X_Anuluj 500
set %click_Y_Anuluj 388
set %to_co_ostatnio 0
set %element_startowy 1
set %nr_produktu 0
set %PlecakiZapisane 0
set %part_1 0
set %part_2 0
set %part_3 0
set %part_4 0
set %part_5 0
set %part_6 0
set %part_7 0
set *WAIT 1
set *STOP 0
set %KoniecSztab 0
set #lpc 2000
menu hideEUO
menu clear
menu window color btnface
menu show
menu window size 210 330
menu window title Platnerz Wyjatki 1.6
;=================== Rodzaj setu =====================
menu font size 8
menu text mtmiasto 10 9 Wybierz rodzaj setu:
menu font size 10
menu font bgcolor white
menu combo create mcprodukt 10 28 190
menu combo add mcprodukt Plytowa
menu combo add mcprodukt Pierscieniowa
menu combo add mcprodukt Kolcza
menu combo add mcprodukt Elfia
menu combo add mcprodukt Samuraja
menu combo add mcprodukt Smocza
menu combo select mcprodukt %nr_produktu
repeat
  menu get mcprodukt
  set %nr_produktu #menures
until %nr_produktu > 0
;=================== wybor powtorzen =================
menu font bgcolor btnface
menu text mtWydobycie 10 220 Wytwarzaj tylko raz?
menu font size 10
menu font bgcolor white
menu combo create mcWydobycie 10 235 190
menu combo add mcWydobycie Nie - Kuj do 50 szt.
menu combo add mcWydobycie Tak - Kuj po 1 szt.
menu combo select mcWydobycie 1
;=================== przyciski =======================
menu font bgcolor btnface
menu font size 9
menu font color black
menu font style b
menu font bgcolor btnface
menu button mbstart 10 270 60 24 Start
menu button mbprzetop 75 270 60 24 Przetop
menu button mbstop 140 270 60 24 Stop
menu button mbZapisz 10 300 190 24 Zapisz dane plecaka
;=================== elementy ========================
gosub UstalPlecaki
rysuj_elementy:
menu font style
menu font size 10
menu font bgcolor btnface
menu text mtskil 10 60 Od ktorego elementu setu
menu font bgcolor white
menu combo create mcelement 10 78 190
if %nr_produktu = 1 || %nr_produktu = 6 ;plytowa  i smocza
   {
   menu combo add mcelement Karczek
   menu combo add mcelement Rekawice
   menu combo add mcelement Naramienniki
   menu combo add mcelement Spodnie
   menu combo add mcelement Klata
   menu combo add mcelement Helm
   }
if %nr_produktu = 2 ; pierscieniowa
   {
   menu combo add mcelement Rekawice
   menu combo add mcelement Naramienniki
   menu combo add mcelement Nogawice
   menu combo add mcelement Tunika
   }
if %nr_produktu = 3 ; kolcza
   {
   menu combo add mcelement Czepiec
   menu combo add mcelement Nogawice
   menu combo add mcelement Kolczuga
   }
if %nr_produktu = 4 ; elfia
   {
   menu combo add mcelement Karczek
   menu combo add mcelement Rekawice
   menu combo add mcelement Naramienniki
   menu combo add mcelement Nogawice
   menu combo add mcelement Klata
   }
if %nr_produktu = 5 ; samuraja
   {
   menu combo add mcelement Helm - Kabuto
   menu combo add mcelement Twarz - Mempo
   menu combo add mcelement Naramienniki - Hiro Sode
   menu combo add mcelement Nogawice - suneate
   menu combo add mcelement Tunika - Do
   menu combo add mcelement Rekawice Plytowe
   }
menu combo select mcelement %element_startowy
;===============================================
set #lpc 10
set #menubutton N/A
set %OdPoczatku 1
;=================== petla ===========================
repeat
    if #menubutton = mbstart
      {
      set #menubutton N/A
      menu delete mbstart
      ignoreitem reset
      menu get mcprodukt
      set %nr_produktu #menures
      ;event sysmessage %nr_produktu
      if %nr_produktu = 1
         {
         set %Rodzaj_produktu Plytowa
         set %Itemy_do_pociecia NSH_ISH_MSH_LSH_HSH_OSH
         }
      if %nr_produktu = 2
         {
         set %Rodzaj_produktu Pierscieniowa
         set %Itemy_do_pociecia KMH_YLH_IMH_WLH
         }
      if %nr_produktu = 3
         {
         set %Rodzaj_produktu Kolcza
         set %Itemy_do_pociecia DPH_APH_ZOH
         }
      if %nr_produktu = 4
         {
         set %Rodzaj_produktu Elfia
         set %Itemy_do_pociecia JJQ_MJQ_GJQ_LJQ_ZIQ
         }
      if %nr_produktu = 5
         {
         set %Rodzaj_produktu Samuraja
         set %Itemy_do_pociecia RBP_PWO_WBP_ECP_LWO_ISH
         }
      if %nr_produktu = 6
         {
         set %Rodzaj_produktu Smocza
         set %Itemy_do_pociecia SKO_LKO_YKO_OLO_UKO_MKO
         }
      set %WcisnietoStart 1
      menu get mcWydobycie
      if #menures <> 1
         {
         set %KujRaz 1
         set %IloscPowtorzen 1
         }
      else
         {
         set %KujRaz 0
         set %IloscPowtorzen 50
         }
      gosub SprawdzCzyPlecakiOtwarte

      gosub Skladniki
      gosub SkladnikiInfo
      if #RESULT = dalej
         {
          if jest in %mlotek_kowalski && jest in %kociol && jest in %plecak_wyjatki && jest in %nozyczki && jest in %Preparat && jest in %tchnienie ;|| jest in %kosci
             {
             menu delete mt_nie_masz
             menu delete mt_mlotek_kowalski
             menu delete mt_preparat_antykorozyjny
             menu delete mt_Sztaby
             }
          set #lpc 10
          menu get mcelement
          set %nr_elementu #menures
          for %i 1 6
              {
              if %nr_elementu = %i  ;jesli %nr_elementu = %i
                 {
                 set % . part_ . %i 1 ;to ustawi odpowiedni part_ na 1
                 }
              }
          gosub Rysuj_Opisy
          set %to_co_ostatnio 0
          gosub Licz_wyjatki
          gosub rozpocznij
         }
      }
    if #menubutton = CLOSED ;wcisnieto przycisk X
       {
       menu hide
       set #menubutton N/A
       halt
       }
    if #menubutton = mbprzetop
       {
       set #menubutton N/A
       set %Itemy_do_pociecia NSH_ISH_MSH_LSH_HSH_OSH_KMH_YLH_IMH_WLH_DPH_APH_ZOH_JJQ_MJQ_GJQ_LJQ_RBP_PWO_WBP_ECP_LWO_SKO_LKO_YKO_OLO_UKO_MKO_ZIQ_CIK
       gosub Przetop
       }
    menu get mcprodukt
    set %Nowy_nr_produktu #menures
    if %nr_produktu <> %Nowy_nr_produktu
       {
         set #lpc 2000
         menu delete mcelement
         set %nr_produktu %Nowy_nr_produktu
         goto rysuj_elementy
       }
until #false
;------------------------------------------------------
sub UzyjNarzedzi
  set #lpc 10
  finditem TLH C_ , #charid  ;mlotek kowalski
  wait 2
  set #LOBJECTID #findid
  event macro 17
  set %TimeNarzedzi #scnt2 + 10
  repeat
     if %TimeNarzedzi < #scnt2
        {
        set %TimeNarzedzi #scnt2 + 10
        set #LOBJECTID #findid
        event macro 17
        }
     if #targcurs = 1
        key Esc
  until 560_460 in #CONTSIZE || ( #CONTSIZEX = 560 && #CONTSIZEY = 460 ) ;&& generic_gump in #CONTNAME
  wait 5
return
;--------------------------------------------------
sub ToCoOstatnio
  if %KujRaz = 1 && %IloscPowtorzen = 1 && %WcisnietoStart = 1 ;zaczyna pierwszy raz kuc
     {
     ;event sysmessage KujRaz %KujRaz IloscPowtorzen %IloscPowtorzen WcisnietoStart %WcisnietoStart
     click 412 417  ;przycisk to co ostatnio  412 417
     key BACK
     key BACK
     key BACK
     msg %IloscPowtorzen
     wait 3
     set %WcisnietoStart 0
     }
  if %KujRaz = 0 && %IloscPowtorzen = 50 && %WcisnietoStart = 1
     {
     ;event sysmessage KujRaz %KujRaz IloscPowtorzen %IloscPowtorzen WcisnietoStart %WcisnietoStart
     click 412 417  ;przycisk to co ostatnio  412 417
     key BACK
     key BACK
     key BACK
     msg %IloscPowtorzen
     wait 3
     set %WcisnietoStart 0
     }
  if %KujRaz = 1 && %OdPoczatku = 0
     {
     click 138 390  ;przycisk to co ostatnio
     return
     }
  if %to_co_ostatnio = 0
     {
     gosub Rodzaj_setu
     if #RESULT = PetalPrzyciskow
        return PetalPrzyciskow
     }
  else
     click %click_X_ToCoOstatnio %click_Y_ToCoOstatnio  ;przycisk to co ostatnio
  set %to_co_ostatnio 0
  set %OdPoczatku 0
return
;--------------------------------------------------
sub rozpocznij
  set #lpc 10
  gosub PrzeniesSztaby
  set %JestWyjatek #false
  set %WyjdzZPetli 0
  ;pause
  set #sysmsgcol 1090
  repeat
      set %PodejdzDoKowadla 0
      if #menubutton = mbstop
        {
        gosub Wcisnieto_Stop
        return
        }
      gosub SprawdzCzyPlecakiOtwarte
      gosub UzyjNarzedzi
      gosub ToCoOstatnio
      if #RESULT = PetalPrzyciskow
         return

      set %TimeKlikWMenu #scnt2 + 10
      repeat
         if %TimeKlikWMenu < #scnt2
            {
             gosub ToCoOstatnio ;%KujRaz
             if #RESULT = PetalPrzyciskow
                return
             set %TimeKlikWMenu #scnt2 + 10
            }
         if Musisz_byc_blisko in #sysmsg
            {
            gosub PodejdzDoKowadla
            set %PodejdzDoKowadla 1
            break
            }
      until #targcurs = 1
      if %PodejdzDoKowadla = 1
         {
         set %PodejdzDoKowadla 0
         continue
         }
      finditem ENK C_ , %Plecak_roboczy2 ;szuka sztab w plecaku
      wait 2
      if #findcnt = 0
         {
          key Esc
          gosub Przetop
          if #RESULT = KoniecKucia
             return
          gosub PodejdzDoKowadla
          continue
         }
      set #LTARGETID #findid
      set #LTARGETX #findx
      set #LTARGETY #findy
      set #LTARGETKIND 1
      event macro 22
      set %TimeKlikWSkore #scnt + 20
      repeat
         if %TimeKlikWSkore < #scnt
            {
             event macro 22
             set %TimeKlikWSkore #scnt + 20
            }
      until #targcurs = 0

      set %czas_konca #scnt + 10
      set %Robi 0
      set %time_okna #scnt + 6

      repeat
         if %time_okna < #scnt
            {
            for %ji 1 5
                {
                 scanjournal %ji
                 if Brakuje_Ci in #journal
                    {
                    set %KoniecSztab 1
                    }
                }
            break ;set %Robi 1
            }
         if %czas_konca < #scnt
            {
            gosub Przetop
            if #RESULT = KoniecKucia
               return
            event sysmessage Koniec kucia. Skrypt czeka.
            gosub Rysuj_przycisk_start
            return ;PetlaPrzyciskow
            }
      until #contsize = 380_200 || %KujRaz = 1

      if %KoniecSztab = 1
         {
         ;set %KoniecSztab 0
         break
         }
      gosub SprawdzCzyPlecakiOtwarte

      repeat
          if *STOP = 1  ;jesli glodny
             {
             click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia ;przerywa szycie
             wait 7s
             if Wyjatkowej_jakosci in #sysmsg
                {
                set %JestWyjatek #true
                }
             set *WAIT 0
             repeat
             until *STOP = 0
             if %JestWyjatek = #true
                {
                break
                }
             else
                {
                set %to_co_ostatnio 1
                continue
                }
             }
          if #menubutton = mbstop
             {
             set %TimeKoniecKucia #scnt + 6
             gosub Wcisnieto_Stop
             repeat
                 if Wyjatkowej_jakosci in #sysmsg
                    {
                    click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia ;przerywa szycie
                    wait 7s
                    break
                    }
             until %TimeKoniecKucia < #scnt
             return
             }
          if %KujRaz = 1
             {
             set %TimeKoniecKucia #scnt2 + 54
             ;set #lpc 1000
             repeat
                 if *STOP = 1
                    {
                    set *WAIT 0
                    repeat
                       if wyjatkowej_jakosci in #sysmsg
                          {
                          set %JestWyjatek #true
                          set %WyjdzZPetli 1
                          }
                    until *STOP = 0
                    if %JestWyjatek = #true
                       break
                    }
                 if Wybierz in #sysmsg
                    {
                    gosub Zlom
                    }
                 scanjournal 2
                 if Lista in #journal
                    {
                    set %BrakSztab 1
                    gosub Przetop
                    if #RESULT = KoniecKucia
                       return
                    gosub PodejdzDoKowadla
                    break
                    }
                 scanjournal 1
                 if Anulowano in #journal ;zabraklo sztabek
                    {
                    finditem %Itemy_do_pociecia C_ , %Plecak_roboczy2
                    wait 2
                    if #findcnt > 3 && #findcnt < 11 ; koniec kucia
                       {
                       gosub Przetop
                       if #RESULT = KoniecKucia
                          return
                       gosub PodejdzDoKowadla
                       set #sysmsgcol 80
                       event sysmessage Masz za mało sztab. Skrypt zatrzymany.
                       return
                       }
                    }
             until _Wykul in #sysmsg ;|| %TimeKoniecKucia < #scnt2
             if wyjatkowej_jakosci in #sysmsg
                {
                set %JestWyjatek #true
                set %WyjdzZPetli 1
                }
             set #lpc 10
             if %WyjdzZPetli = 0
                break
             if %BrakSztab = 1
                {
                set %BrakSztab 0
                break
                }
             }
          else
             {
             gosub SprawdzGumpa
             }
          if Wybierz in #sysmsg && %KujRaz = 0
             {
             gosub Zlom
             }
          if Wyjatkowej_jakosci in #sysmsg && %KujRaz = 0
             {
             click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia ;przerywa szycie
             wait 6s
             set %WyjdzZPetli 1
             set %JestWyjatek #true
             }
          if W_pojemnik_nie_ma_juz_miejsca in #sysmsg
             {
             break
             }
      until %WyjdzZPetli = 1
      set %WyjdzZPetli 0
      set %OdPoczatku 1
      ;koniec_robienia:
      if %JestWyjatek = #false && %KujRaz = 1
         {
         set %to_co_ostatnio 1
         continue
         }
      set %JestWyjatek #false
      gosub Przenies_Wyjatki
      gosub Licz_wyjatki
      ;gosub Przetop
      if #menubutton = mbstop
        {
        gosub Wcisnieto_Stop
        return
        }
      if %KoniecSztab = 0
         {
          gosub Skladniki
          if jest notin %mlotek_kowalski || jest notin %Sztaby  || jest notin %Preparat
             {
             if jest notin %mlotek_kowalski
                set %brakuje_1 %mlotek_kowalski
             if jest notin %Preparat
                set %brakuje_2 %Preparat
             if jest notin %Sztaby
                set %brakuje_3 %Sztaby

             Display ok Nie masz: $ %brakuje_1 $ %brakuje_2 $ %brakuje_3
             gosub Rysuj_przycisk_start
             return
             }
         }
      set %KoniecSztab 0
      if %czy_jest_wyjatek = 0
         {
         set %to_co_ostatnio 1
         }
      else
         {
         gosub WybierzKolejnyPrzedmiot
         if #RESULT = PetalPrzyciskow
            {
            gosub Przetop
            if #RESULT = KoniecKucia
               return
            if #menubutton = mbstop
              {
              gosub Wcisnieto_Stop
              return
              }
            gosub PodejdzDoKowadla
            set #sysmsgcol 75
            event sysmessage Se , t wykuty. Skrypt czeka.
            return
            }
         }

  until #false
return

;--------------------------------------------------
sub Skladniki
  set %Ilosc_pasty 0
  set %Ilosc_tchnien 0
  if %Plecak_roboczy <> #backpackid
     {
     set #lobjectid %Plecak_roboczy ;otwiera plecak roboczy
     set #NEXTCPOSX %Pozycja_X_Plecak_roboczy
     set #NEXTCPOSY %Pozycja_Y_Plecak_roboczy
     event macro 17
     wait 3
     set #lobjectid %Plecak_roboczy2 ;otwiera plecak roboczy
     set #NEXTCPOSX %Pozycja_X_Plecak_roboczy2
     set #NEXTCPOSY %Pozycja_Y_Plecak_roboczy2
     event macro 17
     wait 3
     }

  finditem TLH C_ , #charid  ;mlotek kowalski
  wait 2
  if #findkind = -1
     set %mlotek_kowalski Mlotka , #spc , Kowalskiego
  else
     set %mlotek_kowalski jest

  finditem WLF C_ , #backpackid ; preparat antykorozyjny
  wait 2
  if #findkind = -1
     set %Preparat Preparatu , #spc , Antykorozyjnego!!
  else
     set %Preparat jest

  finditem ENK C_ , %Plecak_roboczy ; sztaby
  wait 2
  if #findstack < 50
     {
     finditem ENK C_ , %Plecak_roboczy2 ; sztaby
     wait 2
     if #findstack < 50
        {
        set %Sztaby Sztab , #spc , lub , #spc , jest , #spc , ich , #spc , mniej , #spc , niz , #spc , 50
        }
     else
        set %Sztaby jest
     }
  else
     set %Sztaby jest
return
;--------------------------------------------------
sub Rodzaj_setu
  if Plytowa in %Rodzaj_produktu
     {
     click 360 130 ; plyta
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     if %part_1 = 1
        click 190 210 ;- karczek
     if %part_2 = 1
        click 330 210 ;- rekawice
     if %part_3 = 1
        click 470 210 ;- naramienniki
     if %part_4 = 1
        click 190 305 ;- nogawice
     if %part_5 = 1
        click 330 305 ;- klata
     if %part_6 = 1
        {
        click 430 130 ;- helmy
        repeat
           scanjournal 1
           if Anulowano. in #journal
              gosub UzyjNarzedzi
        until 560_460 in #CONTSIZE
        wait 3
        click 180 305 ;- karczek
        wait 3
        }
     }
  if Pierscieniowa in %Rodzaj_produktu
     {
     click 120 130 ; pierscieniowa
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     if %part_1 = 1
        click 220 210 ;- rekawice
     if %part_2 = 1
        click 370 210 ;- naramienniki
     if %part_3 = 1
        click 220 305 ;- nogawice
     if %part_4 = 1
        click 370 305 ;- tunika
     if %part_5 = 1
        {
        click %click_X_Anuluj %click_Y_Anuluj
        gosub Przetop
        event sysmessage SE , T ZROBIONY, Koniec kucia.
        gosub ZarujParty
        gosub Rysuj_przycisk_start
        return PetalPrzyciskow
        }
     }
  if Kolcza in %Rodzaj_produktu
     {
     click 260 130 ; Kolcza
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     if %part_1 = 1
        click 220 210 ;- czepiec
     if %part_2 = 1
        click 370 210 ;- nogawice
     if %part_3 = 1
        click 220 305 ;- tunika
     if %part_4 = 1
        {
        click %click_X_Anuluj %click_Y_Anuluj
        gosub Przetop
        event sysmessage SE , T ZROBIONY, Koniec kucia.
        gosub ZarujParty
        gosub Rysuj_przycisk_start
        return PetalPrzyciskow
        }
     }
  if Elfia in %Rodzaj_produktu
     {
     click 370 360 ; Elfia
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     if %part_1 = 1
        click 190 200 ;- karczek
     if %part_2 = 1
        click 330 220 ;- rekawice
     if %part_3 = 1
        click 470 200 ;- naramienniki
     if %part_4 = 1
        click 190 290 ;- nogawice
     if %part_5 = 1
        click 330 320 ;- klata
     if %part_6 = 1
        {
        click %click_X_Anuluj %click_Y_Anuluj
        gosub Przetop
        event sysmessage SE , T ZROBIONY, Koniec kucia.
        gosub ZarujParty
        gosub Rysuj_przycisk_start
        return PetalPrzyciskow
        }
     }
  if Samuraja in %Rodzaj_produktu
     {
     click 200 360 ; Samuraja
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     if %part_1 = 1
        click 190 210 ;- czapka
     if %part_2 = 1
        click 330 210 ;- twarz
     if %part_3 = 1
        click 470 210 ;- naramienniki
     if %part_4 = 1
        click 190 305 ;- nogawice
     if %part_5 = 1
        click 330 305 ;- klata
     if %part_6 = 1
        {
        click 360 130
        repeat
        until 560_460 in #CONTSIZE
        wait 3
        click 330 210
        }
     }
  if Smocza in %Rodzaj_produktu
     {
     click 520 130 ; strzalka w prawo
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     click 120 130 ; Smocza
     repeat
     until 560_460 in #CONTSIZE
     wait 3
     if %part_1 = 1
        click 190 210 ;- karczek
     if %part_2 = 1
        click 330 210 ;- rekawice
     if %part_3 = 1
        click 470 210 ;- naramienniki
     if %part_4 = 1
        click 190 305 ;- nogawice
     if %part_5 = 1
        click 330 305 ;- klata
     if %part_6 = 1
        click 470 305 ;- helm
     }
return
;--------------------------------------------------
sub Przetop
  finditem OUJ_CUJ_JBG G_6 ;typ pieca
  wait 2
  set %PiecID #FINDID
  move #findx #findy 1 20s
  ; otwieranie plecaka juczniaka
  event macro 1 0 podejdzcie
  wait 1s
  gosub OtworzPlecaki %JuczniakID %Pozycja_X_Plecak_roboczy %Pozycja_Y_Plecak_roboczy %Plecak_roboczy
  repeat
      finditem %Plecak_roboczy2 C_ , %Plecak_roboczy
      wait 2
          set #LOBJECTID %PiecID
          event macro 17
          set %TimePiec #scnt2 + 20
          repeat
              if %TimePiec < #scnt2
                 {
                 set #LOBJECTID #FINDID
                 event macro 17
                 set %TimePiec #scnt2 + 20
                 }
          until #targcurs = 1  ;jest celownik
          set #ltargetkind 1
          set #LTARGETX #FINDX
          set #LTARGETY #FINDY
          set #LTARGETID #FINDID
          event macro 22
          set %TimeKwSztaby #scnt2 + 30
          repeat
              if %TimeKwSztaby < #scnt2 && #targcurs = 1
                 {
                 event macro 22
                 set %TimeKwSztaby #scnt2 + 30
                 }
              if Anulowano. in #sysmsg
                 break
              scanjournal 1
              if W_tym_pojemniku_nie_ma_nic in #journal ;sa sztaby ale jest ich za malo i nie ma co przetapiac
                 {
                 set #sysmsgcol 80
                 event sysmessage Masz za malo sztab na wykucie przedmiotu. Skrypt zatrzymany.
                 gosub Rysuj_przycisk_start
                 return KoniecKucia
                 }
          until Udalo in #journal
          if Udalo in #journal
             break
  until #false

  gosub OtworzPlecaki %JuczniakID %Pozycja_X_Plecak_roboczy %Pozycja_Y_Plecak_roboczy %Plecak_roboczy
  gosub OtworzPlecaki %Plecak_roboczy2 %Pozycja_X_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy2 N/A

  repeat
      finditem ENK C_ , #backpackid
      wait 2
      if #WEIGHT > 300
         {
         exevent drag #findid #findstack
         wait 5
         exevent dropc %Plecak_roboczy2
         wait 5
         }
      finditem %Itemy_do_pociecia C_ , %Plecak_roboczy2
      wait 2
      if #findcnt = 0
         break
  until Udalo notin #sysmsg

  finditem ENK C_ , #backpackid
  wait 2
  if #findcnt > 0
     {
     exevent drag #findid #findstack
     wait 5
     exevent dropc %Plecak_roboczy2
     wait 5
     }
  event sysmessage Przedmioty przetopione.
  if *STOP = 1
     {
     set *WAIT 0
     repeat
     until *STOP = 0
     }
return
;--------------------------------------------------
sub Przenies_Wyjatki
    event sysmessage Szukam Wyjatkow.
    set #lpc 10
    finditem %Itemy_do_pociecia C_ , %Plecak_roboczy2
    wait 2
    for #findindex 1 #findcnt
      {
        event Property #findid
        wait 2
        if Wyjatkowej in #property
           {
           exevent drag #findid 1
           wait 5
           exevent dropc %Plecak_na_Wyjatki 200 200
           wait 5
           set %czy_jest_wyjatek 1
           }
      }
    ;ignoreitem reset
return
;--------------------------------------------------
sub WybierzKolejnyPrzedmiot
  for %i 1 6
      {
      if % . part_ . %i = 1  ;jesli part_1 = 1
         {
         set % . part_ . %i 0 ;to part_1 ustawi na 0
         set %j ( %i + 1 )
         set % . part_ . %j 1 ;a kolejny np: part_2 na 1
         ;display ok % , part_ , %i % . part_ . %i
         ;display ok % , part_ , %j % . part_ . %j
         break
         }
      }

  if %part_7 = 1
     {
     set %part_7 0
     event sysmessage SE , T Wykuty, Ide przetopic przedmioty.
     gosub Rysuj_przycisk_start
     return PetalPrzyciskow
     }
return
;--------------------------------------------------
sub SprawdzGumpa
  set #lpc 2000
  set %dziennik #SYSMSG
  ;event sysmessage dziennik %dziennik
  str Pos %dziennik )
  set %Pozycja_nawiasu #StrRes
  set %end %Pozycja_nawiasu - 2
  str Mid %dziennik 2 %end
  set %Tyle_z_Tylu #StrRes
  str Pos %Tyle_z_Tylu z
  set %z_end #StrRes - 2
  str Mid %Tyle_z_Tylu 1 %z_end
  set %Pierwsza_wartosc #StrRes
  ;event sysmessage Pierwsza_wartosc %Pierwsza_wartosc
  str Pos %Tyle_z_Tylu _
  set %__start #StrRes + 3
  str Len %Tyle_z_Tylu
  set %Dlugosc #StrRes
  str Mid %Tyle_z_Tylu %__start %Dlugosc
  set %Druga_wartosc #StrRes
  ;event sysmessage Wartosci: %Pierwsza_wartosc z %Druga_wartosc
  for %i 1 5
      {
      scanjournal %i
      if Brakuje_Ci in #journal
         {
         set %WyjdzZPetli 1
         set #lpc 20
         set %KoniecSztab 1
         return
         }
      }
  if %Pierwsza_wartosc > %Druga_wartosc
     {
     click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia  ;przerywa prace
     set %WyjdzZPetli 1
     wait 6s
     set #lpc 20
     return
     }
  if %Pierwsza_wartosc = %Druga_wartosc
     {
     scanjournal 1
     if #JCOLOR = 40
        {
        click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia ;przerywa prace
        wait 6s
        }
     set %WyjdzZPetli 1
     }
  else
     {
     set #lpc 20
     return
     }
  set #lpc 20
return
;--------------------------------------------------
sub Rysuj_przycisk_start
  menu font color black
  menu font style b
  menu font bgcolor btnface
  menu button mbstart 10 270 60 24 Start
return
;--------------------------------------------------
sub Rysuj_Opisy
  set #lpc 2000
  ;pause
  menu font bgcolor btnface
  menu font size 9
  menu font color green
  menu font style b
  if %nr_produktu = 1 || %nr_produktu = 6
     {
     menu text mt_el_1 10 125 Karczek :
     menu text mt_el_2 10 140 Rekawice :
     menu text mt_el_3 10 155 Naramienniki :
     menu text mt_el_4 10 170 Spodnie :
     menu text mt_el_5 10 185 Klata :
     menu text mt_el_6 10 200 Helm :
     menu text mt_el_opis_1 170 125 0
     menu text mt_el_opis_2 170 140 0
     menu text mt_el_opis_3 170 155 0
     menu text mt_el_opis_4 170 170 0
     menu text mt_el_opis_5 170 185 0
     menu text mt_el_opis_6 170 200 0
     }
  if %nr_produktu = 2
     {
     menu text mt_el_1 10 125 Rekawice :
     menu text mt_el_2 10 140 Naramienniki :
     menu text mt_el_3 10 155 Nogawice :
     menu text mt_el_4 10 170 Tunika :
     menu text mt_el_opis_1 170 125 0
     menu text mt_el_opis_2 170 140 0
     menu text mt_el_opis_3 170 155 0
     menu text mt_el_opis_4 170 170 0
     }
  if %nr_produktu = 3
     {
     menu text mt_el_1 10 125 Czepiec :
     menu text mt_el_2 10 140 Nogawice :
     menu text mt_el_3 10 155 Kolczuga :
     menu text mt_el_opis_1 170 125 0
     menu text mt_el_opis_2 170 140 0
     menu text mt_el_opis_3 170 155 0
     }
  if %nr_produktu = 4
     {
     menu text mt_el_1 10 125 Karczek :
     menu text mt_el_2 10 140 Rekawice :
     menu text mt_el_3 10 155 Naramienniki :
     menu text mt_el_4 10 170 Nogawice :
     menu text mt_el_5 10 185 Klata :
     menu text mt_el_opis_1 170 125 0
     menu text mt_el_opis_2 170 140 0
     menu text mt_el_opis_3 170 155 0
     menu text mt_el_opis_4 170 170 0
     menu text mt_el_opis_5 170 185 0
     }
  if %nr_produktu = 5
     {
     menu text mt_el_1 10 125 Helm - Kabuto :
     menu text mt_el_2 10 140 Twarz - Mempo :
     menu text mt_el_3 10 155 Naramienniki - Hiro Sode :
     menu text mt_el_4 10 170 Nogawice - suneate :
     menu text mt_el_5 10 185 Tunika - Do :
     menu text mt_el_6 10 200 Rekawice Plytowe :
     menu text mt_el_opis_1 170 125 0
     menu text mt_el_opis_2 170 140 0
     menu text mt_el_opis_3 170 155 0
     menu text mt_el_opis_4 170 170 0
     menu text mt_el_opis_5 170 185 0
     menu text mt_el_opis_6 170 200 0
     }
  set #lpc 10
  menu font color green
return
;--------------------------------------------------
sub Licz_wyjatki
  set #lpc 2000
  str Pos %Itemy_do_pociecia _  ; rozdziela typy itemow
  set %Pozycja_znaku #StrRes
  set %start 1
  set %end %Pozycja_znaku - 1
  for %i 1 6
    {
    str Mid %Itemy_do_pociecia %start %end
    set %zm_ . %i #StrRes ;powstaja zmienne: %zm_1 do %zm_6
    set %start ( %start + 4 )
    }

  for %i 1 6
      {
      finditem %zm_ . %i C_ , %Plecak_na_Wyjatki
      wait 2
      if #findkind <> -1
         {
         event Property #findid
         wait 2
         if Wyjatkowej in #property
            {
            menu Set mt_el_opis_ , %i #findcnt
            }
         }
      ignoreitem #findid
      }
  ignoreitem reset
  set #lpc 10
return
;--------------------------------------------------
sub ZarujParty
  for %i 1 6
      {
      set % . part_ . %i  ;to ustawi odpowiedni part_ na 1
      }
return
;--------------------------------------------------
sub SkladnikiInfo
  set #lpc 1000
    menu font bgcolor btnface
    if jest notin %mlotek_kowalski
       {
       menu font size 9
       menu font color black
       menu text mt_nie_masz 10 110 Nie masz:
       menu font color red
       menu text mt_mlotek_kowalski 10 125 Mlotka Kowalskiego
       }
    if jest notin %Preparat
       menu text mt_preparatAnty 10 155 Preparatu Antykorozyjnego
    if jest notin %Sztaby
       menu text mt_Sztaby 10 200 Sztaby
    set #menubutton N/A
    if jest in %mlotek_kowalski || jest in %Preparat || jest in %Sztaby
       {
       set #lpc 10
       return dalej
       }
return
;--------------------------------------------------
sub UstalPlecaki
  set %PlecakPostaci 0
  display yesno $-- Ustawianie plecaka. -- $Musisz miec w glownym plecaku postaci jakis zwykly plecak. $Jesli posiadasz ten plecak wcisniej Tak. $ $Nastepnie wyceluj celownik w juczniaka. $Poczekaj, az plecak sie otworzy i przesun go gdzies bo bedzie otwieral sie w tym miejscu.. $A nastepnie wcisnij przycisk: Zapisz dane plecaka.
  if #DISPRES = Yes
     {
      ;display ok $Wyceluj celownik w juczniaka. $Poczekaj, az plecak sie otworzy i przesun go gdzies bo bedzie otwieral sie w tym miejscu.. $A nastepnie wcisnij przycisk: Zapisz dane plecaka.
      set #targcurs 1
      repeat
      until #targcurs = 0
      if #charid = #ltargetid
         {
         event sysmessage Musisz wycelowac w swojego juczniaka lub golema.
         set #targcurs 1
         repeat
         until #targcurs = 0
         set #lobjectid #ltargetid
         set %JuczniakID #ltargetid
         }
      else
         {
         set #lobjectid #ltargetid
         set %JuczniakID #ltargetid
         }
      event macro 17
      repeat
      until #menubutton = mbZapisz

      set #menubutton N/A
      set %Plecak_roboczy #contid
      set %JuczniakID #ltargetid
      set %Pozycja_X_Plecak_roboczy #CONTPOSX
      set %Pozycja_Y_Plecak_roboczy #CONTPOSY
      set #sysmsgcol 75
      event sysmessage Dane plecaka zapisane

      finditem ZJF C_ , %Plecak_roboczy
      wait 2
      if #findcnt = 0  ; nie znaleziono
         {
          finditem ZJF C_ , #backpackid
          wait 2
          if #findcnt > 0
             {
             for #findindex 1 #findcnt
               {
               event Property #findid
               if Magiczny notin #property
                  {
                   exevent drag #findid 1
                   wait 5
                   exevent dropc %Plecak_roboczy 10 10
                   wait 5
                   set %Plecak_roboczy2 #findid
                   set #lobjectid #findid
                   event macro 17
                   set %TimePlecakRoboczy2 #scnt2 + 10
                   repeat
                       if %TimePlecakRoboczy2 < #scnt2
                          {
                          set %TimePlecakRoboczy2 #scnt2 + 10
                          event macro 17
                          }
                   until #contid = %Plecak_roboczy2
                   break
                  }
               }

             set %Pozycja_X_Plecak_roboczy2 %Pozycja_X_Plecak_roboczy - 180
             set %Pozycja_Y_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy
             set %Plecak_na_Wyjatki %Plecak_roboczy
             contpos %Pozycja_X_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy2
             event sysmessage Dane plecaka zapisane
             set %PlecakiZapisane 1
             }
          else
             {
             menu hide
             display ok $Musisz miec jakis zwykly plecak w glownym plecaku postaci bo inaczej skrypt nie bedzie dzialal.
             halt
             }
         }
      else
         {
         set %Plecak_roboczy2 #findid
         set #lobjectid #findid
         event macro 17
         set %TimePlecakRoboczy2 #scnt2 + 10
         repeat
             if %TimePlecakRoboczy2 < #scnt2
                {
                set %TimePlecakRoboczy2 #scnt2 + 10
                event macro 17
                }
         until #contid = %Plecak_roboczy2

         set %Pozycja_X_Plecak_roboczy2 %Pozycja_X_Plecak_roboczy - 180
         set %Pozycja_Y_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy
         set %Plecak_na_Wyjatki %Plecak_roboczy
         contpos %Pozycja_X_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy2
         event sysmessage Dane plecaka zapisane
         set %PlecakiZapisane 1
         }
      ;execute cmd.exe /c "del %Plik && echo s , et , #spc , % , PlecakNaJedzenie , #spc , %PlecakNaJedzenie >> %Plik && echo s , et , #spc , % , Jestem_Wilkolak , #spc , %Jestem_Wilkolak >> %Plik && echo s , et , #spc , % , Jestem_Wampir , #spc , %Jestem_Wampir >> %Plik && echo exi , t >> %Plik "
     }
   else
     {
     menu hide
     display ok $Musisz miec juczniaka i jakis zwykly plecak w glownym plecaku postaci inaczej skrypt nie bedzie dzialal. $Skrypt wylaczony.
     halt
     }
return
;--------------------------------------------------
sub Wcisnieto_Stop
   event sysmessage Skrypt zatrzymany i czeka.
   click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia
   set #menubutton N/A
   gosub Rysuj_przycisk_start
   gosub ZarujParty
return
;--------------------------------------------------
sub PodejdzDoKowadla
   finditem KBG_ZAG G_6 ; kowadlo
   wait 2
   move #FINDX #FINDY 1 20s
   event macro 1 0 za mna
   wait 5
return
;--------------------------------------------------
sub OtworzPlecaki ; ( id_plecaka lub juki, x_plecaka, y_plecaka, opcjonalnie id plecaka )
  if N/A notin %4
     {
     set %CoOtworzyc %1
     set %IdPlecaka %4
     }
  else
     {
     set %CoOtworzyc %1
     set %IdPlecaka %1
     }
  set %czasPJ #scnt2 + 20 ;czas plecaka juczniaka
  set #LOBJECTID %CoOtworzyc
  event macro 17
  repeat
    if %czasPJ < #scnt2
       {
       set #LOBJECTID %CoOtworzyc
       event macro 17
       set %czasPJ #scnt2 + 20
       }
  ;event sysmessage Do otwarcie: %IdPlecaka otwarty: #contid
  until %IdPlecaka = #contid
  wait 3
  contpos %2 %3
  wait 3
return
;--------------------------------------------------
sub SprawdzCzyPlecakiOtwarte
  set %Sprawdz_X_PlecakRoboczy %Pozycja_X_Plecak_roboczy + 100
  set %Sprawdz_Y_PlecakRoboczy %Pozycja_Y_Plecak_roboczy + 40
  set %Sprawdz_X_PlecakRoboczy2 %Pozycja_X_Plecak_roboczy2 + 100
  set %Sprawdz_Y_PlecakRoboczy2 %Pozycja_Y_Plecak_roboczy2 + 40

  if %Plecak_roboczy <> #contid  ;jesli kontener ktory jest na wiezchu nie jest plecakiem roboczym czyli plecakiem juczniaka
     {
     ;click %click_X_PrzerwanieSzycia %click_Y_PrzerwanieSzycia
     ;wait 6s
     click %Sprawdz_X_PlecakRoboczy %Sprawdz_Y_PlecakRoboczy  ;kliknij w miejsce w ktorym powinien byc
     if %Plecak_roboczy <> #contid  ;jesli kontener ktory jest na wiezchu nie jest plecakiem roboczym czyli plecakiem juczniaka
        {
        gosub OtworzPlecaki %JuczniakID %Pozycja_X_Plecak_roboczy %Pozycja_Y_Plecak_roboczy %Plecak_roboczy
        gosub OtworzPlecaki %Plecak_roboczy2 %Pozycja_X_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy2 N/A
        return
        }
     }
  click %Sprawdz_X_PlecakRoboczy2 %Sprawdz_Y_PlecakRoboczy2
  if %Plecak_roboczy2 <> #contid ;jesli plecak juczniaka jest otwarty sprawdz plecak roboczy2
     {
     ;gosub OtworzPlecaki %Plecak_roboczy %Pozycja_X_Plecak_roboczy %Pozycja_Y_Plecak_roboczy
     gosub OtworzPlecaki %Plecak_roboczy2 %Pozycja_X_Plecak_roboczy2 %Pozycja_Y_Plecak_roboczy2 N/A
     }
return
;--------------------------------------------------
sub PrzenosPreparatyTchnienia ; ID_przedmiotu | Gdzie ma szukac | Gdzie ma przeniesc | Ilosc
  finditem %1 C_ , %2
  wait 2
  if wszystko in %4
     exevent drag #findid #findstack
  if jeden in %4
     exevent drag #findid 1
  wait 5
  exevent dropc %3
  wait 5
return
;---------------------------------------------------
sub PrzeniesSztaby
  finditem ENK C_ , %Plecak_roboczy
  wait 2
  if #findcnt > 0
     {
     for #findindex 1 #findcnt
         {
         exevent drag #findid #findstack
         wait 5
         exevent dropc %Plecak_roboczy2
         wait 5
         }
     }
return
;---------------------------------------------------
sub Zlom
  finditem %Itemy_do_pociecia C_ , %Plecak_roboczy2
  wait 2
  for #findindex 1 #findcnt
      {
      if wyjatkowej_jakosci in #sysmsg
         return
      event Property #findid
      wait 2
      if Wyjatkowej notin #property
         {
         ignoreitem #findid
         }
      }
return