API tools faq
paste
Advertisement
Guest User

QTGMC for avs 2.60

a guest
Dec 23rd, 2016
757
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 79.58 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.346, by Vit, 2012, 2016 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.346s
  16. # - EEDI3+NNEDI3 bug fix by ndjamena
  17. # - Renamed DftThreads parameter to FftThreads, to set the ncpu argument of FFT3DFilter (from VS)
  18. # - FFT3DFilter will work now in YUY2, use it with Denoiser="fft3df" (or use NoisePreset)
  19. #
  20. # v3.345s
  21. # - work with SMDegrain_KNLMeansCL now to process chroma too
  22. #
  23. # v3.343s
  24. # - edit in ChromaEdi
  25. # - others
  26. #
  27. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  28. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  29. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  30. #
  31. # v3.33s (mod) 2016 12 06
  32. # - Add TR2=4 and TR2=5
  33. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  34. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  35. #
  36. # v3.33s (mod) 2016 04 11
  37. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  38. # - others
  39. #
  40. # v3.33s (mod) 2016 01 19
  41. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  42. #
  43. # v3.33s (mod) 2015 10 23
  44. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  45. #
  46. # v3.33s (mod) 2015 9 10
  47. # - fix Multiple QTGMC Calls
  48. # - others fix
  49. #
  50. # v3.33s (mod) 2015 8 6
  51. # - some changes in bob to speed up
  52. #
  53. # v3.33s (mod) 2015 8 4
  54. # - fix bug in YUY2 with SourceMatch
  55. # - add slice=false to ditherpost to avoid artefacts
  56. #
  57. # v3.33s (mod)
  58. # - fix bob chroma
  59. # - work with new masktool2 for avs 2.60 in YUY2
  60. #
  61. # v3.33d (mod)
  62. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  63. # - optimized some mask handling a bit as originally suggested by Vit
  64. # - others
  65. #
  66. # v3.33
  67. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  68. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  69. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  70. # - Minor change to denoising
  71. #
  72. # v3.32
  73. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  74. # - Tweaked vector recalculation for shutter motion blur
  75. # - Changed defaults for TR2 when using source-match
  76. # - Minor bugfix with SLMode/SLRad on pass-through settings
  77. #
  78. # --- REQUIREMENTS ---
  79. #
  80. # Input colorspaces: YV12, YUY2, others as plugins supports
  81. #
  82. # Core plugins:
  83. #   MVTools2 (2.7.5.22 or above from pinterf https://github.com/pinterf/mvtools/releases)
  84. #   MaskTools v2 (2.0b1 or above)
  85. #   NNEDI3 (0.9.4.6 or above)
  86. #   RgTools
  87. #
  88. # Additional plugins:
  89. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  90. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  91. #   FFT3DFilter - if selected for noise processing
  92. #   dfttest (1.9.4 or above) - if selected for noise processing
  93. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  94. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  95. #   KNLMeansCL - if selected for noise processing
  96. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  97.  
  98.  
  99. # --- GETTING STARTED ---
  100. #
  101. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  102. # To use QTGMC write a script like this:
  103. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  104. #   QTGMC( Preset="Slow" )
  105. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  106. #
  107. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  108. #
  109. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  110. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  111. # The default preset is "Slower"
  112. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  113. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  114. #
  115. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  116. #   QTGMC( Preset="Slow", ShowSettings=true )
  117.  
  118.  
  119. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  120.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  121.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  122.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  123.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  124.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  125.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  126.                     int "FftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  127.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  128.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  129.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  130.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "lsbd", bool "lsb" )
  131. {
  132.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  133.  
  134.     # Temporary Warnings
  135.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  136.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  137.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  138.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  139.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  140.  
  141.     #---------------------------------------
  142.     # Presets
  143.     lsbd         = default( lsbd,    false)
  144.     lsb          = default( lsb,     false)
  145.     Str          = default( Str,      1.0 )
  146.     Amp          = default( Amp,   0.0625 )
  147.     TV_range     = default( TV_range, true)
  148.  
  149.     # Select presets / tuning
  150.     Preset = default( Preset, "Slower" )
  151.     pNum = (Preset == "Placebo"   ) ? 0 : \
  152.            (Preset == "Very Slow" ) ? 1 : \
  153.            (Preset == "Slower"    ) ? 2 : \
  154.            (Preset == "Slow"      ) ? 3 : \
  155.            (Preset == "Medium"    ) ? 4 : \
  156.            (Preset == "Fast"      ) ? 5 : \
  157.            (Preset == "Faster"    ) ? 6 : \
  158.            (Preset == "Very Fast" ) ? 7 : \
  159.            (Preset == "Super Fast") ? 8 : \
  160.            (Preset == "Ultra Fast") ? 9 : \
  161.            (Preset == "Draft"     ) ? 10 : 11
  162.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  163.  
  164.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  165.              (MatchPreset == "Placebo"   ) ? 0 : \
  166.              (MatchPreset == "Very Slow" ) ? 1 : \
  167.              (MatchPreset == "Slower"    ) ? 2 : \
  168.              (MatchPreset == "Slow"      ) ? 3 : \
  169.              (MatchPreset == "Medium"    ) ? 4 : \
  170.              (MatchPreset == "Fast"      ) ? 5 : \
  171.              (MatchPreset == "Faster"    ) ? 6 : \
  172.              (MatchPreset == "Very Fast" ) ? 7 : \
  173.              (MatchPreset == "Super Fast") ? 8 : \
  174.              (MatchPreset == "Ultra Fast") ? 9 : \
  175.              (MatchPreset == "Draft"     ) ? 10 : 11
  176.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  177.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  178.  
  179.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  180.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  181.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  182.              (MatchPreset2 == "Slower"    ) ? 2 : \
  183.              (MatchPreset2 == "Slow"      ) ? 3 : \
  184.              (MatchPreset2 == "Medium"    ) ? 4 : \
  185.              (MatchPreset2 == "Fast"      ) ? 5 : \
  186.              (MatchPreset2 == "Faster"    ) ? 6 : \
  187.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  188.              (MatchPreset2 == "Super Fast") ? 8 : \
  189.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  190.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  191.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  192.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  193.  
  194.     NoisePreset = default( NoisePreset, "Fast" )
  195.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  196.             (NoisePreset == "Slow"   ) ? 1 : \
  197.             (NoisePreset == "Medium" ) ? 2 : \
  198.             (NoisePreset == "Fast"   ) ? 3 : \
  199.             (NoisePreset == "Faster" ) ? 4 : 5
  200.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  201.  
  202.     Tuning = default( Tuning, "None" )
  203.     tNum = (Tuning == "None"  ) ? 0 : \
  204.            (Tuning == "DV-SD" ) ? 1 : \
  205.            (Tuning == "DV-HD" ) ? 2 : 3
  206.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  207.  
  208.     # Tunings only affect blocksize in this version
  209.     bs = Select( tNum,  16, 16, 32 )
  210.     bs2 = (bs >= 16) ? 32 : bs * 2
  211.  
  212.     #                                                               Very                                                        Very      Super      Ultra
  213.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  214.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  215.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  216.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  217.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  218.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  219.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  220.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  221.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  222.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  223.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  224.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  225.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  226.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  227.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  228.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  229.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  230.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  231.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  232.     bs = Blocksize
  233.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  234.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  235.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  236.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  237.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  238.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  239.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  240.  
  241.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  242.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  243.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  244.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  245.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  246.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  247.  
  248.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  249.     SourceMatch   = default( SourceMatch, 0 )
  250.     MatchNNSize   = NNSize
  251.     MatchNNeurons = NNeurons
  252.     MatchEdiMaxD  = EdiMaxD
  253.     MatchEdiQual  = EdiQual
  254.  
  255.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  256.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  257.     #                                                                    Very                                                        Very      Super     Ultra
  258.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  259.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  260.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  261.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  262.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  263.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  264.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  265.     MatchEdi = TempEdi
  266.  
  267.     #                                                          Very                                                        Very      Super     Ultra
  268.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  269.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  270.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  271.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  272.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  273.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  274.  
  275.  
  276.     #---------------------------------------
  277.     # Settings
  278.  
  279.     # Core and Interpolation defaults
  280.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  281.     RepChroma  = default( RepChroma,  true )
  282.     EdiThreads = default( EdiThreads, 0    )
  283.     ChromaEdi  = default( ChromaEdi,  ""   )
  284.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  285.     EdiQual    = (EdiMode == "EEDI3+NNEDI3" || EdiMode == "NNEDI3") && EdiQual > 2 ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  286.  
  287.     # Source-match / lossless defaults
  288.     MatchTR1     = TR1
  289.     MatchTR2     = default( MatchTR2,     1   )
  290.     MatchEnhance = default( MatchEnhance, 0.5 )
  291.     Lossless     = default( Lossless,     0   )
  292.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  293.  
  294.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  295.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  296.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  297.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  298.     spatialSL  = (SLMode == 1 || SLMode == 3)
  299.     temporalSL = (SLMode == 2 || SLMode == 4)
  300.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  301.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  302.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  303.     Sbb        = (SMode == 0) ? 0 : Sbb
  304.     SOvs       = default( SOvs,   0   )
  305.     SVThin     = default( SVThin, 0.0 )
  306.  
  307.     # Noise processing settings
  308.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  309.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  310.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  311.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  312.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  313.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  314.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  315.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  316.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  317.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  318.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  319.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  320.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  321.     Sigma        = defined(Sigma)       ? Sigma : \
  322.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  323.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  324.     FftThreads   = default( FftThreads, EdiThreads )
  325.     ChromaNoise  = default( ChromaNoise, false )
  326.     ShowNoise    = default( ShowNoise, 0.0 )
  327.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  328.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  329.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  330.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  331.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  332.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  333.     totalRestore = GrainRestore + NoiseRestore
  334.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  335.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  336.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  337.  
  338.     # MVTools settings
  339.     SubPelInterp = default( SubPelInterp, 2     )
  340.     TrueMotion   = default( TrueMotion,   false )
  341.     GlobalMotion = default( GlobalMotion, true  )
  342.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  343.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  344.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  345.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  346.     DCT          = default( DCT,     0          )
  347.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  348.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  349.     ThSCD1       = default( ThSCD1,  180        )
  350.     ThSCD2       = default( ThSCD2,  98         )
  351.  
  352.     # Motion blur settings
  353.     FPSDivisor  = default( FPSDivisor, 1 )
  354.     ShutterBlur = default( ShutterBlur, 0 )
  355.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  356.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  357.     SBlurLimit  = default( SBlurLimit, 4 )
  358.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  359.  
  360.     # Miscellaneous
  361.     InputType      = default( InputType,     0        )
  362.     Border         = default( Border,        false    )
  363.     ShowSettings   = default( ShowSettings,  false    )
  364.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  365.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  366.     ForceTR        = default( ForceTR,       0        )
  367.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  368.     ReuseGlobals   = (PrevGlobals == "Reuse")
  369.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  370.     rgBlur         = (Precise) ? 11 : 12
  371.  
  372.     # Get maximum temporal radius needed
  373.     maxTR = (temporalSL)       ? SLRad : 0
  374.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  375.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  376.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  377.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  378.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  379.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  380.  
  381.  
  382.     #---------------------------------------
  383.     # Pre-Processing
  384.  
  385.     w = Input.Width()
  386.     h = Input.Height()
  387.     yuy2 = Input.IsYUY2()
  388.     epsilon = 0.0001
  389.  
  390.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  391.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  392.  
  393.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  394.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  395.     h = (Border) ? h+8 : h
  396.  
  397.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  398.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  399.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  400.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  401.     vpad = (vpad > 8) ? vpad : 8
  402.  
  403.  
  404.     #---------------------------------------
  405.     # Motion Analysis
  406.  
  407.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  408.     planarClip = yuy2 ? clip.converttoyv16() : clip
  409.  
  410.     # Bob the input as a starting point for motion search clip
  411.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  412.              (InputType == 1) ? planarClip : \
  413.                                 planarClip.Blur( 0,1 )
  414.  
  415.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  416.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  417.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  418.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  419.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  420.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  421.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  422.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  423.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  424.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  425.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  426.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  427.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  428.  
  429.     CMmt = ChromaMotion ? 3   :  1
  430.     CMts = ChromaMotion ? 255 :  0
  431.     CMrg = ChromaMotion ? 12  : -1
  432.  
  433.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  434.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  435.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  436.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  437.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  438.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  439.  
  440.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  441.     binomial0 = IsClip(srchClip) ? NOP() : \
  442.                 (TR0 == 0)       ? bobbed : \
  443.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  444.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  445.  
  446.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  447.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  448.  
  449.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  450.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  451.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  452.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  453.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  454.  
  455.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  456.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : NOP()
  457.     srchcheck   = IsClip(srchClip)
  458.     srchClip    = srchcheck         ? srchClip : \
  459.                   (SrchClipPP == 0) ? repair0 : \
  460.                   (SrchClipPP < 3)  ? spatialBlur : \
  461.                                       spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  462.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  463.     # Calculate forward and backward motion vectors from motion search clip
  464.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  465.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  466.     bVec5 = IsClip(bVec5) ? bVec5 : \
  467.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  468.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  469.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  470.     bVec4 = IsClip(bVec4) ? bVec4 : \
  471.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  472.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  473.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  474.     bVec3 = IsClip(bVec3) ? bVec3 : \
  475.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  476.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  477.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  478.     bVec2 = IsClip(bVec2) ? bVec2 : \
  479.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  480.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  481.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  482.     bVec1 = IsClip(bVec1) ? bVec1 : \
  483.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  484.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  485.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  486.     fVec1 = IsClip(fVec1) ? fVec1 : \
  487.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  488.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  489.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  490.     fVec2 = IsClip(fVec2) ? fVec2 : \
  491.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  492.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  493.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  494.     fVec3 = IsClip(fVec3) ? fVec3 : \
  495.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  496.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  497.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  498.     fVec4 = IsClip(fVec4) ? fVec4 : \
  499.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  500.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  501.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  502.     fVec5 = IsClip(fVec5) ? fVec5 : \
  503.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  504.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  505.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  506.  
  507.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  508.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  509.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  510.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  511.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  512.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  513.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  514.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  515.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  516.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  517.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  518.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  519.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  520.  
  521.  
  522.     #---------------------------------------
  523.     # Noise Processing
  524.  
  525.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  526.  
  527.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  528.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  529.                 (InputType > 0)     ? clip : \
  530.                                       clip.QTGMC_Bob( 0,1.0 )
  531.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.converttoyv16() : fullClip
  532.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  533.  
  534.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  535.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  536.                   (!DenoiseMC)        ? fullClip : \
  537.                   (NoiseTR == 0)      ? fullClip : \
  538.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  539.                                                     fullClip, \
  540.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  541.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  542.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  543.                                                     fullClip, \
  544.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  545.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  546.     noiseWindow = yuy2 && (Denoiser == "fft3df") && NoiseTR > 0 ? noiseWindow.ConvertToYUY2() : noiseWindow
  547.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  548.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=FftThreads, lsb=lsbd ) : \
  549.             (Denoiser == "KNLMeansCL")  ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU" ) : \
  550.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD, ncpu=FftThreads )
  551.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  552.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.ConvertToYUY2() : dnWindow
  553.  
  554.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  555.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  556.     denoised = (NoiseProcess == 0) ? NOP() : \
  557.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  558.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  559.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  560.  
  561.     # >>>> Switch to planar YUY2 for noise bypass
  562.  
  563.     CNmt1   = ChromaNoise ? 3 : 1
  564.     CNmt2   = ChromaNoise ? 3 : 2
  565.     CNmt128 = ChromaNoise ? 3 : -128
  566.  
  567.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  568.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.converttoyv16() : denoised
  569.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  570.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  571.                  (InputType != 0)                           ? noise : \
  572.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  573.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  574.                                                               noise.DoubleWeave()
  575.     # Motion-compensated stabilization of generated noise
  576.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  577.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  578.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  579.  
  580.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  581.     innerClip = (NoiseProcess == 1) ? denoised : clip
  582.  
  583.  
  584.     #---------------------------------------
  585.     # Interpolation
  586.  
  587.     # >>>> Interleaved YUY2 for interpolation
  588.  
  589.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  590.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  591.  
  592.     # Create interpolated image as starting point for output
  593.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  594.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  595.  
  596.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  597.  
  598.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  599.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  600.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.ConvertToYV16()) :\
  601.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).ConvertToYV16()) : \
  602.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  603.                                                         mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend, U=2,V=2 ))
  604.  
  605.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  606.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  607.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  608.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  609.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  610.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  611.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  612.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  613.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  614.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  615.  
  616.  
  617.     #---------------------------------------
  618.     # Create basic output
  619.  
  620.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  621.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  622.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  623.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  624.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  625.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  626.     degrain1 = (TR1 > 0) && lsb ? degrain1.ditherpost(mode=6, slice=false) : degrain1
  627.     degrain2 = (TR1 > 1) && lsb ? degrain2.ditherpost(mode=6, slice=false) : degrain2
  628.  
  629.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  630.     binomial1 = (TR1 == 0) ? edi : \
  631.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  632.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  633.  
  634.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  635.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  636.  
  637.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  638.     match = (SourceMatch == 0) ? repair1 : \
  639.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  640.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  641.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  642.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  643.  
  644.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  645.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  646.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  647.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  648.  
  649.  
  650.     #---------------------------------------
  651.     # Resharpen / retouch output
  652.  
  653.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  654.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  655.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  656.     resharp   = (SMode == 0) ? lossed1 : \
  657.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  658.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  659.  
  660.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  661.     SVThinSc = SVThin * 6.0
  662.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  663.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  664.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  665.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  666.  
  667.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  668.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  669.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  670.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  671.  
  672.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  673.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  674.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  675.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  676.                                   backBlend1
  677.  
  678.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  679.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  680.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  681.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  682.  
  683.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  684.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  685.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  686.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  687.  
  688.     # Final light linear temporal smooth for denoising
  689.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  690.     stable  = (TR2 == 0) ? addNoise1 : \
  691.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  692.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  693.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  694.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  695.                            addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb )
  696.     stable  = (TR2 > 0) && lsb ? stable.ditherpost(mode=6, slice=false) : stable
  697.  
  698.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  699.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  700.  
  701.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  702.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  703.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  704.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  705.                                   repair2
  706.  
  707.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  708.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  709.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  710.  
  711.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  712.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  713.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  714.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  715.  
  716.  
  717.     #---------------------------------------
  718.     # Post-Processing
  719.  
  720.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  721.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  722.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  723.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  724.  
  725.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  726.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  727.     rBlockSize = BlockSize / rBlockDivide
  728.     rOverlap   = Overlap   / rBlockDivide
  729.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  730.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  731.     rBlockDivide = BlockSize / rBlockSize
  732.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  733.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  734.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  735.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  736.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  737.  
  738.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  739.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  740.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  741.  
  742.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  743.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  744.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  745.                    (SBlurLimit == 0)  ? sblur : \
  746.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  747.     # Reduce frame rate
  748.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  749.  
  750.     # Crop off temporary vertical padding
  751.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  752.     h = Border ? h-8 : h
  753.  
  754.     # Show output of choice + settings
  755.     # >>>> Restore YUY2 to interleaved
  756.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  757.     output = yuy2 ? output.ConvertToYUY2() : output
  758.     return (ShowSettings == false) ? output : \
  759.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  760.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  761.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  762.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  763.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  764.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  765.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  766.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  767.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  768.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  769.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  770.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  771.         Denoiser + "' | FftThreads=" + string(FftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  772.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  773.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  774.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  775.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  776.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  777.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  778.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  779. }
  780.  
  781.  
  782. #---------------------------------------
  783. # Helpers
  784.  
  785. # Same as Bob, but keeps the field order the same.
  786. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  787. {
  788.   ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  789.   h = Default(height, cp.Height)
  790.   w = cp.Width
  791.   shift = GetParity(cp) ? 0.25 : -0.25
  792.  
  793.   c420 = ssispmt ? Is420(cp) : IsYV12(cp)
  794.  
  795.   c420 ? cp.SeparateFields() : nop()
  796.  
  797.   oeven=c420 ? SelectEven() : nop()
  798.   oodd=c420 ? SelectOdd() : nop()
  799.  
  800.   even=c420 ? ssispmt ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  801.   odd=c420 ? ssispmt ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  802.  
  803.   evenChr=c420 ? Interleave(ssispmt ? oeven.ExtractU() : oeven.UToY8(), ssispmt ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  804.   oddChr=c420 ? Interleave(ssispmt ? oodd.ExtractU() : oodd.UToY8(), ssispmt ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  805.  
  806.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  807.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  808. }
  809.  
  810.  
  811. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  812. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  813. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  814.                             string "ChromaEdi" )
  815. {
  816.     # >>>> YUY2 is interleaved here
  817.  
  818.     ChromaEdi = default( ChromaEdi, "" )
  819.     CEed = (ChromaEdi == "")
  820.  
  821.     interp = (InputType == 1)            ? Input : \
  822.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  823.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  824.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  825.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  826.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  827.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  828.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  829.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  830.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  831.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  832.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.ConvertToYv16().Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  833.                                                            Input.Yadifmod2( mode=3 ) : \   
  834.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).ConvertToYv16(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  835.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  836.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  837.  
  838.     interpuv = (InputType == 1)        ? NOP() : \
  839.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  840.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  841.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  842.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  843.                                          NOP()
  844.  
  845.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  846. }
  847.  
  848.  
  849. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  850. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  851. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  852. {
  853.     # >>>> YUY2 is planar here
  854.     mtY =default( Y, 3 )
  855.     mtU =default( U, 1 )
  856.     mtV =default( V, 1 )
  857.     rgY = (mtY == 3) ? 20 : -1
  858.     rgU = (mtU == 3) ? 20 : -1
  859.     rgV = (mtV == 3) ? 20 : -1
  860.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  861. }
  862.  
  863. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  864. {
  865.     # >>>> YUY2 is planar here
  866.     mtY =default( Y, 3 )
  867.     mtU =default( U, 1 )
  868.     mtV =default( V, 1 )
  869.     rgY = (mtY == 3) ? 20 : -1
  870.     rgU = (mtU == 3) ? 20 : -1
  871.     rgV = (mtV == 3) ? 20 : -1
  872.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  873. }
  874.  
  875. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  876. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  877. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  878. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  879. {
  880.     # >>>> YUY2 is planar here
  881.  
  882.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  883.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  884.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  885.     Rep    = default( Rep,    1    )
  886.     Chroma = default( Chroma, true )
  887.     ed = (Rep < 10) ? Rep : Rep / 10
  888.     od = (Rep < 10) ? 0   : Rep % 10
  889.     RCrg  = Chroma ? 3 : 1
  890.     RCrgo = Chroma ? 3 : 2
  891.  
  892.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  893.  
  894.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  895.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  896.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  897.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  898.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  899.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  900.                                                                                                                      
  901.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  902.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  903.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  904.  
  905.     # Over-dilation - extra reflation up to about 1 pixel
  906.     choke1 = (od == 0)            ? choke1 : \
  907.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  908.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  909.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  910.  
  911.     # Areas of negative difference (similar to above)
  912.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  913.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  914.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  915.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  916.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  917.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  918.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  919.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  920.     choke2 = (od == 0)            ? choke2 : \
  921.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  922.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  923.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  924.  
  925.     # Combine above areas to find those areas of difference to restore
  926.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  927.  
  928.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  929. }
  930.  
  931.  
  932. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  933. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  934. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  935. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  936. {
  937.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  938.     ChromaNoise = default( ChromaNoise, false )
  939.     CNmt1 = ChromaNoise ? 3 : 1
  940.     origNoise = Input.SeparateFields()
  941.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  942.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  943.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  944.     random    = InterleavedClip.IsYUY2() ? random.converttoyv16() : random
  945.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  946.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  947.     return Interleave( origNoise, newNoise ).Weave()
  948. }
  949.  
  950.  
  951. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  952. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  953. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  954. {
  955.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  956.  
  957.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  958.  
  959.     # Weave the source fields and the "new" fields that have generated in the input
  960.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  961.     srcFields  = Source.IsYUY2() ? srcFields1.converttoyv16() : srcFields1
  962.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  963.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  964.  
  965.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  966.     vertMedian  = processed.VerticalCleaner( mode=1 )
  967.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  968.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  969.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  970.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  971.  
  972.     # Reweave final result
  973.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  974. }
  975.  
  976.  
  977. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  978. # the source without introducing shimmer. All other arguments defined in main script
  979. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  980.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  981.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  982.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  983.                                  float MatchEnhance, int EdiThreads, bool lsb )
  984. {
  985.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  986.     yuy2 = Source.IsYUY2()
  987.     Source = yuy2 ? Source.converttoyv16() : Source
  988.  
  989.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  990.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  991.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  992.     # this new source. Result will still be shimmer-free and closer to the original source.
  993.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  994.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  995.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  996.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  997.     errorTemporalSimilarity = 0.5  # S in formula described above
  998.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  999.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1000.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  1001.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  1002.     yv16match1Edi  = EdiMode=="NNEDI2" || EdiMode=="NNEDI" || EdiMode=="EEDI3+NNEDI3" || EdiMode=="EEDI3" || EdiMode=="EEDI2" || EdiMode=="TDeint" || EdiMode=="cYadif" || EdiMode=="RepcYadif" || ChromaEdi=="cYadif"
  1003.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  1004.    !yv16match1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1005.                              match1Update.ConvertToYUY2() \
  1006.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1007.                                          .ConvertToYv16()
  1008.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1009.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1010.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1011.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1012.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1013.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1014.                      (MatchTR1 == 0)   ? match1Edi : \
  1015.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1016.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1017.  
  1018.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1019.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : match1
  1020.  
  1021.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1022.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1023.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1024.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1025.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1026.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1027.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1028.     yv16match1Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1029.                              match2Diff.ConvertToYUY2() \
  1030.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1031.                                        .ConvertToYv16()
  1032.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1033.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1034.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1035.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1036.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1037.     match2         = (SourceMatch < 2) ? match1 : \
  1038.                      (MatchTR2 == 0)   ? match2Edi : \
  1039.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1040.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1041.  
  1042.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1043.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1044.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1045.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 )
  1046.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1047.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1048.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1049.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1050.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1051.     match3         = (SourceMatch < 3) ? match2 : \
  1052.                      (MatchTR2 == 0)   ? match3Update : \
  1053.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1054.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1055.  
  1056.     # Apply difference calculated in source-match refinement
  1057.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1058. }
  1059.  
  1060.  
  1061. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1062. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1063. {
  1064.     Replace = default( Replace, false )
  1065.     globalName = Prefix + "_" + Name
  1066.  
  1067.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1068.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1069.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1070.     catch (e)
  1071.     {
  1072.         Eval( "global " + globalName + " = Value" )
  1073.         Replace = true
  1074.     }
  1075.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1076. }
  1077.  
  1078. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1079. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1080. {
  1081.     Reuse = default( Reuse, false )
  1082.     globalName = Prefix + "_" + Name
  1083.  
  1084.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1085.     catch (e) { ret = NOP() }
  1086.     return ret
  1087. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!