Ocn_FastNMAvsNMA

// Ocn_FastNMAvsNMA version 1.01
#property  copyright "NMA algorithm © jim sloman, for metatrader programmed by udc"
#property  link      "[email protected]"

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1 Magenta
#property indicator_color2 Silver
#property indicator_color3 Silver
#property indicator_color4 Silver
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int    NMA_period         = 40;
extern int    FastNMA_period     = 40;
extern int    FastNMA_LB_min     = 8;
extern bool   Show_SD            = false;
extern int    SD_len             = 30;
extern double SD_up              = 2;
extern double SD_dn              = 2;
extern bool   Show_SD_1line_only = false;
extern bool   Show_SD_3lines_up  = true;
extern bool   Show_SD_3lines_dn  = true;
extern bool   Show_SD_3lines_md  = true;
extern bool   ValuesInPips       = false;

double FastNMAvsNMA[];
double SD[];
double SD2[];
double SD3[];
double NMA[];
double FastNMA[];
double point;

int init()
{
  string name = "FastNMAvsNMA(" + NMA_period + ", " + FastNMA_period + ", " + FastNMA_LB_min + ")";
  IndicatorShortName(name);
  IndicatorBuffers(6);
  SetIndexBuffer(0, FastNMAvsNMA);
  SetIndexLabel(0, name);
  SetIndexBuffer(1, SD);
  SetIndexBuffer(2, SD2);
  SetIndexBuffer(3, SD3);
  if(Show_SD_1line_only)
    {
    SetIndexLabel(1, "FastNMAvsNMA_SD(" + SD_len + ")");
    SetIndexLabel(2, "unused");
    SetIndexLabel(3, "unused");
    }
  else
    {
    if(Show_SD_3lines_up) SetIndexLabel(1, "FastNMAvsNMA_SD_up(" + SD_len + ")");
    else                  SetIndexLabel(1, "unused");
    if(Show_SD_3lines_dn) SetIndexLabel(2, "FastNMAvsNMA_SD_dn(" + SD_len + ")");
    else                  SetIndexLabel(2, "unused");
    if(Show_SD_3lines_md) SetIndexLabel(3, "FastNMAvsNMA_SD_md(" + SD_len + ")");
    else                  SetIndexLabel(3, "unused");
    }
  SetIndexBuffer(4, NMA);
  SetIndexBuffer(5, FastNMA);
  point = Point;
  if(MarketInfo("EURUSD", MODE_POINT)==0.00001) point *= 10;
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted()-1;
  int max = MathMax(NMA_period, FastNMA_period);
  double nmasum, nmaabssum, nmaratio, nmmnum, maxnmm, fastnmasum, fastnmaabssum, fastnmaratio, temp;
  bool nmadone, fastnmadone;

  if(Bars <= max) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > max) limit = Bars - counted_bars;
  else                   limit = Bars - max - 1;

  for(i = limit; i >= 0; i--)
    {
    if(i == Bars - max - 1) { NMA[i+1] = Close[i+1]; FastNMA[i+1] = Close[i+1]; }
    nmaratio = 0; maxnmm = 0; fastnmaratio = 0;
    int NMA_LB_max;
    for(ii = 1; ii <= FastNMA_period; ii++)
      {
      nmmnum = (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
      if(MathAbs(nmmnum) > maxnmm) { maxnmm = MathAbs(nmmnum); NMA_LB_max = ii; }
      }
    if(NMA_LB_max < FastNMA_LB_min) NMA_LB_max = FastNMA_LB_min;
    nmasum = (MathLog(Close[i]) - MathLog(Close[i+1])) + (MathLog(Close[i+1]) - MathLog(Close[i+2])) * (MathSqrt(2)-1);
    fastnmasum = nmasum;
    nmadone = false; fastnmadone = false; ii = 2;
    while( !(nmadone) || !(fastnmadone) )
      {
      temp = (MathLog(Close[i+ii]) - MathLog(Close[i+ii+1])) * (MathSqrt(ii+1) - MathSqrt(ii));
      if(ii >= NMA_period) nmadone=true;
      else                 nmasum += temp;
      if(ii >= NMA_LB_max) fastnmadone=true;
      else                 fastnmasum += temp;
      ii++;
      }
    nmaabssum = MathAbs(nmasum);
    fastnmaabssum = MathAbs(fastnmasum);
    nmasum = 0; fastnmasum = 0;
    nmadone = false; fastnmadone = false; ii = 0;
    while( !(nmadone) || !(fastnmadone) )
      {
      temp = MathAbs(MathLog(Close[i+ii]) - MathLog(Close[i+ii+1]));
      if(ii >= NMA_period) nmadone=true;
      else                 nmasum += temp;
      if(ii >= NMA_LB_max) fastnmadone=true;
      else                 fastnmasum += temp;
      ii++;
      }
    if(nmasum != 0) nmaratio = nmaabssum / nmasum;
    if(fastnmasum != 0) fastnmaratio = fastnmaabssum / fastnmasum;
    NMA[i] = NMA[i+1] + (Close[i] - NMA[i+1]) * nmaratio;
    FastNMA[i] = FastNMA[i+1] + (Close[i] - FastNMA[i+1]) * fastnmaratio;
    if(ValuesInPips) FastNMAvsNMA[i] = (FastNMA[i] - NMA[i]) / point;
    else             FastNMAvsNMA[i] = FastNMA[i] - NMA[i];
    }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - max - 1 - SD_len)
        {
        if(Show_SD_1line_only)
          {
          if(FastNMAvsNMA[i] == 0)     SD[i] = 0;
          else if(FastNMAvsNMA[i] > 0) SD[i] = iBandsOnArray(FastNMAvsNMA, 0, SD_len, SD_up, 0, MODE_UPPER, i);
          else if(FastNMAvsNMA[i] < 0) SD[i] = iBandsOnArray(FastNMAvsNMA, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
          }
        else
          {
          if(Show_SD_3lines_up) SD[i] = iBandsOnArray(FastNMAvsNMA, 0, SD_len, SD_up, 0, MODE_UPPER, i);
          if(Show_SD_3lines_dn) SD2[i] = iBandsOnArray(FastNMAvsNMA, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
          if(Show_SD_3lines_md) SD3[i] = (iBandsOnArray(FastNMAvsNMA, 0, SD_len, SD_up, 0, MODE_UPPER, i)+
                                          iBandsOnArray(FastNMAvsNMA, 0, SD_len, SD_dn, 0, MODE_LOWER, i) ) / 2;
          }
        }

  return(0);
}