Rainmaker

// Clock speedometer - metric
// Credits to : ...
// Y_Less for his sscanf | Kolji for his dot rotating algorithm
// Tazok for Speed color changing | Luk_Ass for helping me to  unferstand the power of "format" (int-hex converting)
// Misco for his GetPlayerSpeed

#include <a_samp>
#include <float>

forward speedoonre(playerid);       // Re-enables speedo
forward Updater();                  // Updates Speedometer

// Speedometer / speedometer globals
new Text:speedoclock[MAX_PLAYERS];  // Clock of speedometer
new Text:speedodot[MAX_PLAYERS];    // The dot circulating in the clock
new Text:speedospeed[MAX_PLAYERS];  // Speed values
new Text:speedominmax[MAX_PLAYERS]; // Borders min max speed
new bool:speedoon[MAX_PLAYERS];     // Is speedometr for this player on ?
new bool:speedoonex[MAX_PLAYERS];   // Because of speedoonre
new Float:speedox = 557.0;          // Pos of dot - X
new Float:speedoy = 359.0;          // Pos od dot - Y
new Float:speedor = 32.0;           // Radius of dot circle
new Float:speedomin = 220.0;        // Circle min angle
new Float:speedomax = -35.0;        // Circle max angle
new updater_timer;                 // Timer which updates Speedometer

speedoShow(playerid)
{
    speedoon[playerid] = true;
    if(IsPlayerInAnyVehicle(playerid) == 1)
    {
	    TextDrawShowForPlayer(playerid, speedoclock[playerid]);
		TextDrawShowForPlayer(playerid, speedodot[playerid]);
		TextDrawShowForPlayer(playerid, speedospeed[playerid]);
		TextDrawShowForPlayer(playerid, speedominmax[playerid]);
	}
	return 1;
}

speedoHide(playerid)
{
    speedoon[playerid] = false;
	TextDrawHideForPlayer(playerid, speedoclock[playerid]);
	TextDrawHideForPlayer(playerid, speedodot[playerid]);
	TextDrawHideForPlayer(playerid, speedospeed[playerid]);
	TextDrawHideForPlayer(playerid, speedominmax[playerid]);
	return 1;
}

public speedoonre(playerid)
{
	speedoon[playerid] = true;
	return 1;
}

Float:GetPlayerSpeed(playerid) // Misco (simple maths)
{
	new Float:Vx,Float:Vy,Float:Vz,Float:rtn;
	if(IsPlayerInAnyVehicle(playerid))
	{
		GetVehicleVelocity(GetPlayerVehicleID(playerid),Vx,Vy,Vz);
		rtn = floatsqroot(floatpower(floatabs(Vx),2)+floatpower(floatabs(Vy),2)+floatpower(floatabs(Vz),2));
	}
	else
	{
		GetPlayerVelocity(playerid,Vx,Vy,Vz);
		rtn = floatsqroot(floatpower(floatabs(Vx),2)+floatpower(floatabs(Vy),2)+floatpower(floatabs(Vz),2));
	}
	return floatmul(floatmul(rtn, 100), 1.61);
}

GetSpeedColor(speed) // Tazok
{
	new str1[32], str2[32], str3[32];
	new speedex = 255-speed;
	new result;
	format(str1, sizeof(str1), "%x", speed);
	if(strlen(str1) == 1) format(str1, sizeof(str1), "0%s", str1);
	format(str2, sizeof(str2), "%x", speedex);
	if(strlen(str2) == 1) format(str2, sizeof(str2), "0%s", str2);
	format(str3, sizeof(str3), "0x%s%s00FF", str1, str2);
	sscanf(str3, "h", result);
    return result;
}

public Updater() // Algorithm by Kolji
{
	for(new playerid = 0; playerid < MAX_PLAYERS; playerid++)
	{
	    if(IsPlayerConnected(playerid) && speedoon[playerid] == true && IsPlayerInAnyVehicle(playerid))
	    {
	        new Float:XX, Float:YY, Float:speed, Float:ratio;
	        ratio = floatdiv((speedomin - speedomax), 255);
			speed = GetPlayerSpeed(playerid);
			XX = floatadd(speedox, floatmul(floatcos(floatmul(floatsub(speedomin, speed), ratio), degrees), speedor));
			YY = floatsub(speedoy, floatmul(floatsin(floatmul(floatsub(speedomin, speed), ratio), degrees), speedor));
			TextDrawDestroy(speedodot[playerid]);
			speedodot[playerid] = TextDrawCreate(XX,YY,".");
		    TextDrawAlignment(speedodot[playerid],2);
		    TextDrawBackgroundColor(speedodot[playerid], 0x000000ff);
		    TextDrawFont(speedodot[playerid],1);
			TextDrawLetterSize(speedodot[playerid],1.100000,3.499998);
			TextDrawColor(speedodot[playerid], 0xffffffff);
			TextDrawSetOutline(speedodot[playerid],1);
			TextDrawSetProportional(speedodot[playerid],1);
			TextDrawShowForPlayer(playerid, speedodot[playerid]);
	        new njn[24];
	        format(njn, sizeof(njn), "%d", floatround(speed));
	        new barvicka;
	        barvicka = GetSpeedColor(floatround(speed));
	        TextDrawColor(speedospeed[playerid], barvicka);
			TextDrawSetString(speedospeed[playerid], njn);
			TextDrawShowForPlayer(playerid, speedospeed[playerid]);
	    }
	}
}

