NMS_with_Ocn_MAs

#property indicator_separate_window
#property indicator_buffers 3
#property indicator_color1 Magenta
#property indicator_color2 Yellow
#property indicator_color3 Aqua
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int     NMS_period  = 40;
extern int     NMA_period  = 40;
extern int     NMA_LB_min  = 8;

double NMS[];
double NMS_NMA[];
double NMS_FastNMA[];

int init()
{
  IndicatorShortName("NMS_with_Ocn_MAs(" + NMS_period + ", " + NMA_period + ", " + NMA_LB_min + ")");
  IndicatorBuffers(3);
  SetIndexBuffer(0, NMS);
  SetIndexLabel(0, "NMS(" + NMS_period + ")");
  SetIndexBuffer(1, NMS_NMA);
  SetIndexLabel(1, "NMS_NMA(" + NMA_period + ")");
  SetIndexBuffer(2, NMS_FastNMA);
  SetIndexLabel(2, "NMS_FastNMA(" + NMA_period + ", " + NMA_LB_min + ")");
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();
  double nms2, sum, abssum, ratio, nmsnum, maxnms;

  if(Bars <= NMS_period) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMS_period) limit = Bars - counted_bars;
  else                          limit = Bars - NMS_period - 1;

  for(i = limit; i >= 0; i--)
    {
    nms2 = 0;
    for(ii = 1; ii <= NMS_period; ii++)
      {
      double oLRSlope = 0, SumXY = 0, SumY = 0, SumX, SumXSqr, Divisor;
      if(ii > 1)
        {
        SumX = ii * (ii - 1) * 0.5;
        SumXSqr = ii * (ii - 1) * (2 * ii - 1) * 1/6;
        Divisor = (SumX * SumX) - ii * SumXSqr;
        for(int iii = 0; iii < ii; iii++)
          {
          SumXY += iii * MathLog(Close[i+iii]);
          SumY += MathLog(Close[i+iii]);
          }
        oLRSlope = (ii * SumXY - SumX * SumY) / Divisor;
        }
      nms2 += oLRSlope * MathSqrt(ii);
      }
    NMS[i] = nms2 * 100;
    }

  for(i = limit; i >= 0; i--)
    if(i < Bars - NMS_period - 1 - NMA_period)
      {
      ratio = 0;
      sum = (NMS[i] - NMS[i+1]) + (NMS[i+1] - NMS[i+2]) * (MathSqrt(2)-1);
      for(ii = 2; ii < NMA_period; ii++)
        sum += (NMS[i+ii] - NMS[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
      abssum = MathAbs(sum);
      sum = 0;
      for(ii = 0; ii < NMA_period; ii++)
        sum += MathAbs(NMS[i+ii] - NMS[i+ii+1]);
      if(sum != 0) ratio = abssum / sum;
      NMS_NMA[i] = NMS_NMA[i+1] + (NMS[i] - NMS_NMA[i+1]) * ratio;
      }

  for(i = limit; i >= 0; i--)
    if(i < Bars - NMS_period - 1 - NMA_period)
      {
      maxnms = 0; ratio = 0;
      int NMA_LB_max;
      for(ii = 1; ii <= NMA_period; ii++)
        {
        nmsnum = (NMS[i] - NMS[i+ii]) / MathSqrt(ii);
        if(MathAbs(nmsnum) > maxnms) { maxnms = MathAbs(nmsnum); NMA_LB_max = ii; }
        }
      if(NMA_LB_max < NMA_LB_min) NMA_LB_max = NMA_LB_min;
      sum = (NMS[i] - NMS[i+1]) + (NMS[i+1] - NMS[i+2]) * (MathSqrt(2)-1);
      for(ii = 2; ii < NMA_LB_max; ii++)
        sum += (NMS[i+ii] - NMS[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
      abssum = MathAbs(sum);
      sum = 0;
      for(ii = 0; ii < NMA_LB_max; ii++)
        sum += MathAbs(NMS[i+ii] - NMS[i+ii+1]);
      if(sum != 0) ratio = abssum / sum;
      NMS_FastNMA[i] = NMS_FastNMA[i+1] + (NMS[i] - NMS_FastNMA[i+1]) * ratio;
      }

  return(0);
}