Cloud function and deep sleep

#define WATCHDOG_TIMEOUT 10000  //10 000 ms for watchdog to reset the device in case of cloud failure
#define INTERVAL 10
#define EVENT_NAME "test_Safe"

bool eventPending;      // signal for receiving feedback from cloud on event we sent
bool safeModePending;

// Handler for cloud event
void eventHandler(const char *event, const char *data)
{
    eventPending = false;
}

// Cloud function to send device to Safe Mode for user firmware upgrade
int gotoSafeMode(String command){
    safeModePending=true;
    return 1;
}


void setup()
{
    Particle.subscribe(EVENT_NAME, eventHandler);   // set up validaton mechanism
    safeModePending= false;
    Particle.function("safe", gotoSafeMode);        // set up cloud function for DFU
}


void loop()
{

    RGB.control(true);              // take over rgb led control

    if(!Particle.connected()){      // maybe not needed, but to be on safe side
        RGB.color(255,0,0);         // show user red light indicator on no-connection state
        Particle.connect();         // reconnect to cloud
        Particle.process();         // and run process once for fun
    }

    RGB.color(0, 255, 0);           // show user green light indicator on ok state

    eventPending = true;                            // initialize flag for event below
    Particle.publish(EVENT_NAME, "Plop");

    long watchDogTimer = millis(); // establish watchdog to verify cloud got the data
    while(eventPending){              // wait for signal that we received the event sent
        RGB.color(255,255,0);         // show yellow indicator on waiting
        Particle.process();         // while waiting, give OS time to process
        if(millis() > watchDogTimer+WATCHDOG_TIMEOUT){ // watchdog resets system if takes too long
                System.reset();
        }
    }
    RGB.color(0,0,0);         // show black indicator on completion

    if(safeModePending){            // if we have received req to go to safe mode
        System.enterSafeMode();    //  enter it here
    }

    delay(2000);                                // a short delay for fun
    System.sleep(SLEEP_MODE_DEEP, INTERVAL);     // we get this far. DEEP SLEEP resets the device.
}