public OnFilterScriptInit()
{
	print("\n  ****** Speedometer loaded ******\n");
	updater_timer = SetTimer("Updater", 500, 1);

	for(new playerid; playerid < MAX_PLAYERS; playerid++)
	{
		if(IsPlayerConnected(playerid))
		{
			speedoon[playerid] = true;
		    speedoonex[playerid] = true;

		    //============================ Text Draw speedo clock ======================
			speedoclock[playerid] = TextDrawCreate(504.000000,319.000000,"O");
			TextDrawAlignment(speedoclock[playerid],0);
			TextDrawBackgroundColor(speedoclock[playerid],0x00000066);
			TextDrawFont(speedoclock[playerid],1);
			TextDrawLetterSize(speedoclock[playerid],3.900001,12.900002);
			TextDrawColor(speedoclock[playerid],0xffffffcc);
			TextDrawSetOutline(speedoclock[playerid],1);
			TextDrawSetProportional(speedoclock[playerid],1);

			//=========================== Text Draw speedo dot =========================
			speedodot[playerid] = TextDrawCreate(527.000000,379.000000,".");
			TextDrawAlignment(speedodot[playerid],2);
			TextDrawBackgroundColor(speedodot[playerid],0x000000ff);
			TextDrawFont(speedodot[playerid],1);
			TextDrawLetterSize(speedodot[playerid],1.100000,3.499998);
			TextDrawColor(speedodot[playerid],0xffffffff);
			TextDrawSetOutline(speedodot[playerid],1);
			TextDrawSetProportional(speedodot[playerid],1);

			//============================ Text Draw speedo minmax ======================
			speedominmax[playerid] = TextDrawCreate(531.0000,397.0000,"~g~/ ~r~\\");
			TextDrawAlignment(speedominmax[playerid],0);
			TextDrawBackgroundColor(speedominmax[playerid],0x000000ff);
			TextDrawFont(speedominmax[playerid],3);
			TextDrawLetterSize(speedominmax[playerid],1.100000,2.000000);
			TextDrawSetOutline(speedominmax[playerid],1);
			TextDrawSetProportional(speedominmax[playerid],1);

			//========================== Text Draw speedo speed  ========================
			speedospeed[playerid] = TextDrawCreate(557.000000,372.000000,"194");
			TextDrawAlignment(speedospeed[playerid],2);
			TextDrawBackgroundColor(speedospeed[playerid],0x00000033);
			TextDrawFont(speedospeed[playerid],3);
			TextDrawLetterSize(speedospeed[playerid],0.499999,2.100000);
			TextDrawColor(speedospeed[playerid],0xff000099);
			TextDrawSetOutline(speedospeed[playerid],1);
			TextDrawSetProportional(speedospeed[playerid],1);
		}
	}
	return 1;
}

public OnFilterScriptExit()
{
	for(new playerid; playerid < MAX_PLAYERS; playerid++)
	{
	    TextDrawHideForPlayer(playerid, speedoclock[playerid]);
		TextDrawHideForPlayer(playerid, speedodot[playerid]);
		TextDrawHideForPlayer(playerid, speedospeed[playerid]);
		TextDrawHideForPlayer(playerid, speedominmax[playerid]);
		TextDrawDestroy(speedoclock[playerid]);
		TextDrawDestroy(speedodot[playerid]);
		TextDrawDestroy(speedospeed[playerid]);
		TextDrawDestroy(speedominmax[playerid]);
		speedoon[playerid] = false;
	    speedoonex[playerid] = false;
	}
	KillTimer(updater_timer);
	print("\n  ****** Speedometer unloaded ******\n");
	return 1;
}

