PKGBUILD

# Maintainer: TryA <tryagainprod@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
# Contributor: Travis Willard <travis@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>

_pkgbasename=libpng
pkgname=lib32-libpng14
pkgver=1.4.11
_apngver=1.4.11
pkgrel=1
pkgdesc="A collection of routines used to create PNG format graphics files (32-bit, 1.4 branch)"
arch=('x86_64')
url="http://www.libpng.org/pub/png/libpng.html"
license=('custom')
depends=('lib32-zlib')
makedepends=('gcc-multilib')
options=('!libtool')
source=("http://downloads.sourceforge.net/sourceforge/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2"
        "http://downloads.sourceforge.net/sourceforge/libpng-apng/libpng-${_apngver}-apng.patch.gz"
    "libpng14-autoconf-1.13.patch")

md5sums=('d33dd98a8fe8f06e2379c45c4f5d7677'
         'acfcfc215f4e419ea2aa8567e26589e7'
         '999021c8e2ceb7a198c25cf6ef460448')
build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "${srcdir}/${_pkgbasename}-${pkgver}"

  # Add animated PNG (apng) support
  # see http://sourceforge.net/projects/libpng-apng/
  patch -Np1 -i "${srcdir}/libpng-${_apngver}-apng.patch"

  # fix obsoleted macro in configure.ac
  patch -Np0 -i "${srcdir}/libpng14-autoconf-1.13.patch"

  libtoolize --force --copy
  aclocal
  autoconf
  automake --add-missing

  ./configure --prefix=/usr --libdir=/usr/lib32

  make ECHO=echo
}

package() {
  cd "${srcdir}/${_pkgbasename}-${pkgver}"
  make ECHO=echo DESTDIR="${pkgdir}" install

  rm -f ${pkgdir}/usr/lib32/{libpng.so,libpng.a,pkgconfig/libpng.pc}
  rm -rf ${pkgdir}/usr/{include,share,bin}

  mkdir -p "${pkgdir}/usr/share/licenses"
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}