Tr1viUm

// TrivTransport by Tr1viUm

#include <a_samp>

// COLOR
#define TRIV_TRANSPORT_COLOR 0xA1B1BAA

// COSTS
#define TRAIN_COST 12
#define AIRPORT_COST 150

// MENUS
new Menu:train_menu;
new Menu:airport_menu;

// TRAIN STATION
new pickups_train[5];
new Float:train_stations[5][4] = {
    {1767.0929,-1949.7094,14.1096,353.9789}, // Train Station - Unity station
    {816.9966,-1361.7493,-0.5078,317.9242}, // Train Station - Market Station
    {-1959.2285,137.8699,27.6940,268.4318}, // Train Station - Cranberry Station
    {1436.5896,2620.3301,11.3926,97.9844}, // Train Station - Prickle Pine Station
    {2855.1130,1290.0981,11.3906,273.5092} // Train Station - Linden Station
};

// AIRPORTS
new pickups_airport[3];
new Float:airports[3][4] = {
    {1642.1951,-2334.6511,13.5469,0.6866}, // Airport - Los Santos
    {-1409.9064,-298.7570,14.1484,130.2494}, // Airport - San Fierro
    {1673.7072,1447.7372,10.7847,270.4063} // Airport - Las Venturas
};


public OnFilterScriptInit(){

    train_menu = CreateMenu("Train Station", 2, 125.0, 125.0, 200.0, 200.0);
    AddMenuItem(train_menu, 0, "Los Santos");
    AddMenuItem(train_menu, 1, "Unity Station");
    AddMenuItem(train_menu, 0, "Los Santos");
    AddMenuItem(train_menu, 1, "Market Station");
    AddMenuItem(train_menu, 0, "San Fierro");
    AddMenuItem(train_menu, 1, "Cranberry Station");
    AddMenuItem(train_menu, 0, "Las Venturas");
    AddMenuItem(train_menu, 1, "Prickle Pine Station");
    AddMenuItem(train_menu, 0, "Las Venturas");
    AddMenuItem(train_menu, 1, "Linden Station");

    airport_menu = CreateMenu("Airport", 2, 125.0, 125.0, 200.0, 200.0);
    AddMenuItem(airport_menu, 0, "Los Santos");
    AddMenuItem(airport_menu, 1, "Airport");
    AddMenuItem(airport_menu, 0, "San Fierro");
    AddMenuItem(airport_menu, 1, "Airport");
    AddMenuItem(airport_menu, 0, "Las Venturas");
    AddMenuItem(airport_menu, 1, "Airport");

    for(new x = 0; x < 5; x++){
        pickups_train[x] = CreatePickup(1239, 2, train_stations[x][0], train_stations[x][1], train_stations[x][2]);
        if(x < 3){
            pickups_airport[x] = CreatePickup(1239, 2, airports[x][0], airports[x][1], airports[x][2]);
        }
    }

    print("\n TrivTransport ~ Loaded\n");
    return 1;
}

public OnFilterScriptExit(){

    DestroyMenu(train_menu);
    DestroyMenu(airport_menu);

    for(new x = 0; x < sizeof(train_stations); x++){
        DestroyPickup(pickups_train[x]);
        if(x < 3){
            DestroyPickup(pickups_airport[x]);
        }
    }

    print("\n TrivTransport ~ Unloaded\n");
    return 1;
}

public OnPlayerPickUpPickup(playerid, pickupid){

    for(new x = 0; x < 5; x++){
        if(pickupid == pickups_train[x]){
            ShowMenuForPlayer(train_menu, playerid);
            TogglePlayerControllable(playerid, 0);
            break;
        }
        if(x < 3){
            if(pickupid == pickups_airport[x]){
                ShowMenuForPlayer(airport_menu, playerid);
                TogglePlayerControllable(playerid, 0);
                break;
            }
        }
    }
    return 1;
}

public OnPlayerSelectedMenuRow(playerid, row){
    new Menu:player_menu = GetPlayerMenu(playerid);

    if(player_menu == train_menu){
        if(GetPlayerMoney(playerid) < TRAIN_COST){
            return SendClientMessage(playerid, TRIV_TRANSPORT_COLOR, "Insufficient money.");
        }
        SetPlayerPos(playerid, train_stations[row][0], train_stations[row][1], train_stations[row][2]);
        SetPlayerFacingAngle(playerid, train_stations[row][3]);
        GivePlayerMoney(playerid, -TRAIN_COST);
        TogglePlayerControllable(playerid, 1);
    }
    else if(player_menu == airport_menu){
        if(GetPlayerMoney(playerid) < AIRPORT_COST){
            return SendClientMessage(playerid, TRIV_TRANSPORT_COLOR, "Insufficient money.");
        }
        SetPlayerPos(playerid, airports[row][0], airports[row][1], airports[row][2]);
        SetPlayerFacingAngle(playerid, airports[row][3]);
        GivePlayerMoney(playerid, -AIRPORT_COST);
        TogglePlayerControllable(playerid, 1);
    }

    return 1;
}

public OnPlayerExitedMenu(playerid){
    TogglePlayerControllable(playerid, 1);
    return 1;
}