public OnPlayerConnect(playerid)
{
    speedoon[playerid] = true;
    speedoonex[playerid] = true;

    //============================ Text Draw speedo clock ======================
	speedoclock[playerid] = TextDrawCreate(504.000000,319.000000,"O");
	TextDrawAlignment(speedoclock[playerid],0);
	TextDrawBackgroundColor(speedoclock[playerid],0x00000066);
	TextDrawFont(speedoclock[playerid],1);
	TextDrawLetterSize(speedoclock[playerid],3.900001,12.900002);
	TextDrawColor(speedoclock[playerid],0xffffffcc);
	TextDrawSetOutline(speedoclock[playerid],1);
	TextDrawSetProportional(speedoclock[playerid],1);

	//=========================== Text Draw speedo dot =========================
	speedodot[playerid] = TextDrawCreate(527.000000,379.000000,".");
	TextDrawAlignment(speedodot[playerid],2);
	TextDrawBackgroundColor(speedodot[playerid],0x000000ff);
	TextDrawFont(speedodot[playerid],1);
	TextDrawLetterSize(speedodot[playerid],1.100000,3.499998);
	TextDrawColor(speedodot[playerid],0xffffffff);
	TextDrawSetOutline(speedodot[playerid],1);
	TextDrawSetProportional(speedodot[playerid],1);

	//============================ Text Draw speedo minmax ======================
	speedominmax[playerid] = TextDrawCreate(531.0000,397.0000,"~g~/ ~r~\\");
	TextDrawAlignment(speedominmax[playerid],0);
	TextDrawBackgroundColor(speedominmax[playerid],0x000000ff);
	TextDrawFont(speedominmax[playerid],3);
	TextDrawLetterSize(speedominmax[playerid],1.100000,2.000000);
	TextDrawSetOutline(speedominmax[playerid],1);
	TextDrawSetProportional(speedominmax[playerid],1);

	//========================== Text Draw speedo speed  ========================
	speedospeed[playerid] = TextDrawCreate(557.000000,372.000000,"194");
	TextDrawAlignment(speedospeed[playerid],2);
	TextDrawBackgroundColor(speedospeed[playerid],0x00000033);
	TextDrawFont(speedospeed[playerid],3);
	TextDrawLetterSize(speedospeed[playerid],0.499999,2.100000);
	TextDrawColor(speedospeed[playerid],0xff000099);
	TextDrawSetOutline(speedospeed[playerid],1);
	TextDrawSetProportional(speedospeed[playerid],1);
	return 1;
}

public OnPlayerDeath(playerid, killerid, reason)
{
    speedoHide(playerid);
    SetTimerEx("speedoonre", 3000, 0, "d", playerid);
    return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
	new string[128], idx;

	string = strtok(cmdtext, idx);

	if(!strcmp(string, "/speedo", true) || !strcmp(string, "/speedometer", true))
	{
	    if(speedoon[playerid] == false) speedoShow(playerid);
		else speedoHide(playerid);
		return 1;
	}
	return 0;
}

public OnPlayerDisconnect(playerid, reason)
{
	TextDrawHideForPlayer(playerid, speedoclock[playerid]);
	TextDrawHideForPlayer(playerid, speedodot[playerid]);
	TextDrawHideForPlayer(playerid, speedospeed[playerid]);
	TextDrawHideForPlayer(playerid, speedominmax[playerid]);
	TextDrawDestroy(speedoclock[playerid]);
	TextDrawDestroy(speedodot[playerid]);
	TextDrawDestroy(speedospeed[playerid]);
	TextDrawDestroy(speedominmax[playerid]);
	speedoon[playerid] = false;
    speedoonex[playerid] = false;
	return 1;
}

public OnPlayerStateChange(playerid,newstate,oldstate)
{
	if(newstate == 1  && (oldstate == 2 || oldstate == 3))
	{
	    if(speedoon[playerid] == true)
		{
			speedoHide(playerid);
			SetTimerEx("speedoonre", 3000, 0, "d", playerid);
		}
	}
	if((newstate == 7 || newstate == 8 || newstate == 9) && (oldstate == 2 || oldstate == 3))
	{
	    if(speedoon[playerid] == true)
		{
			speedoHide(playerid);
			SetTimerEx("speedoonre", 3000, 0, "d", playerid);
		}
	}
	if(newstate == 2 || newstate == 3)
    {
		if(speedoon[playerid] == true) speedoShow(playerid);
    }
	return 1;
}

