Zinglish

/*
*  ________                       ___                 __
* /\_____  \  __                 /\_ \    __         /\ \
* \/____//'/'/\_\    ___      __ \//\ \  /\_\    ____\ \ \___
*      //'/' \/\ \ /' _ `\  /'_ `\ \ \ \ \/\ \  /',__\\ \  _ `\
*     //'/'___\ \ \/\ \/\ \/\ \Z\ \ \_\ \_\ \ \/\__, `\\ \ \ \ \
*     /\_______\ \_\ \_\ \_\ \____ \/\____\\ \_\/\____/ \ \_\ \_\
*     \/_______/\/_/\/_/\/_/\/___Z\ \/____/ \/_/\/___/   \/_/\/_/
*                             /\____/
*                             \_/__/
*/

/*
*        ________  ______      ______          __        _____
*       |  __   _||_   _ \   .' ___  |        /  |      / ___ `.
*       |_/  / /    | |_) | / .'   \_|  _   __`| |     |_/___) |
*          .'.' _   |  __'. | |        [ \ [  ]| |      .'____.'
*        _/ /__/ | _| |__) |\ `.___.'\  \ \/ /_| |_  _ / /_____
*       |________||_______/  `.____ .'   \__/|_____|(_)|_______|
*
*/

#define BLACK 0x000000FF
#define WHITE 0xFFFFFFFF
#define COLOR_RED 0xE21F1FFF

#define dcmd(%1,%2,%3) if (!strcmp((%3)[1], #%1, true, (%2)) && ((((%3)[(%2) + 1] == '\0') && (dcmd_%1(playerid, ""))) || (((%3)[(%2) + 1] == ' ') && (dcmd_%1(playerid, (%3)[(%2) + 2]))))) return 1

#include <a_samp>

new Text:TextZBC;
new TextZBCHours, TextZBCHoursString[56];
new TextZBCMinutes, TextZBCMinutesString[56];
stock InitializeZBC()
{
    TextZBC = TextDrawCreate(546.000000,22.000000,"--:--");
    TextDrawAlignment(TextZBC,0);
    TextDrawBackgroundColor(TextZBC,BLACK);
    TextDrawFont(TextZBC,3);
    TextDrawLetterSize(TextZBC,0.635,2.4);
    TextDrawColor(TextZBC,WHITE);
    TextDrawSetOutline(TextZBC,1);
    TextDrawSetProportional(TextZBC,1);
    TextDrawSetShadow(TextZBC,1);
}
//------------------------------------------------

public OnFilterScriptInit()
{
    print("\n--Zinglish's Basic Clock loaded.\n");
    InitializeZBC();
    TextZBCMinutes = 00;
    TextZBCHours = 00;
    SetTimer("UpdateTime", 1000, 1);
    SetWorldTime(TextZBCHours);
    return 1;
}

public OnPlayerSpawn(playerid)
{
    TextDrawShowForPlayer(playerid, TextZBC);
    return 1;
}

//Timer for time (lol)
forward UpdateTime(playerid);
public UpdateTime(playerid)
{
    new string[126];
    TextZBCMinutes++;
    // Checks for clock 'defining' minutes limit as 60 and hours limit as 24
    if(TextZBCMinutes == 60)
    {
        TextZBCMinutes = 00;
        if(TextZBCHours == 24)
        {
            TextZBCHours = 00;
        }
        TextZBCHours++;
    }
    if(TextZBCMinutes < 10)
    {
        format(TextZBCMinutesString, sizeof(TextZBCMinutesString), "0%i", TextZBCMinutes);
    }
    if(TextZBCMinutes > 10)
    {
        format(TextZBCMinutesString, sizeof(TextZBCMinutesString), "%i", TextZBCMinutes);
    }
    if(TextZBCHours < 10)
    {
        format(TextZBCHoursString, sizeof(TextZBCHoursString), "0%i", TextZBCHours);
    }
    if(TextZBCHours > 10)
    {
        format(TextZBCHoursString, sizeof(TextZBCHoursString), "%i", TextZBCHours);
    }
    format(string, sizeof(string), "%s:%s", TextZBCHoursString, TextZBCMinutesString);
    for(new i  =0; i<MAX_PLAYERS; i++)
    {
        if(IsPlayerConnected(i))
        {
            SetPlayerTime(i, TextZBCHours, TextZBCMinutes);
        }
    }
    TextDrawSetString(TextZBC, string);
}

public OnPlayerCommandText(playerid, cmdtext[])
{
    dcmd(time,4,cmdtext);

    return 0;
}

dcmd_time(playerid, params[])
{
    new time;
    if(sscanf(params, "i", time))
    {
        if(IsPlayerAdmin(playerid))
        {
            SendClientMessage(playerid, COLOR_RED, "Usage: /time <0-24>");
            SendClientMessage(playerid, COLOR_RED, "Sets global time");
        }
    }
    else if(IsPlayerAdmin(playerid))
    {
        if(time < 0 || time >24)
        {
            SendClientMessage(playerid, COLOR_RED, "Time must be between 0 and 24 hours");
        }
        else if(time <= 24 && time >= 0)
        {
            TextZBCHours = time;
        }
    }
    else if(!IsPlayerAdmin(playerid))
    {
        SendClientMessage(playerid, COLOR_RED, "You must be admin for this command to work");
    }

    return 1;
}


