NMM_ROC

#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Magenta
#property indicator_color2 Silver
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int     NMM_ROC_period = 40;
extern int     NMM_ROC_LB     = 3;
extern int     NMM_ROC_AvgLen = 3;
extern bool    Show_SD        = true;
extern int     SD_len         = 30;
extern double  SD_up          = 2;
extern double  SD_dn          = 2;

double NMM_ROC[];
double SD[];
double NMM[];
double NMM_ROCx[];

int init()
{
  string nmmrocname = "NMM_ROC(" + NMM_ROC_period + ", " + NMM_ROC_LB + ", " + NMM_ROC_AvgLen + ")";
  string sdname = "NMM_ROC_SD(" + SD_len + ")";
  IndicatorShortName(nmmrocname);
  IndicatorBuffers(4);
  SetIndexBuffer(0, NMM_ROC);
  SetIndexLabel(0, nmmrocname);
  SetIndexBuffer(1, SD);
  SetIndexLabel(1, sdname);
  SetIndexBuffer(2, NMM);
  SetIndexBuffer(3, NMM_ROCx);
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();

  if(Bars <= NMM_ROC_period + NMM_ROC_LB + NMM_ROC_AvgLen) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMM_ROC_period) limit = Bars - counted_bars;
  else                              limit = Bars - NMM_ROC_period - 1;

  for(i = limit; i >= 0; i--)
    {
    double nmm2 = 0;
    for(ii = 1; ii <= NMM_ROC_period; ii++)
      nmm2 += (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
    NMM[i] = (nmm2 / NMM_ROC_period)  * 1000;
    }

  for(i = limit; i >= 0; i--)
    if(i < Bars - NMM_ROC_period - 1 - NMM_ROC_LB)
      NMM_ROCx[i] = NMM[i] - NMM[i+NMM_ROC_LB];

  for(i = limit; i >= 0; i--)
    if(i < Bars - NMM_ROC_period - 1 - NMM_ROC_LB - NMM_ROC_AvgLen)
      {
      double WtdSum = 0;
      for(ii = 0; ii < NMM_ROC_AvgLen; ii++)
        WtdSum += (NMM_ROC_AvgLen - ii) * NMM_ROCx[i+ii];
      NMM_ROC[i] = WtdSum / ((NMM_ROC_AvgLen + 1) * NMM_ROC_AvgLen * 0.5);
      }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMM_ROC_period - 1 - NMM_ROC_LB - NMM_ROC_AvgLen - SD_len)
        {
        if(NMM_ROC[i] == 0)     SD[i] = 0;
        else if(NMM_ROC[i] > 0) SD[i] = iBandsOnArray(NMM_ROC, 0, SD_len, SD_up, 0, MODE_UPPER, i);
        else if(NMM_ROC[i] < 0) SD[i] = iBandsOnArray(NMM_ROC, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
        }

  return(0);
}