iScreenFader 1.1

/*

        iScreenFader 1.1
        pabaigta 2012m. Birželio 13d 11:09

        Autorius: InstincT
        Keisti kreditus draudžiama! Pakeitęs kreditus autoriumi netapsi!

        funkcijos
            FadeScreenForPlayer( playerid, mode )
            playerid - žaidėjo ID
            mode - užtemdymo rėžimas. Jų yra du tipai:
                FADE_IN - užtemdyti(po truputį padaryti ekraną juodą)
                FADE_OUT - atitemdyti(po truputį padaryti ekraną matomą)

            FadePlayerPos( playerid, Float:fsPosX, Float:fsPosY, Float:fsPosZ, Float:fsPosA = -1.0, fsInt = -1, fsVW = -1 )
            playerid - žaidėjo ID
            fsPosX - koordinatė X
            fsPosY - koordinatė Y
            fsPosZ - koordinatė Z
            **fsPosA - pasisukimo laipsniai
            **fsInt - interioras
            **fsVW - virtual worldas

            FadeSkinForPlayer( playerid, skinID )
            playerid - žaidėjo ID
            skinID - skino ID

            ** - PARAMETRAS NEBŪTINAS!

        callbackai
            OnFadeComplete( playerid, mode )
                playerid - žaidėjo ID
                mode - užtemdymo rėžimas

        changelogas
            2012m. Birželio 12d.:
                - išleista
            2012m. Birželio 13d.:
                - padaryti pranešimai bei vykdymo nutraukimai, kurių dėka bus išvengiamas netaisyklingas funkcijų naudojimas,
                - naudojami PlayerTextDraw'ai vietoje globalių TextDraw'ų,
                - viskas turėtų veikti dvigubai greičiau, pakeistas timer'io interval'as iš 5 į 10, taip pat kintamasis fsSteps mažinamas dviem vienetais
                - naujos funkcijos:
                        FadePlayerPos, FadePlayerSkin


*/


#define FADE_IN 1
#define FADE_OUT 2


forward OnFadeComplete( playerid, mode );


enum fadeScreenEnumas
{
    fsTD_sukurtas,
    PlayerText:fsTextDraw,
    fsTimer,
    fsSteps,
    fsMode,

    Float:fsPos[ 4 ],
    fsInterior,
    fsVirtualWorld,
    fsSkin
}

new
    fadeScreen[ MAX_PLAYERS ][ fadeScreenEnumas ]
;


stock FadeScreenForPlayer( playerid, mode )
{
    if( mode != FADE_IN && mode != FADE_OUT ) return print( "KLAIDA iScreenFader naudojime! FadeScreenForPlayer žaidėjui %d mode buvo netinkamas." );
    if( fadeScreen[ playerid ][ fsSteps ] > 0 ) return print( "KLAIDA iScreenFader naudojime! FadeScreenForPlayer funkcijoje žaidėjas %d jau naudoja ekrano tamsinimą." );
    fadeScreen[ playerid ][ fsSteps ] = 255;
    fadeScreen[ playerid ][ fsMode ] = mode;
    fadeScreen[ playerid ][ fsTimer ] = SetTimerEx( "FadeScreen", 10, true, "d", playerid );
    return 1;
}

stock FadePlayerPos( playerid, Float:fsPosX, Float:fsPosY, Float:fsPosZ, Float:fsPosA = -1.0, fsInt = -1, fsVW = -1 )
{
    if( fadeScreen[ playerid ][ fsSteps ] > 0 ) return print( "KLAIDA iScreenFader naudojime! FadePlayerPos funkcijoje žaidėjas %d jau naudoja ekrano tamsinimą." );
    fadeScreen[ playerid ][ fsSteps ] = 255;
    fadeScreen[ playerid ][ fsMode ] = FADE_IN;
    fadeScreen[ playerid ][ fsPos ][ 0 ] = fsPosX;
    fadeScreen[ playerid ][ fsPos ][ 1 ] = fsPosY;
    fadeScreen[ playerid ][ fsPos ][ 2 ] = fsPosZ;
    fadeScreen[ playerid ][ fsPos ][ 3 ] = fsPosA;
    fadeScreen[ playerid ][ fsInterior ] = fsInt;
    fadeScreen[ playerid ][ fsVirtualWorld ] = fsVW;
    fadeScreen[ playerid ][ fsTimer ] = SetTimerEx( "FadeScreen", 10, true, "d", playerid );
    return 1;
}

