TinyTowerSquad

static int _WIDTH = 640; // set me

//Auto Generated from _WIDTH ---
static int _HEIGHT = (int)(_WIDTH * .8);
static float playWindowHeight = _WIDTH * .65;
static float cellSize = _WIDTH/20;
static float menuPosY = playWindowHeight + 1;
static float menuHeight = _HEIGHT - menuPosY;
float lives = 5;
//--------------

Cell[][] Grid = new Cell[20][13];
PImage[] TowerSprites;
CreepSprite[] CreepSprites;

PImage field;
PImage path;
PImage pathMask;

Cell hoverCell = null;

//Level Variables---
Path Level;
//Gameplay Variables----
ArrayList<Tower> AllTowers = new ArrayList<Tower>();
ArrayList<Creep> AllCreeps = new ArrayList<Creep>();
//------------------

void setup() {
  size(_WIDTH, _HEIGHT);

  //initialize Grid ---
  for (int x = 0; x < Grid.length; x++) {
    for (int y = 0; y < Grid[0].length; y++) {
      Grid[x][y] = new Cell(x, y);
    }
  }
  //--------

  field = loadImage("grass.png");
  path = loadImage("dirt.png");
  pathMask = loadImage("dirt-mask2.png");
  path.mask(pathMask);

  TowerSprites = new PImage[] {
    loadImage("towers/t1.png"),
    //more sprites
  };

  CreepSprites = new CreepSprite[] {
    new CreepSprite("gob"),
    new CreepSprite("ticky"),
  };

  Vector[] _path = new Vector[] {
    new Vector(0, 5),
    new Vector(3, 5),
    new Vector(3, 8),
    new Vector(1, 8),
    new Vector(1, 11),
    new Vector(9, 11),
    new Vector(9, 8),
    new Vector(6, 8),
    new Vector(6, 3),
    new Vector(10, 3),
    new Vector(10, 5),
    new Vector(11, 5),
    new Vector(11, 10),
    new Vector(14, 10),
    new Vector(14, 8),
    new Vector(17, 8),
    new Vector(17, 5),
    new Vector(13, 5),
    new Vector(13, 0),
  };

  Level = new Path(_path);

  setUnbuildable(new Vector(0, 0));
  setUnbuildable(new Vector(1, 0));
  setUnbuildable(new Vector(1, 2));
  setUnbuildable(new Vector(0, 2));
  setUnbuildable(new Vector(0, 3));
}

void draw() {
  image(field, 0, 0, width, playWindowHeight);
  image(path, 0, 0, width, playWindowHeight);

  for (int i = 0; i < AllTowers.size(); i++) {
    AllTowers.get(i).drawMe();
  }

  for (int i = 0; i < AllCreeps.size(); i++) AllCreeps.get(i).move();

  mouseCheck();
}

void mouseCheck() {
  int x = (int)(mouseX / cellSize);
  int y = (int)(mouseY / cellSize);

  if (x < Grid.length && y < Grid[0].length) {
    hoverCell = Grid[x][y];
    hoverCell.outlineMe();
  }
}

void keyPressed() {
  if (key == 'a') AllCreeps.add(new Creep(0));
  else if (key == 's') AllCreeps.add(new Creep(1));
}

void mousePressed() {
  if (hoverCell != null) {
    println("new Vector(" + hoverCell.x + ", " + hoverCell.y + "),");
    if (hoverCell.buildable()) hoverCell.buildOn(new Tower(hoverCell.x, hoverCell.y, 0));
  }
}


void setUnbuildable(Vector v) {
  Grid[v.x][v.y].isPath = true;
}

void leak(Creep c) {
  AllCreeps.remove(c);
  println("A creep has leaked!");

}