#!/usr/local/bin/liquidsoap

PASSWORD=argv(1)

set("log.file.path","gst.log")
set("log.stdout",true)
set("log.level", 5)
set("encoder.encoder.export",["Rob Canning","Radio Kulturo","Network Compositions","Classical","2010","00","SPC"])

def kulturo_player(p, d, s)
    x = input.gstreamer.audio(pipeline="uridecodebin uri=#{s}")
    x = echo(x, delay=d, feedback=-8.0 )
    x = stereo.pan(pan=p, field=90., x)
   x
end

ie = kulturo_player(-0.9, 0.38, "mms://live1.rte.ie/wmtencoder/lyric.wma")
be = kulturo_player(-0.7, 0.77, "http://mp3.streampower.be/klaracontinuo-mid")
fr = kulturo_player(-0.5, 0.66, "http://mp3.live.tv-radio.com/francemusique/all/francemusiquehaut")
pt = kulturo_player(-0.3, 0.55, "mms://195.245.168.21/antena2")
rm = kulturo_player(-0.1, 0.44, "http://stream2.srr.ro:8022/")
lit = kulturo_player(-0.1, 0.40, "mms://82.135.234.194/Klasika")
dk = kulturo_player( 0.1, 0.30, "http://live-icy.gss.dr.dk:8000/Channel1_HQ.mp3")
pl = kulturo_player( 0.3, 0.80, "mms://stream.polskieradio.pl/program2")
es = kulturo_player( 0.4, 0.70, "http://195.10.10.206/rtve/radioclasica.mp3")
at = kulturo_player( 0.7, 0.60, "http://srvhost24.serverhosting.apa.net:8000/rsdstream32")
uk = kulturo_player( 0.9, 0.50, "mms://wmlive-nonacl.bbc.net.uk/wms/bbc_ami/radio3/radio3_bb_live")

stereo = add(normalize=false,[ie,be,fr,pt,rm,dk,pl,es,at,uk,lit])
def stream (c,m,o)
    out = output.icecast(c,
    host="localhost",
    port=8800,
    description="Radio Kulturo - Live ReBroadCastReMix",
    genre="Network Music",url="http://radiokulturo.net",
    password = "#{PASSWORD}",
    mount = m,
    fallible=true,
    o
    )
    out
end

stream(%vorbis,"rk-stereo.ogg",stereo)
stream(%opus,"rk-stereo.opus",stereo)
#stream(%mp3,"rk-stereo.mp3",stereo)
stream(%aacplus,"rk-stereo.aac",stereo)
#stream(%vorbis(channels=8),"rk-8channel.ogg",oct)