# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Contributer: graysky <graysky AT archlinux DOT us>
pkgname=('quodlibet' 'quodlibet-libs' 'exfalso')
pkgbase=quodlibet
pkgver=2.4.1
pkgrel=2
arch=('i686' 'x86_64')
url="http://code.google.com/p/quodlibet/"
license=('GPL2')
makedepends=('intltool')
options=('!makeflags')
source=(http://quodlibet.googlecode.com/files/${pkgname}-${pkgver}.tar.gz)
sha1sums=('4db812f0b447805a27ae8f25517623205712b75e')

build() {
    cd "${srcdir}/${pkgbase}-${pkgver}"
    sed -i 's#env python#env python2#' *.py quodlibet/util/fmps.py
    sed -i 's#libudev.so.0#libudev.so.1#' quodlibet/devices/__init__.py
    ./setup.py build
}

package_quodlibet-libs() {
        pkgdesc="Quod Libet/Exfalso shared libs."
    cd "${srcdir}/${pkgbase}-${pkgver}"
    ./setup.py install --prefix="${pkgdir}/usr"

    # keep only shared files
    rm -rf "${pkgdir}"/usr/bin
    rm -rf "${pkgdir}"/usr/share/{applications,man,pixmaps}
}

package_quodlibet() {
        pkgdesc="An audio player written in pygtk."
    depends=('gstreamer0.10-python' 'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins'
    'gstreamer0.10-ugly-plugins' 'mutagen' 'pygtk' 'quodlibet-libs')
    optdepends=('gstreamer0.10-ffmpeg: for ffmpeg (ASF/WMA) support '
    'gstreamer0.10-bad-plugins: for MPEG-4 (AAC) and Musepack support'
    'python2-dbus: for dbus support'
    'notification-daemon: for notification support'
    'libgpod: for ipod support'
    'python2-feedparser: for audio feeds (podcast) support'
    'udisks: for media devices support'
    'media-player-info: for media devices support')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    ./setup.py install --prefix="${pkgdir}/usr"
    install -D -m644 quodlibet/images/hicolor/64x64/apps/quodlibet.png "${pkgdir}/usr/share/pixmaps/quodlibet.png"

    # purge shared libs since quodlibet-libs provides them
    rm -rf "${pkgdir}"/usr/lib
    rm -rf "${pkgdir}"/usr/share/locale

    # purge exfalso
    find "${pkgdir}" -name "exfalso*" | xargs rm -f
}

package_exfalso() {
        pkgdesc="Cross-platform audio tag editor."
    depends=('pygtk' 'mutagen' 'quodlibet-libs')
    cd "${srcdir}/${pkgbase}-${pkgver}"
    ./setup.py install --prefix="${pkgdir}/usr"
    install -D -m644 quodlibet/images/hicolor/64x64/apps/exfalso.png "${pkgdir}/usr/share/pixmaps/exfalso.png"

    # purge shared libs since quodlibet-libs provides them
    rm -rf "${pkgdir}"/usr/lib
    rm -rf "${pkgdir}"/usr/share/locale

    # purge quodlibet
    find "${pkgdir}" -name "quodlibet*" | xargs rm -f
}