stock sscanf(string[], format[], {Float,_}:...) // Coded by Y_Less ...  http://wiki.sa-mp.com/wiki/Sscanf
{
	#if defined isnull
		if (isnull(string))
	#else
		if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
	#endif
		{
			return format[0];
		}
	#pragma tabsize 4
	new
		formatPos = 0,
		stringPos = 0,
		paramPos = 2,
		paramCount = numargs(),
		delim = ' ';
	while (string[stringPos] && string[stringPos] <= ' ')
	{
		stringPos++;
	}
	while (paramPos < paramCount && string[stringPos])
	{
		switch (format[formatPos++])
		{
			case '\0':
			{
				return 0;
			}
			case 'i', 'd':
			{
				new
					neg = 1,
					num = 0,
					ch = string[stringPos];
				if (ch == '-')
				{
					neg = -1;
					ch = string[++stringPos];
				}
				do
				{
					stringPos++;
					if ('0' <= ch <= '9')
					{
						num = (num * 10) + (ch - '0');
					}
					else
					{
						return -1;
					}
				}
				while ((ch = string[stringPos]) > ' ' && ch != delim);
				setarg(paramPos, 0, num * neg);
			}
			case 'h', 'x':
			{
				new
					num = 0,
					ch = string[stringPos];
				do
				{
					stringPos++;
					switch (ch)
					{
						case 'x', 'X':
						{
							num = 0;
							continue;
						}
						case '0' .. '9':
						{
							num = (num << 4) | (ch - '0');
						}
						case 'a' .. 'f':
						{
							num = (num << 4) | (ch - ('a' - 10));
						}
						case 'A' .. 'F':
						{
							num = (num << 4) | (ch - ('A' - 10));
						}
						default:
						{
							return -1;
						}
					}
				}
				while ((ch = string[stringPos]) > ' ' && ch != delim);
				setarg(paramPos, 0, num);
			}
			case 'c':
			{
				setarg(paramPos, 0, string[stringPos++]);
			}
			case 'f':
			{
				setarg(paramPos, 0, _:floatstr(string[stringPos]));
			}
			case 'p':
			{
				delim = format[formatPos++];
				continue;
			}
			case '\'':
			{
				new
					end = formatPos - 1,
					ch;
				while ((ch = format[++end]) && ch != '\'') {}
				if (!ch)
				{
					return -1;
				}
				format[end] = '\0';
				if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
				{
					if (format[end + 1])
					{
						return -1;
					}
					return 0;
				}
				format[end] = '\'';
				stringPos = ch + (end - formatPos);
				formatPos = end + 1;
			}
			case 'u':
			{
				new
					end = stringPos - 1,
					id = 0,
					bool:num = true,
					ch;
				while ((ch = string[++end]) && ch != delim)
				{
					if (num)
					{
						if ('0' <= ch <= '9')
						{
							id = (id * 10) + (ch - '0');
						}
						else
						{
							num = false;
						}
					}
				}
				if (num && IsPlayerConnected(id))
				{
					setarg(paramPos, 0, id);
				}
				else
				{
					#if !defined foreach
						#define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
						#define __SSCANF_FOREACH__
					#endif
					string[end] = '\0';
					num = false;
					new
						name[MAX_PLAYER_NAME];
					id = end - stringPos;
					foreach (Player, playerid)
					{
						GetPlayerName(playerid, name, sizeof (name));
						if (!strcmp(name, string[stringPos], true, id))
						{
							setarg(paramPos, 0, playerid);
							num = true;
							break;
						}
					}
					if (!num)
					{
						setarg(paramPos, 0, INVALID_PLAYER_ID);
					}
					string[end] = ch;
					#if defined __SSCANF_FOREACH__
						#undef foreach
						#undef __SSCANF_FOREACH__
					#endif
				}
				stringPos = end;
			}
			case 's', 'z':
			{
				new
					i = 0,
					ch;
				if (format[formatPos])
				{
					while ((ch = string[stringPos++]) && ch != delim)
					{
						setarg(paramPos, i++, ch);
					}
					if (!i)
					{
						return -1;
					}
				}
				else
				{
					while ((ch = string[stringPos++]))
					{
						setarg(paramPos, i++, ch);
					}
				}
				stringPos--;
				setarg(paramPos, i, '\0');
			}
			default:
			{
				continue;
			}
		}
		while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
		{
			stringPos++;
		}
		while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
		{
			stringPos++;
		}
		paramPos++;
	}
	do
	{
		if ((delim = format[formatPos++]) > ' ')
		{
			if (delim == '\'')
			{
				while ((delim = format[formatPos++]) && delim != '\'') {}
			}
			else if (delim != 'z')
			{
				return delim;
			}
		}
	}
	while (delim > ' ');
	return 0;
}

strtok(const string[],&index)
{
	new length=strlen(string);
	while((index<length)&&(string[index]<= ' '))index++;
	new offset=index;
	new result[20];
	while((index<length)&&(string[index]>' ')&&((index-offset)<(sizeof(result)-1))){
		result[index-offset]=string[index];
		index++;}
	result[index-offset]=EOS;
	return result;
}