Enpass 5.2.0 - Arch PKGBUILD

pkgname=enpass-bin
_pkgname=enpass
pkgrel=2
pkgdesc="A multiplatform password manager"
arch=('i686' 'x86_64')
url="http://enpass.io/"
license=('custom')
depends=('libxss' 'lsof')
install=enpass-bin.install
case $CARCH in
    'x86_64')
        _arch='amd64'
        sha256sums=(
            'f6ca52edf0e6c0a075e93f823b9395a0e8c5a3217231d139b8cd40c2ca5e71f6'
        )
        pkgver=5.2.0.1
        source=(http://repo.sinew.in/pool/main/e/enpass/${_pkgname}_${pkgver}_${_arch}.deb)
        ;;
    'i686')
        _arch='i386'
        sha256sums=(
            '14695d8549d7ca7ff0612d687b49e4ad6e8a41863be94e8cacabc8c21f6069c5'
        )
        pkgver=5.2.0
        source=(http://repo.sinew.in/pool/main/e/enpass/${_pkgname}_${pkgver}_${_arch}.deb)
        ;;
esac


package() {
    # Extract data
    tar xfz ${srcdir}/data.tar.gz -C ${pkgdir}/

    # Symlink libssl
    ln -s /opt/Enpass/lib/libssl.so.1.0.0 ${pkgdir}/opt/Enpass/lib/libssl.so

    # Remove unnecessary files which are included in the .deb
    find ${pkgdir} -name ".DS_Store" -delete
    find ${pkgdir} -name "._.DS_Store" -delete
    find ${pkgdir} -name "._enpass.png" -delete

    # Update permissions to match the default system ones
    chmod 755 ${pkgdir}/opt/
    find ${pkgdir}/usr/ -type d -exec chmod 755 {} \;

    # Symlink "runenpass.sh" to "/usr/bin" so it is accessible via terminal
    mkdir -p ${pkgdir}/usr/bin
    ln -s /opt/Enpass/bin/runenpass.sh ${pkgdir}/usr/bin/enpass
}