some_yahoo

// Persistence of Vision Ray Tracer Scene Description File
// File: starship.pov
// Vers: 3.6
// Desc: A simple starship corridor
// Date: 1/30/2010
// Auth: Bryan Valencia



#include "colors.inc"
#include "textures.inc"

#declare PlainWhite=texture{
	pigment {color rgb 1}
	finish  {phong 1 specular 1 metallic}
	normal {cells 0.1}
}

#declare shiny_floor=texture{
	pigment{color rgb .20}
	finish{reflection .2 phong 1 metallic}
	normal{bumps 0.1}
}

#declare windows=texture{
	pigment{cells
		color_map{
			[0 0.1 color rgb 7 color rgb 7]
			[0.1 1 color rgb .25 color rgb .25]
		}
	}
}

#declare neon=texture{
	pigment{color rgb<0.25,1,0.3>}
	finish{ambient 1}
}

#declare thefloor=box{
	<-15,-1,-30><15,0,30>
	texture{New_Penny}
}



#declare k=sqrt((10*10)/2);
#declare lowerwalls=difference{
	box{<-20,-1,-30><20,5,30>}
	box{<-k,-k,-31><k,k,31>
		rotate z*45
		translate <0,5,0>
	}
	texture{PlainWhite}
}


#declare upperwalls=object{
	lowerwalls
	translate y*-5
	scale <1,-3,1>
	translate y*5

}

#declare walls=union{
	object{lowerwalls}
	object{upperwalls}
}


#declare doordrill=difference{
	box{<-2,-1,-1><2,10,1>}
	union{
		box{<-5,-10,-2><-2,10,2> rotate z* 10 translate y*5}
		box{< 5,-10,-2>< 2,10,2> rotate z*-10 translate y*5}
		box{<-5,-10,-2><-2,10,2> rotate z*-10 translate y*5}
		box{< 5,-10,-2>< 2,10,2> rotate z* 10 translate y*5}
	}
}

//object{doordrill texture{Aluminum}}

#declare walls2=difference{
	object{walls}
	union{
		object{doordrill rotate y*90 scale <50,1,1>}
		object{doordrill rotate y*90 scale <50,1,1> translate z* 10}
		object{doordrill rotate y*90 scale <50,1,1> translate z*-10}
		object{doordrill rotate y*90 scale <50,1,1> translate z* 20}
		object{doordrill rotate y*90 scale <50,1,1> translate z*-20}
	}
	texture{PlainWhite}
}

#declare doorlights=union{
	light_source{0 rgb .4 translate<-15,9.9,0> media_interaction off}
}

#declare ceiling=difference{
	box{<-10,20,-30><10,30,30>}
	box{<-4,19,-29><4,28,29>}
	texture{ PlainWhite }
}

//ceiling lights
#declare ceil_light=light_source{
	<0,25,0> color rgb 1
  spotlight
  point_at <0, 0, 0>
  radius 45
  tightness 20
  falloff 70
  media_interaction on
  media_attenuation off
}


#declare media_box=box{
	<-10,-10,-50><10,30,200>
	hollow
	pigment{color rgbf 1}
	interior{
		media {
		  intervals 9
		  scattering { 1, rgb 0.01 }
		  samples 1, 10
		  confidence 1/10
		  variance 1/1000
		  ratio 0.9
		}
	}
}

#declare sphere_room=difference{
	box{-100,100}
	union{
		sphere{0,99 texture{windows scale <5,3,1>/5}}
		object{doordrill scale <2,1,5> translate z*-100}
	}
	texture{PlainWhite}
	translate z*130
}

#declare engine_gizmo=union{
	cone{<0,-100,0>,50,<0,-1,0>,1}
	cone{<0,100,0>,50,<0,1,0>,1}
	texture{New_Penny}
	translate z*130
}


//door numbers
#declare xfactor=7.7;
union{
	//cylinder{<0,0,0><0,20,0>,0.1}
	text {ttf "crystal.ttf", "1171", 2, 0 translate <-1,0,0>  rotate y*90 translate <xfactor,11,-20>}
	text {ttf "crystal.ttf", "1172", 2, 0 translate <-1,0,0>  rotate y*-90 translate <-xfactor,11,-20>}

	text {ttf "crystal.ttf", "1173", 2, 0 translate <-1,0,0>  rotate y*90 translate <xfactor,11,-10>}
	text {ttf "crystal.ttf", "1174", 2, 0 translate <-1,0,0>  rotate y*-90 translate <-xfactor,11,-10>}

	text {ttf "crystal.ttf", "1175", 2, 0 translate <-1,0,0>  rotate y*90 translate <xfactor,11,0>}
	text {ttf "crystal.ttf", "1176", 2, 0 translate <-1,0,0>  rotate y*-90 translate <-xfactor,11,0>}

	text {ttf "crystal.ttf", "1177", 2, 0 translate <-1,0,0>  rotate y*90 translate <xfactor,11,10>}
	text {ttf "crystal.ttf", "1178", 2, 0 translate <-1,0,0>  rotate y*-90 translate <-xfactor,11,10>}

	text {ttf "crystal.ttf", "1179", 2, 0 translate <-1,0,0>  rotate y*90 translate <xfactor,11,20>}
	text {ttf "crystal.ttf", "1180", 2, 0 translate <-1,0,0>  rotate y*-90 translate <-xfactor,11,20>}

	text {ttf "verdana.ttf", "Reactor", .2, 0 translate <-1.6,0,0> scale 2 translate <0,11,29.9>}

	texture{neon}
}



light_source{<0,0,130>
	color rgb <2,1,1>
	media_interaction on
	media_attenuation off
}

light_source{<0,20,-29> color rgb <0,.1,0>
	media_interaction off
}

camera {
  location  <0.0, 5.0, -25.0>
  look_at   <0.0, 0.0, 100>
  right     x*image_width/image_height
}


object{thefloor}
object{walls2}
object{ceiling}
object{doorlights}

object{ ceil_light }
object{ ceil_light translate z* 20}
object{ ceil_light translate z*-20}

object{media_box}
object{sphere_room}
object{engine_gizmo}


//#include "girls_POV_geom.inc"
//#object{girls_ scale 6 translate <-1,0,3>}