// -------------------------------------------------------------------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------------------------------------------------------------------

stock sscanf(string[], format[], {Float,_}:...)
{
    #if defined isnull
        if (isnull(string))
    #else
        if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
    #endif
        {
            return format[0];
        }
    #pragma tabsize 4
    new
        formatPos = 0,
        stringPos = 0,
        paramPos = 2,
        paramCount = numargs(),
        delim = ' ';
    while (string[stringPos] && string[stringPos] <= ' ')
    {
        stringPos++;
    }
    while (paramPos < paramCount && string[stringPos])
    {
        switch (format[formatPos++])
        {
            case '\0':
            {
                return 0;
            }
            case 'i', 'd':
            {
                new
                    neg = 1,
                    num = 0,
                    ch = string[stringPos];
                if (ch == '-')
                {
                    neg = -1;
                    ch = string[++stringPos];
                }
                do
                {
                    stringPos++;
                    if ('0' <= ch <= '9')
                    {
                        num = (num * 10) + (ch - '0');
                    }
                    else
                    {
                        return -1;
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num * neg);
            }
            case 'h', 'x':
            {
                new
                    ch,
                    num = 0;
                while ((ch = string[stringPos]) > ' ' && ch != delim)
                {
                    switch (ch)
                    {
                        case 'x', 'X':
                        {
                            num = 0;
                            continue;
                        }
                        case '0' .. '9':
                        {
                            num = (num << 4) | (ch - '0');
                        }
                        case 'a' .. 'f':
                        {
                            num = (num << 4) | (ch - ('a' - 10));
                        }
                        case 'A' .. 'F':
                        {
                            num = (num << 4) | (ch - ('A' - 10));
                        }
                        default:
                        {
                            return -1;
                        }
                    }
                }
                setarg(paramPos, 0, num);
            }
            case 'c':
            {
                setarg(paramPos, 0, string[stringPos++]);
            }
            case 'f':
            {
                setarg(paramPos, 0, _:floatstr(string[stringPos]));
            }
            case 'p':
            {
                delim = format[formatPos++];
                continue;
            }
            case '\'':
            {
                new
                    end = formatPos - 1,
                    ch;
                while ((ch = format[++end]) && ch != '\'') {}
                if (!ch)
                {
                    return -1;
                }
                format[end] = '\0';
                if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
                {
                    if (format[end + 1])
                    {
                        return -1;
                    }
                    return 0;
                }
                format[end] = '\'';
                stringPos = ch + (end - formatPos);
                formatPos = end + 1;
            }
            case 'u':
            {
                new
                    end = stringPos - 1,
                    id = 0,
                    bool:num = true,
                    ch;
                while ((ch = string[++end]) && ch != delim)
                {
                    if (num)
                    {
                        if ('0' <= ch <= '9')
                        {
                            id = (id * 10) + (ch - '0');
                        }
                        else
                        {
                            num = false;
                        }
                    }
                }
                if (num && IsPlayerConnected(id))
                {
                    setarg(paramPos, 0, id);
                }
                else
                {
                    #if !defined foreach
                        #define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
                        #define __SSCANF_FOREACH__
                    #endif
                    string[end] = '\0';
                    num = false;
                    new
                        name[MAX_PLAYER_NAME];
                    id = end - stringPos;
                    foreach (Player, playerid)
                    {
                        GetPlayerName(playerid, name, sizeof (name));
                        if (!strcmp(name, string[stringPos], true, id))
                        {
                            setarg(paramPos, 0, playerid);
                            num = true;
                            break;
                        }
                    }
                    if (!num)
                    {
                        setarg(paramPos, 0, INVALID_PLAYER_ID);
                    }
                    string[end] = ch;
                    #if defined __SSCANF_FOREACH__
                        #undef foreach
                        #undef __SSCANF_FOREACH__
                    #endif
                }
                stringPos = end;
            }
            case 's', 'z':
            {
                new
                    i = 0,
                    ch;
                if (format[formatPos])
                {
                    while ((ch = string[stringPos++]) && ch != delim)
                    {
                        setarg(paramPos, i++, ch);
                    }
                    if (!i)
                    {
                        return -1;
                    }
                }
                else
                {
                    while ((ch = string[stringPos++]))
                    {
                        setarg(paramPos, i++, ch);
                    }
                }
                stringPos--;
                setarg(paramPos, i, '\0');
            }
            default:
            {
                continue;
            }
        }
        while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
        {
            stringPos++;
        }
        while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
        {
            stringPos++;
        }
        paramPos++;
    }
    do
    {
        if ((delim = format[formatPos++]) > ' ')
        {
            if (delim == '\'')
            {
                while ((delim = format[formatPos++]) && delim != '\'') {}
            }
            else if (delim != 'z')
            {
                return delim;
            }
        }
    }
    while (delim > ' ');
    return 0;
}