OREGONA

see paste http://pastebin.com/tjDcWSLg for listing 1 which is needed for this

 5 QS = 50
 10  SCALE= 1: ROT= 0: POKE 232,170: POKE 233,50: IN# 0: PR# 0
 30 P1 = 261:Q1 = 99
 40 Y1 = 600: GOSUB 50:A = Y: GOSUB 50:F = Y: GOSUB 50:B = Y: GOSUB 50:C = Y: GOSUB 50:M1 = Y: GOSUB 50:D9 = Y: GOTO 95
 50 Y =  VAL ( STR$ ( PEEK (Y1)) +  STR$ ( PEEK (Y1 + 1)) +  STR$ ( PEEK (Y1 + 2))):Y1 = Y1 + 3: RETURN
 95  HOME :ZM = 20
 96  HIMEM: 12970
 105 X1 = 1
 110 T = 700 - (A + F + B + C + M1):B = B * 50
 190 D3 = D3 + 1
 200  IF K8 = 1 OR S4 = 1 THEN T = T - 20: IF T < 0 THEN 5080
 201 X =  FRE (0): GOSUB 17000: IF IG = 1 THEN 6050
 202  IF K8 = 1 OR S4 = 1 THEN K8 = 0:S4 = 0: VTAB 7: PRINT "THE DOCTOR'S BILL IS $20.": GOSUB 12000
 205  IF F < 13 THEN  VTAB 8: PRINT "YOU'D BETTER DO SOME HUNTING": PRINT "OR BUY SOME FOOD AND SOON!"
 207  GOSUB 12000: GOSUB 12500:X1 = X1 *  - 1
 210  IF X1 = 1 THEN 270
 215  VTAB 11: PRINT "DO YOU WANT TO-": PRINT : PRINT "  1. STOP AT THE NEXT FORT": PRINT "  2. HUNT": PRINT "  3. CONTINUE"
 220 GT = 51: PRINT : PRINT "WHICH NUMBER?";: GOSUB 40000:X =  VAL (A$): GOTO 290
 270  VTAB 11: PRINT "DO YOU WANT TO-": PRINT : PRINT "  1. HUNT": PRINT "  2. CONTINUE":GT = 50
 275  PRINT : PRINT "WHICH NUMBER? ";: GOSUB 40000:X =  VAL (A$) + 1
 280 X =  VAL (A$) + 1
 290  IF X = 2 AND B > 40 OR X <  > 2 THEN A1 = 2:A2 = 3: GOTO 300
 292  VTAB 20: PRINT "TOUGH-YOU NEED MORE BULLETS TO HUNT!": GOSUB 500
 294  VTAB 20: CALL  - 868: GOSUB 10000: GOTO 210
 300  ON X GOTO 350,1000,3000
 350  GOSUB 10050: GOSUB 10000: VTAB 8: PRINT "HOW MUCH DO YOU WANT TO SPEND ON-"
 355  GOSUB 10000: VTAB 11: PRINT "FOOD? ";: GOSUB 525:F7 =  VAL (ZN$): IF T - F7 < 0 THEN  GOSUB 400: GOTO 355
 360 T = T - F7:F = F + 2 / 3 * F7: GOSUB 12000
 365  GOSUB 10000: VTAB 11: PRINT "AMMUNITION? ";: GOSUB 525:A7 =  VAL (ZN$): IF T - A7 < 0 THEN  GOSUB 400: GOTO 365
 370 T = T - A7:B =  INT (B + 2 / 3 * A7 * 50): GOSUB 12000
 375  GOSUB 10000: VTAB 11: PRINT "CLOTHES? ";: GOSUB 525:C7 =  VAL (ZN$): IF T - C7 < 0 THEN  GOSUB 400: GOTO 375
 380 T = T - C7:C = C + 2 / 3 * C7: GOSUB 12000
 385  GOSUB 10000: VTAB 11: PRINT "MISCELLANEOUS? ";: GOSUB 525:M7 =  VAL (ZN$): IF T - M7 < 0 THEN  GOSUB 400: GOTO 385
 390 T = T - M7:M1 = M1 + 2 / 3 * M7: GOSUB 12000: GOTO 3000
 400  VTAB 15: PRINT "YOU DON'T HAVE THAT MUCH MONEY LEFT!": GOSUB 500: RETURN
 500  FOR G = 1 TO 1000: NEXT G: POKE  - 16368,0
 505  VTAB 24: CALL  - 868: HTAB 7: POKE  - 16368,0: PRINT "PRESS ";: INVERSE : PRINT "SPACE BAR";: NORMAL : PRINT " TO CONTINUE";: WAIT  - 16384,128: POKE  - 16368,0: HTAB 1: CALL  - 868: HOME : RETURN
 525  POKE  - 16368,0:CH =  PEEK (36):CV =  PEEK (37)
 530  INPUT "";ZN$: IF  LEN (ZN$) <  >  LEN ( STR$ ( VAL (ZN$))) THEN 540
 535  IF  VAL (ZN$) <  > 0 OR ZN$ = "0" THEN 550
 540  VTAB ZM: PRINT "I CAN'T UNDERSTAND YOUR ANSWER."
 545  PRINT "PLEASE TYPE A NUMBER.": GOSUB 555: GOTO 530
 550  VTAB ZM: CALL  - 868: VTAB ZM + 1: CALL  - 868: VTAB CV + 1 + (CV < 23):ZN =  VAL (ZN$): RETURN
 555  VTAB CV + 1: POKE 36,CH: CALL  - 868: RETURN
 1000 S1 = 0: HOME :T7 = 0: HGR2
 1001 Z1 = 70:Z2 = 172:Z$ = "PRESS ANY KEY TO SHOOT": GOSUB 30000
 1010  HCOLOR= 1: FOR G = 20 TO 260 STEP 40:SL =  RND (1):SH = 1: IF SL < .5 THEN SH = 7
 1012 FR =  INT ( RND (1) * 15): DRAW SH AT G,FR: DRAW SH AT G + 1,FR: NEXT G
 1015  POKE  - 16368,0:KP = 166:HS = 0:SH = 0
 1020 PK = 46
 1030 X =  PEEK ( - 16384): IF X > 127 AND KP = 166 THEN  FOR G = 1 TO 20:X =  PEEK ( - 16336): NEXT G:SH = 1: GOSUB 35000
 1040 PK = PK +  INT ( RND (1) * 25): IF PK > 260 THEN 1020
 1050  HCOLOR= 3: DRAW A1 AT PK,55
 1054  IF SH = 1 THEN  GOSUB 1200
 1056  IF HS > 0 THEN  GOSUB 1400: IF HS = 1 AND (A1 = 5 OR A1 = 13) THEN 3170
 1057  IF HS > 0 THEN HS = 0:T7 = T7 + 1: IF T7 > D9 THEN  FOR G = 1 TO 1000: NEXT G: GOTO 1430
 1058  FOR T2 = 1 TO 10: NEXT T2: HCOLOR= 0: DRAW A1 AT PK,55
 1059 X =  PEEK ( - 16384): IF X > 127 AND KP = 166 THEN  FOR G = 1 TO 20:X =  PEEK ( - 16336): NEXT G:SH = 1: GOSUB 35000
 1060 PK = PK +  INT ( RND (1) * 25): IF PK > 260 THEN 1020
 1062  HCOLOR= 3: DRAW A2 AT PK,55: FOR T2 = 1 TO 10: NEXT T2
 1070  IF SH = 1 THEN  GOSUB 1200
 1075  IF HS > 0 THEN  GOSUB 1400: IF HS = 1 AND (A1 = 5 OR A1 = 13) THEN 3170
 1077  IF HS > 0 THEN HS = 0:T7 = T7 + 1: IF T7 > D9 THEN  FOR G = 1 TO 1000: NEXT G: GOTO 1430
 1080  FOR T2 = 1 TO 10: NEXT T2: HCOLOR= 0: DRAW A2 AT PK,55: GOTO 1030
 1200  HCOLOR= 0: DRAW 4 AT 130,KP: HCOLOR= 3:KP = KP - 9: DRAW 4 AT 130,KP: IF KP > 70 THEN  RETURN
 1202  HCOLOR= 0: DRAW 4 AT 130,KP: DRAW A1 AT PK,55: DRAW A2 AT PK,55: POKE  - 16368,0
 1203 SH = 0:KP = 166
 1210  IF PK < 125 OR PK > 173 THEN HS = 2: RETURN
 1220 HS = 1: RETURN
 1400  IF HS = 1 THEN Z1 = 100:Z2 = 183: PRINT  CHR$ (7):Z$ = "DIRECT HIT": GOSUB 30000: PRINT  CHR$ (7):S1 = S1 + 1:PK = 46: RETURN
 1420 Z1 = 100:Z2 = 183:Z$ = "YOU MISSED": GOSUB 30000: RETURN
 1430  HGR2 : IF A1 = 5 THEN 3170
 1435 F = F + S1 * ( INT ( RND (1) * 10) + 5):B = B - 8 * D9
 3000  GOSUB 10050: GOSUB 10000:QS = 255: GOSUB 12000: GOSUB 12500:QS = 50
 3005  IF F < 13 THEN 5060
 3010  VTAB 10: PRINT "DO YOU WANT TO EAT-": PRINT : PRINT "  1. POORLY": PRINT "  2. MODERATELY": PRINT "  3. WELL"
 3015  PRINT : PRINT "WHICH NUMBER? ";:GT = 51: GOSUB 40000
 3020 E =  VAL (A$):F = F - 8 - 5 * E: IF F >  = 0 THEN 3050
 3025 F = F + 8 + 5 * E: VTAB 21: PRINT "YOU CAN'T EAT THAT WELL!": GOSUB 500: GOTO 3000
 3050 M = M + 200 + (A - 220) / 5 +  INT ( RND (1) * 10)
 3054 L1 = 0:C1 = 0: GOSUB 12000
 3100  IF  RND (1) * 10 > ((M / 100 - 4) ^ 2 + 72) / ((M / 100 - 4) ^ 2 + 12) - 1 THEN 4010
 3110  GOSUB 10050: GOSUB 10000: VTAB 10: PRINT "RIDERS AHEAD...THEY":S5 = 0: IF  RND (1) > .8 THEN  PRINT "DON'T ";:S5 = 1
 3120  PRINT "LOOK HOSTILE.": PRINT : PRINT "TACTICS -": PRINT : PRINT "  1. RUN": PRINT "  2. ATTACK"
 3130  PRINT "  3. CONTINUE": PRINT "  4. CIRCLE YOUR WAGONS": PRINT : PRINT "WHICH NUMBER? ";:GT = 52: GOSUB 40000:T1 =  VAL (A$)
 3135  IF  RND (1) > .8 THEN S5 = S5 - 1
 3140  IF S5 = 1 THEN 3300
 3145  IF T1 > 1 THEN 3150
 3146 M = M + 20:M = M - 15:B = B - 150:A = A - 40: GOTO 3470
 3150  IF T1 = 3 THEN 3200
 3152 HT = 1:D8 = 0
 3165 A1 = 5:A2 = 6: GOTO 1000
 3170  HGR2 : HOME : TEXT : GOSUB 12000: GOSUB 12500: VTAB 12: IF B8 > 0 THEN  ON B8 GOTO 3965,4350
 3174 B = B - (T7 * 40 - 50)
 3176  IF T1 = 4 THEN M = M - 25
 3180  IF HS = 0 THEN  PRINT "LOUSY SHOOTING - - - YOU GOT KNIFED":K8 = 1: PRINT "YOU'LL HAVE TO SEE 'OL DOC BLANCHARD!": GOSUB 500
 3190  GOTO 3470
 3200  IF  RND (1) > .8 THEN  PRINT "YOU ARE LUCKY...": PRINT "THEY DIDN'T ATTACK.": GOSUB 500: GOTO 190
 3210 B = B - 150:M1 = M1 - 15: GOTO 3470
 3300  IF T1 > 1 THEN 3370
 3305 M = M + 15:A = A - 10: GOTO 3470
 3370  IF T1 > 2 THEN 3410
 3375 M = M - 5:B = B - 100
 3410  IF T1 = 4 THEN M = M - 20
 3470  GOSUB 10000: GOSUB 10050: VTAB 12: IF S5 = 1 THEN  PRINT "THE RIDERS WERE FRIENDLY,": PRINT "BUT CHECK FOR POSSIBLE LOSSES!": GOSUB 500: GOTO 190
 3500  PRINT "THE RIDERS WERE HOSTILE.": PRINT "CHECK FOR LOSSES!": IF B >  = 0 THEN  GOSUB 500: GOTO 190
 3510  PRINT "YOU RAN OUT OF BULLETS,": PRINT "AND YOU WERE MASACRED!": GOTO 5170
 3660  PRINT "YOUR WAGON HAS BROKEN DOWN...": PRINT "LOSE TIME AND SUPPLIES FIXING IT.":M = M - 15 - 5 *  RND (1):M1 = M1 - 8: GOTO 4710
 3700  PRINT "OX INJURES LEG. SLOWS YOU": PRINT "DOWN FOR THE REST OF THE TRIP"::M = M - 25:A = A - 20: GOTO 4710
 3740  PRINT "BAD LUCK. YOUR DAUGHTER BROKE HER": PRINT "ARM, YOU USED SUPPLIES HELPING HER.":M = M - 5 - 4 *  RND (1):M1 = M1 - 2 - 3 *  RND (1): GOTO 4710
 3790  PRINT "OX WANDERS OFF.": PRINT "YOU SPEND TIME LOOKING FOR IT.":M = M - 17: GOTO 4710
 3820  PRINT "YOUR SON GOT LOST.": PRINT "SPEND TIME LOOKING FOR HIM.":M = M - 10: GOTO 4710
 3850  PRINT "UNSAFE WATER.": PRINT "SPEND TIME LOOKING FOR CLEAR SPRING":M = M - 10 *  RND (1) - 2: GOTO 4710
 3880  IF M > 950 THEN 4490
 3890  PRINT "HEAVY RAINS.": PRINT "TIME AND SUPPLIES LOST.":F = F - 10:B = B - 500:M1 = M1 - 15:M = M - 10 *  RND (1) - 5: GOTO 4710
 3960  PRINT "BANDITS ATTACKING!": GOSUB 30700
 3961 B8 = 1: GOTO 3165
 3965 B8 = 0:B = B - 20 * T7: IF B < 0 THEN  PRINT "YOU RAN OUT OF BULLETS!": PRINT "THEY GET LOTS OF CASH!":T = T / 3: GOTO 4040
 3967  IF HS = 1 THEN  PRINT "QUICKEST DRAW OUTSIDE OF DODGE CITY!": PRINT "YOU GOT 'EM.": GOTO 4710
 3968  PRINT "YOU GOT SHOT IN THE LEG AND THEY TOOK": PRINT "ONE OF YOUR OXEN.":K8 = 1: PRINT "BETTER HAVE A DOC LOOK AT YOUR WOUND!!"
 3969 M1 = M1 - 5:A = A - 20: GOTO 4710
 4000  GOSUB 500: TEXT
 4010  GOSUB 10000: GOSUB 10050: RESTORE : FOR G = 1 TO 20: READ G7$: NEXT G:R1 = 100 *  RND (1):D1 = 0
 4020 D1 = D1 + 1: IF D1 = 16 THEN 4670
 4025  READ D: IF R1 > D THEN 4020
 4035  ON D1 GOTO 3660,3700,3740,3790,3820,3850,3880,3960,4130,4190
 4036  PRINT
 4037  ON D1 - 10 GOTO 4220,4290,4340,4560,4610,4670
 4040  PRINT : PRINT "YOU GOT SHOT IN THE LEG AND THEY TOOK": PRINT "ONE OF YOUR OXEN.":M1 = M1 - 5:A = A - 20:K8 = 1
 4041  PRINT : PRINT "BETTER HAVE A DOC LOOK AT YOUR WOUND.": GOTO 4710
 4130  PRINT "THERE WAS A FIRE IN YOUR WAGON.": PRINT "FOOD AND SUPPLIES DAMAGED":F = F - 40:B = B - 400:M1 = M1 - 10 - 5 *  RND (1) * 8 - 3:M = M - 15: GOTO 4710
 4190  PRINT "LOSE YOUR WAY IN HEAVY FOG-TIME IS LOST":M = M - 10 - 5 *  RND (1): GOTO 4710
 4220  PRINT "YOU KILLED A POISONOUS SNAKE AFTER IT ": PRINT "BIT YOU.":B = B - 10:M1 = M1 - 5: IF M1 >  = 0 THEN  PRINT "MEDICINE USED..": PRINT : GOTO 4710
 4260  PRINT : PRINT : PRINT "YOU DIED OF THE BITE, BECAUSE YOU": PRINT : PRINT "DON'T HAVE ANY MEDICINE!": GOTO 5170
 4290  PRINT "WAGON GETS SWAMPED FORDING RIVER - -": PRINT "LOSE FOOD AND CLOTHES":F = F - 30:C = C - 20:M = M - 20 - 20 *  RND (1): GOTO 4710
 4340  PRINT "WILD ANIMALS ATTACK!": GOSUB 500
 4345 A1 = 13:A2 = 14:B8 = 2: GOTO 1000
 4350 B8 = 0: IF M < 950 THEN 190
 4355  GOTO 4720
 4490  PRINT "COLD WEATHER-----BRRRRRR!----": PRINT "YOU ";: IF C > 22 + 4 *  RND (1) THEN 4530
 4510  PRINT "DON'T ";:C1 = 1
 4530  PRINT "HAVE ENOUGH CLOTHES": PRINT "TO KEEP WARM": IF C1 = 0 THEN 4710: GOTO 6300
 4560  PRINT "HAIL STORM---SUPPLIES DAMAGED":M = M - 5 -  RND (1) * 10:B = B - 100:M1 = M1 - 4 -  RND (1) * 3: GOTO 4710
 4610  IF E = 1 THEN 6300
 4620  IF E = 3 THEN 4650
 4630  IF  RND (1) > .25 THEN 6300
 4640  GOTO 4710
 4650  IF  RND (1) < .5 THEN 6300
 4660  GOTO 4710
 4670  PRINT "HELPFUL INDIANS SHOW YOU WHERE TO FIND": PRINT "MORE FOOD":F = F + 14
 4710  IF M < 1050 THEN  GOSUB 30700: GOTO 190
 4715  PRINT
 4720  IF  RND ( - 1) * 10 > 9 - ((M / 100 - 15) ^ 2 + 72) / ((M / 100 - 15) ^ 2 + 12) THEN 4860
 4730  PRINT "RUGGED MOUNTAINS": PRINT : IF  RND (1) > .1 THEN 4780
 4750  PRINT "YOU GOT LOST - LOSE VALUABLE TIME TRYING": PRINT "TO FIND THE TRAIL!": PRINT :M = M - 60: GOTO 4860
 4780  IF  RND (1) > .1 THEN 4840
 4790  PRINT "WAGON DAMAGED! LOSE TIME AND SUPPLIES":M1 = M1 - 5:B = B - 200:M = M - 20 - 30 *  RND ( - 1): PRINT : GOTO 4860
 4840  PRINT "THE GOING IS SLOW":M = M - 45 -  RND (1) / .02: PRINT
 4860  IF F1 = 1 THEN 4900
 4870 F1 = 1
 4880  IF  RND (1) < .8 THEN 4970
 4890  PRINT "YOU MADE IT SAFELY THROUGH SOUTH PASS": PRINT : PRINT "THERE WAS NO SNOW."
 4900  IF M < 1700 THEN 4940
 4910  IF F2 = 1 THEN 4940
 4920 F2 = 1
 4930  IF  RND (1) < .7 THEN 4970
 4940  IF M > 950 THEN  GOSUB 30700: GOTO 190
 4950 M9 = 1: GOSUB 30700: GOTO 190
 4970  PRINT "BLIZZARD IN MOUNTAIN PASS -- TIME AND ": PRINT "SUPPLIES LOST":L1 = 1:F = F - 25:M1 = M1 - 10:B = B - 300:M = M - 30 - 40 *  RND (1)
 5030  IF C < 18 + 2 *  RND (1) THEN 6300
 5040  GOTO 4940
 5060  GOSUB 10000: GOSUB 10050: VTAB 12: PRINT "YOU RAN OUT OF FOOD AND STARVED": PRINT "TO DEATH.": GOTO 5170
 5080 T = 0: PRINT "YOU CAN'T AFFORD A DOCTOR": GOTO 5120
 5110  PRINT "YOU RAN OUT OF MEDICAL SUPPLIES..."
 5120  PRINT "YOU DIED OF ";
 5130  IF K8 = 1 THEN 5160
 5140  PRINT "PNEUMONIA": GOTO 5170
 5160  PRINT "INJURIES"
 5170  GOSUB 30700: POKE  - 16368,0
 5171  TEXT : HOME : PRINT : PRINT : PRINT "DUE TO YOUR UNFORTUNATE SITUATION": PRINT "THERE ARE A FEW FORMALITIES": PRINT "WE MUST GO THROUGH-"
 5210  PRINT "WOULD YOU LIKE A MINISTER";: INPUT C$
 5230  PRINT : PRINT "WOULD YOU LIKE A FANCY FUNERAL";: INPUT C$
 5250  PRINT : PRINT "WOULD YOU LIKE US TO INFORM YOUR NEXT": PRINT "OF KIN";: INPUT C$: IF  LEFT$ (C$,1) = "Y" THEN 5310
 5280  HOME : PRINT "BUT YOUR AUNT SADIE IN ST. LOUIS IS": PRINT "WORRIED ABOUT YOU!": GOTO 5330
 5310  HOME : PRINT : PRINT "THAT WILL BE $4.50 FOR THE TELEGRAPH": PRINT "CHARGE."
 5330  PRINT : PRINT "THANK YOU FOR THIS INFORMATION.": PRINT : PRINT "SORRY YOU DIDN'T MAKE IT TO OREGON!"
 5350  PRINT : PRINT "BETTER LUCK NEXT TIME.": PRINT
 5380  HTAB 20: PRINT "SINCERLY": PRINT : HTAB 5: PRINT "THE OREGON CITY CHAMBER OF COMMERCE": GOSUB 30700: PR# 6
 6050  TEXT : HOME : PRINT : PRINT : RESTORE : FOR G = 1 TO 35: READ X$: NEXT G: SPEED= 100: FOR G = 1 TO 8: READ X$
 6060  FOR Z7 = 1 TO  LEN (X$): PRINT  MID$ (X$,Z7,1);:X =  PEEK ( - 16336):X =  PEEK ( - 16336): NEXT Z7: PRINT : PRINT : NEXT G: GOSUB 30700: PR# 6
 6300  IF 100 *  RND (1) < 10 + 35 * (E - 1) THEN 6370
 6310  IF 100 *  RND (1) < 100 - (40 / 4 ^ (E - 1)) THEN 6410
 6320  PRINT "SERIOUS ILLNESS...": PRINT "YOU MUST STOP FOR MEDICAL ATTENTION!":M1 = M1 - 10:S4 = 1: GOTO 6440
 6370  PRINT "MILD ILLNESS... MEDICINE USED.":M = M - 5:M1 = M1 - 2: GOTO 6440
 6410  PRINT "BAD ILLNESS..MEDICINE USED.":M = M - 5:M1 = M1 - 5
 6430  GOTO 4710
 6440  IF M1 < 0 THEN 5110
 6450  IF L1 = 1 THEN 4940
 6460  GOTO 4710
 10000  TEXT : HTAB 1: VTAB 9: FOR G = 9 TO 23: VTAB G: CALL  - 868: NEXT G: HTAB 1: VTAB 1: RETURN
 10050  TEXT : VTAB 7: HTAB 1: CALL  - 868: VTAB 8: CALL  - 868: RETURN
 11030 X =  PEEK ( - 16384): IF X > 127 AND KP = 166 THEN  FOR G = 1 TO 20:X =  PEEK ( - 16336): NEXT G:SH = 1: HOME
 12000 F =  INT (F):B =  INT (B):C =  INT (C):M1 =  INT (M1):T =  INT (T):M =  INT (M):M2 = M
 12003  IF M9 = 1 THEN M = 950:M9 = 0
 12004  IF F < 0 THEN F = 0
 12005  IF B < 0 THEN B = 0
 12006  IF C < 0 THEN C = 0
 12007  IF M1 < 0 THEN M1 = 0
 12015  VTAB 3: FOR G = 1 TO 40: PRINT "-";: NEXT G: PRINT : VTAB 4: PRINT " FOOD  BULLETS  CLOTHING  MISC.   CASH"
 12018  VTAB 5: CALL  - 868: VTAB 5: SPEED= QS
 12020  HTAB 2: PRINT F;: HTAB 8: PRINT B;: HTAB 17: PRINT C;: HTAB 27: PRINT M1;: HTAB 35: PRINT "   ";: HTAB 35: PRINT T
 12025  SPEED= 255: FOR G = 1 TO 40: PRINT "-";: NEXT G: RETURN
 12050  DATA "MARCH 29","APRIL 12","APRIL 26","MAY 10","MAY 24","JUNE 7","JUNE 21","JULY 5","JULY 19","AUGUST 2"
 12075  DATA "AUGUST 16","AUGUST 31","SEPTEMBER 13","SEPTEMBER 27","OCTOBER 11","OCTOBER 25","NOVEMBER 8"
 12080  DATA "NOVEMBER 22","DECEMBER 6","DECEMBER 20"
 12500  SPEED= QS: VTAB 2: PRINT "MONDAY- ";: RESTORE : FOR G = 1 TO D3: READ A$: NEXT G: PRINT A$",1847";
 12510  FOR G = 1 TO 20 - D3: READ A$: NEXT G: VTAB 2: HTAB 34 -  LEN ( STR$ (M)): PRINT "MILES= "M: FOR G = 1 TO 300: NEXT G: SPEED= 255: RETURN
 14000  DATA 6,11,13,15,17,22,32,35,37,42,44,54,64,69,95
 15000  DATA "INCOMING TELEGRAM"," ","TO NEW RESIDENT OF OREGON TERRITORY-"," ","PRESIDENT JAMES K. POLK SENDS YOU HIS"
 15100  DATA "HEARTIEST CONGRATULATIONS,","AND WISHES YOU A PROSPEROUS LIFE"
 15200  DATA "AHEAD AT YOUR NEW HOME!"
 17000  HGR2 : HCOLOR= 3: DRAW 8 AT 1,1: DRAW 9 AT 1,1
 17001  RESTORE : FOR G = 1 TO D3: READ A$: NEXT G:Z1 = 5:Z2 = 150:Z$ = A$ + " 1847": GOSUB 30000
 17002 Z1 = 150:Z2 = 150:Z$ = "MILES  " +  STR$ ( INT (M)): GOSUB 30000
 17005  IF M = 0 THEN  HCOLOR= 3: DRAW 10 AT P1,Q1:W4 = 1: GOTO 17500
 17006  FOR G = W4 TO  INT (M / 24.8)
 17010  IF P1 = 261 THEN P2 = 4:Q2 = 1
 17020  IF P1 = 165 THEN P2 = 2:Q2 = 0
 17030  IF P1 = 113 THEN P2 = 1:Q2 = 2
 17040  IF P1 = 96 THEN P2 = 2:Q2 = 0
 17050  IF P1 <  = 66 THEN IG = 1: GOTO 17080
 17060  HCOLOR= 3: DRAW 10 AT P1,Q1: FOR X = 1 TO 250: NEXT X: HCOLOR= 0: DRAW 10 AT P1,Q1
 17065  HCOLOR= 3: DRAW 8 AT 1,1: DRAW 9 AT 1,1
 17067 P1 = P1 - P2:Q1 = Q1 - Q2
 17070  NEXT G:W4 =  INT (M / 24.8)
 17075  GOTO 17500
 17080  HCOLOR= 3: DRAW 10 AT P1,Q1: FOR G = 1 TO 500: NEXT G: FOR G = 1 TO 15: HCOLOR= 0: DRAW 10 AT P1,Q1: FOR X = 1 TO 20: NEXT X: HCOLOR= 3: DRAW 10 AT P1,Q1
 17090  PRINT  CHR$ (7): FOR X = 1 TO 20: NEXT X,G
 17500  HCOLOR= 3: DRAW 10 AT P1,Q1:Z$ = "PRESS SPACE BAR TO CONTINUE":Z1 = 40:Z2 = 181: GOSUB 30000: POKE  - 16368,0: GOSUB 505
 17999  HOME : HGR2 : TEXT : RETURN
 30000  FOR Z = 1 TO  LEN (Z$):Z3 =  ASC ( MID$ (Z$,Z,1)): HCOLOR= 3
 30013  IF Z3 = 32 THEN 30050
 30015  DRAW Z3 - 28 AT Z1 + (Z - 1) * 7,Z2: GOTO 30050
 30050  NEXT Z
 30060  RETURN
 30700  GOSUB 505
 30718  HOME : RETURN
 35000  HCOLOR= 0: FOR X = 182 TO 191: HPLOT 90,X TO 180,X: NEXT X: HCOLOR= 3: RETURN
 40000  GET A$: IF  ASC (A$) = 3 THEN  STOP
 40005  IF  ASC (A$) < 49 OR  ASC (A$) > GT THEN 40000
 40010  PRINT A$;
 40020  GET B$: IF  ASC (B$) <  > 13 AND  ASC (B$) <  > 8 THEN 40020
 40030  IF  ASC (B$) = 13 THEN  PRINT : RETURN
 40040  PRINT  CHR$ (8)" " CHR$ (8);: GOTO 40000