ExileClient_gui_traderDialog_updateInventoryDropdown

/**
 * ExileClient_gui_traderDialog_updateInventoryDropdown
 *
 * Exile Mod
 * www.exilemod.com
 * © 2015 Exile Mod Team
 *
 * This work is licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 International License.
 * To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-nd/4.0/.
 */

private["_dialog","_inventoryDropdown","_index","_nearVehicles"];
disableSerialization;
_dialog = uiNameSpace getVariable ["RscExileTraderDialog", displayNull];
_inventoryDropdown = _dialog displayCtrl 4004;
lbClear _inventoryDropdown;
_index = _inventoryDropdown lbAdd "Equipment";
_inventoryDropdown lbSetValue [_index, 1];
_inventoryDropdown lbSetPicture [_index, "a3\ui_f\data\gui\Rsc\RscDisplayArsenal\face_ca.paa"];
_inventoryDropdown lbSetCurSel 0;
if !((uniform player) isEqualTo "") then
{
    _index = _inventoryDropdown lbAdd "Uniform";
    _inventoryDropdown lbSetPicture [_index, "a3\ui_f\data\gui\Rsc\RscDisplayArsenal\uniform_ca.paa"];
    _inventoryDropdown lbSetValue [_index, 2];
};
if !((vest player) isEqualTo "") then
{
    _index = _inventoryDropdown lbAdd "Vest";
    _inventoryDropdown lbSetPicture [_index, "a3\ui_f\data\gui\Rsc\RscDisplayArsenal\vest_ca.paa"];
    _inventoryDropdown lbSetValue [_index, 3];
};
if !((backpack player) isEqualTo "") then
{
    _index = _inventoryDropdown lbAdd "Backpack";
    _inventoryDropdown lbSetPicture [_index, "a3\ui_f\data\gui\Rsc\RscDisplayArsenal\backpack_ca.paa"];
    _inventoryDropdown lbSetValue [_index, 4];
};
_nearVehicles = nearestObjects [player, ["LandVehicle", "Air", "Ship", "Exile_Container_SupplyBox"], 80];
{
    if (local _x) then
    {
        if (alive _x) then
        {
            _index = _inventoryDropdown lbAdd getText(configFile >> "CfgVehicles" >> (typeOf _x) >> "displayName");
            _inventoryDropdown lbSetData [_index, netId _x];
            _inventoryDropdown lbSetValue [_index, 5];
        };
    };
}
forEach _nearVehicles;
true