; Path of Exile AutoHotkey Script by Glyph - http://www.twitch.tv/glyph27
; Version "29-Aug-2014".
;
; This script aims to combine the best qualities of the POE hotkey scripts I could find online and
; modify them to be clearer and more performance-optimised when possible.
;
; Distribute and modify this script however you please. This code is provided without any warranty,
; express or implied.
;
; Props to GGG for a great UI design that changes states without any delay. Most of these functions
; would require sleep commands and take a noticable amount of time.

; INSTRUCTIONS:
;
;   1. Change the hotkeys below to whatever you like.
;   2. Search this file for "MODIFY THIS" and change anything accordingly.


; Key Bindings
;
; For more information about AutoHotkey key bindings, see :
;   * http://www.autohotkey.com/docs/Hotkeys.htm
;   * http://www.autohotkey.com/docs/KeyList.htm

; Use global "#IfWinActive" instead of local "IfWinActive" so that hotkeys are not eaten by AHK.
#IfWinActive, Path of Exile

Numpad0::PathOfExile_logout()
NumpadIns::PathOfExile_logout()

`::PathOfExile_oos()
~::PathOfExile_oos()

F2::PathOfExile_remaining()

F3::PathOfExile_hideout()

F4::PathOfExile_itemlevel()

F5::PathOfExile_portal()


; Log the user out as fast as possible.
PathOfExile_logout()
{
  SendMode Input ; Ensures that MouseClick uses the fastest input mode.

  BlockInput On

  SendInput {Space}{Esc}

  ; This code can automatically calculate where your logout button is based on your resolution,
  ; however, this seems (to me, and based on very few tests) to take a little bit longer to process
  ; and so instead of risking it I use the mouse coordiante click below. The reason for the delay,
  ; if there is any, is due to WinActivate or WinGetPos taking some time. I'm not sure if WinActivate
  ; can be omitted.
  ;WinActivate
  ;WinGetPos, , , Width, Height, A

  ; Calculate position of "EXIT TO LOG IN SCREEN" button based on screen height.
  ;x := Width / 2
  ;y := Height * .403
  ;MouseClick, Left, x, y

  ; If you are using this click technique, MODIFY THIS to the position of the desired logout or exit button.
  ; Set the first number to your screen's horizontal resolution divided by 2. Set the second number to your screen's
  ; vertical resolution multiplied by 0.403.
  MouseClick, Left, 1275, 580

  BlockInput Off
}

PathOfExile_oos()
{
  BlockInput On

	SendInput {Enter}/oos{Enter}

  ; Enter party chat after command (instead of local).
  SendInput {Enter}{`%}{Enter} ; Change the {'%} to {#} for global, etc.

  BlockInput Off
}

PathOfExile_remaining()
{
  BlockInput On

	SendInput {Enter}/remaining{Enter}

  ; Enter party chat after command (instead of local).
  SendInput {Enter}{`%}{Enter} ; Change the {'%} to {#} for global, etc.

  BlockInput Off
}

PathOfExile_hideout()
{
  BlockInput On

	SendInput {Enter}/hideout{Enter}

  ; Enter party chat after command (instead of local).
  SendInput {Enter}{`%}{Enter} ; Change the {'%} to {#} for global, etc.

  BlockInput Off
}

; Checks item level of the held item.
PathOfExile_itemlevel()
{
  BlockInput On

  SendInput {Enter}/itemlevel{Enter}

  ; Enter party chat after command (instead of local).
  SendInput {Enter}{`%}{Enter} ; Change the {'%} to {#} for global, etc.

  BlockInput Off
}

; Casts town portal. MUST BE CONFIGURED for the location of your townportal scroll and your inventory hotkey.
; RIP my town portal scrolls from testing this method.
PathOfExile_portal()
{
  BlockInput On

  MouseGetPos, x, y ; so that we can return the mouse to the original position after.

  ; Send mouse button up commands if the mouse buttons are down, or else town portal will fail.
  GetKeyState, lbstate, LButton
  GetKeyState, rbstate, RButton

  if lbstate = D
    SendInput {LButton Up}

  if rbstate = D
    SendInput {RButton Up}

  if lbstate = D or rbstate = D
    Sleep, 50

  SendMode Input ; Ensures that MouseClick uses the fastest input mode.

  SendInput f ; MODIFY THIS to your inventory hotkey.

  Sleep, 50 ; Needed when inventory hasn't been opened on this map yet for some reason.

  MouseClick, Right, 2500, 1100 ; MODIFY THIS to the position of your town portal scroll.

  SendInput {Space}

  ; Ensure that the mouse isn't moved back so fast that the portal doesn't get clicked.
  Sleep, 50

  MouseMove, x, y

  BlockInput Off
}