stock FadePlayerSkin( playerid, skinID )
{
    if( fadeScreen[ playerid ][ fsSteps ] > 0 ) return print( "KLAIDA iScreenFader naudojime! FadePlayerSkin funkcijoje žaidėjas %d jau naudoja ekrano tamsinimą." );
    fadeScreen[ playerid ][ fsSteps ] = 255;
    fadeScreen[ playerid ][ fsMode ] = FADE_IN;
    fadeScreen[ playerid ][ fsSkin ] = skinID + 1;
    fadeScreen[ playerid ][ fsTimer ] = SetTimerEx( "FadeScreen", 10, true, "d", playerid );
    return 1;
}

forward FadeScreen( playerid );
public FadeScreen( playerid )
{
    if( !fadeScreen[ playerid ][ fsTD_sukurtas ] )
    {
        fadeScreen[ playerid ][ fsTextDraw ] = CreatePlayerTextDraw( playerid, -159.000000, -288.000000, "iScreenFader by InstincT" );
        PlayerTextDrawBackgroundColor( playerid, fadeScreen[ playerid ][ fsTextDraw ], 255 );
        PlayerTextDrawFont( playerid, fadeScreen[ playerid ][ fsTextDraw ], 0 );
        PlayerTextDrawLetterSize( playerid, fadeScreen[ playerid ][ fsTextDraw ], 0.270000, 88.999687 );
        PlayerTextDrawColor( playerid, fadeScreen[ playerid ][ fsTextDraw ], -1 );
        PlayerTextDrawSetOutline( playerid, fadeScreen[ playerid ][ fsTextDraw ], 0 );
        PlayerTextDrawSetProportional( playerid, fadeScreen[ playerid ][ fsTextDraw ], 1 );
        PlayerTextDrawSetShadow( playerid, fadeScreen[ playerid ][ fsTextDraw ], 1 );
        PlayerTextDrawUseBox( playerid, fadeScreen[ playerid ][ fsTextDraw ], 1 );
        PlayerTextDrawBoxColor( playerid, fadeScreen[ playerid ][ fsTextDraw ], 255 );
        PlayerTextDrawTextSize( playerid, fadeScreen[ playerid ][ fsTextDraw ], 848.000000, 2.000000 );
        fadeScreen[ playerid ][ fsTD_sukurtas ] = true;
    }
    PlayerTextDrawBoxColor( playerid, fadeScreen[ playerid ][ fsTextDraw ], GetFadeColor( playerid, fadeScreen[ playerid ][ fsMode ] ) );
    PlayerTextDrawShow( playerid, fadeScreen[ playerid ][ fsTextDraw ] );
    fadeScreen[ playerid ][ fsSteps ] -= 2;
    if( fadeScreen[ playerid ][ fsSteps ] <= 0 )
    {
        KillTimer( fadeScreen[ playerid ][ fsTimer ] );
        if( fadeScreen[ playerid ][ fsMode ] == FADE_OUT )
        {
            PlayerTextDrawHide( playerid, fadeScreen[ playerid ][ fsTextDraw ] );
        }
        else
        {
            if( fadeScreen[ playerid ][ fsPos ][ 0 ] != 0.0 && fadeScreen[ playerid ][ fsPos ][ 1 ] != -1.0 && fadeScreen[ playerid ][ fsPos ][ 2 ] != -1.0 )
            {
                SetPlayerPos( playerid, fadeScreen[ playerid ][ fsPos ][ 0 ], fadeScreen[ playerid ][ fsPos ][ 1 ], fadeScreen[ playerid ][ fsPos ][ 2 ] );

                if( fadeScreen[ playerid ][ fsPos ][ 3 ] != 0.0 ) SetPlayerFacingAngle( playerid, fadeScreen[ playerid ][ fsPos ][ 3 ] );
                if( fadeScreen[ playerid ][ fsInterior ] != -1.0 ) SetPlayerInterior( playerid, fadeScreen[ playerid ][ fsInterior ] );
                if( fadeScreen[ playerid ][ fsVirtualWorld ] != -1.0 ) SetPlayerVirtualWorld( playerid, fadeScreen[ playerid ][ fsVirtualWorld ] );
            }
            if( fadeScreen[ playerid ][ fsSkin ] != 0 ) SetPlayerSkin( playerid, fadeScreen[ playerid ][ fsSkin ] - 1 ); // -1, kadangi funkcijoje buvo +1. Tai reikalinga tam, kad būtų leidžiama nustatyti CJ skiną(ID 0)
        }
        CallRemoteFunction( "OnFadeComplete", "dd", playerid, fadeScreen[ playerid ][ fsMode ] );
        return 1;
    }
    return 1;
}

stock GetFadeColor( playerid, mode )
{
    if( mode == FADE_IN ) return 255 - fadeScreen[ playerid ][ fsSteps ];
    else return 255 - ( 255 - fadeScreen[ playerid ][ fsSteps ] );
}