.cshrc

# Set default masking
umask 077

# Begin JAIST's Setting
set system = `uname -s`
switch ("${system}")
case "SunOS":
    set path = (~/bin /pkg/local10/bin \
                /usr/dt/bin /usr/openwin/bin /usr/ccs/bin /opt/SUNWspro/bin \
                /usr/bin /usr/ucb /usr/local/bin /pkg/all/bin)
    setenv MANPATH      "/pkg/local10/man:/usr/dt/man:/usr/openwin/share/man:/usr/share/man:/opt/SUNWspro/man:/usr/local/man:/pkg/all/man"
    setenv LOCALTEXMF   "/usr/local/share/jaist.texmf"
    setenv TEXINPUTS    ".:${LOCALTEXMF}/tex//::"
    setenv TEXFONTS     ".:${LOCALTEXMF}/fonts//::"
    breaksw

case "Linux":
    breaksw

default:
    if (-f ".cshrc.${system}") then
        source ".cshrc.${system}"
    endif
    breaksw
endsw

if ($?HOST == 0 || "${HOST}" == "") then
    setenv HOST `hostname`
endif

## Uncomment this if you prefer Japanese message.
#setenv LANG     "ja_JP.UTF-8"

# Common applications
setenv  EDITOR  "emacs -nw"
setenv  PAGER   "less"

# Common servers
setenv  JSERVER     "localhost"
setenv  NNTPSERVER  "jaist-news.jaist.ac.jp"
setenv  MAILHOST    "smtp.jaist.ac.jp"

# END JAIST's Setting

# Make sure the EDITOR is set for using with svn or git
if ($?EDITOR == 0 || "${EDITOR}" == "") then
    setenv EDITOR "vi"
endif

# Setting up the workspace
if (-d "/work/${USER}") then
    setenv WORK "/work/${USER}"

    # Add custom binaries
    if (-d "${WORK}/bin") then
        set path = ("${WORK}/bin" ${path})
    endif

    if (-d "${WORK}/sbin") then
        set path = ("${WORK}/sbin" ${path})
    endif

    # Add custom libraries
    if (-d "${WORK}/lib" || -d "${WORK}/lib64") then
        if ($?LD_LIBRARY_PATH == 0) then
            setenv LD_LIBRARY_PATH "/usr/local/lib64:/usr/local/lib:/usr/lib64:/usr/lib"
        endif
        if (-d "${WORK}/lib") then
            setenv LD_LIBRARY_PATH "${WORK}/lib:${LD_LIBRARY_PATH}"
        endif
        if (-d "${WORK}/lib64") then
            setenv LD_LIBRARY_PATH "${WORK}/lib64:${LD_LIBRARY_PATH}"
        endif
    endif

    # Add custom man pages
    if (-d "${WORK}/share/man") then
        if ($?MANPATH == 0) then
            setenv MANPATH "`man -w`"
        endif
        setenv MANPATH "${WORK}/share/man:${MANPATH}"
    endif

    # Add custom headers
    if (-d "${WORK}/include") then
        if ($?CPATH == 0) then
            setenv CPATH "/usr/local/include:/usr/include"
        endif
        setenv CPATH "${WORK}/include:${CPATH}"
    endif

    # Add package config
    if (-d "${WORK}/lib/pkgconfig" || -d "${WORK}/lib64/pkgconfig") then
        if ($?PKG_CONFIG_PATH == 0) then
            setenv PKG_CONFIG_PATH "/usr/local/lib64/pkgconfig:/usr/local/lib/pkgconfig:/usr/lib64/pkgconfig:/usr/lib/pkgconfig"
        endif
        if (-d "${WORK}/lib/pkgconfig") then
            setenv PKG_CONFIG_PATH "${WORK}/lib/pkgconfig:${PKG_CONFIG_PATH}"
        endif
        if (-d "${WORK}/lib64/pkgconfig") then
            setenv PKG_CONFIG_PATH "${WORK}/lib64/pkgconfig:${PKG_CONFIG_PATH}"
        endif
    endif

    # Add environment module files
    if (-d "${WORK}/etc/modulefiles" && $?MODULEPATH != 0) then
        setenv MODULEPATH "${WORK}/etc/modulefiles:${MODULEPATH}"
    endif
endif

# Check interactive mode
if ($?prompt) then
    if ("`uname -s`" =~ "Linux") then
        alias   ls      "ls -F --color=auto"
        alias   grep    "grep --color=auto"

        set     prompt = "%{\e[32;1m%}%n%{\e[37m%}@%{\e[33m%}%m%{\e[37m%}:%{\e[36m%}%~%{\e[37m%}"%%"%{\e[0m%} "
    endif
    alias   ll  "ls -al"
endif