pkgbase=psi-plus
pkgname=('psi-plus'
         'psi-plus-plugins')
pkgver=0.15.5317
pkgrel=1
url="http://psi-plus.com"
license=('GPL2')
arch=('i686' 'x86_64')
makedepends=('qconf')
# https://github.com/tehnick/psi-plus/tags
source=("https://nodeload.github.com/tehnick/psi-plus/tarball/$pkgver")
md5sums=('a58295b03f25e443e8bb94a83de21d59')

build() {
  cd $srcdir/tehnick*
  psisrcdir=`pwd`

  qconf
  ./configure --prefix=/usr \
              --disable-bundled-qca \
              --disable-growl \
              --enable-webkit \
              --enable-plugins \
              --enable-whiteboarding
  make

  for plugin in $psisrcdir/src/plugins/generic/*plugin
  do
    cd $plugin
    qmake
    make
  done
}

package_psi-plus() {
  pkgdesc='Psi+ is a powerful Jabber client (Qt, C++) designed for the Jabber power users'
  depends=('qt' 'qca-ossl' 'qca-gnupg' 'aspell' 'libxss' 'openssl' 'dbus' 'zlib')
  conflicts=('psi' 'psi-plus-git')
  provides=('psi' 'psi-plus-git')

  cd $srcdir/tehnick*
  make INSTALL_ROOT="$pkgdir" install
}

package_psi-plus-plugins() {
  pkgdesc='Plugins for Psi+'
  depends=('psi-plus' 'tidyhtml')

  cd $srcdir/tehnick*
  psisrcdir=`pwd`

  mkdir -p $pkgdir/usr/lib/psi-plus/plugins

  for plugin in $psisrcdir/src/plugins/generic/*plugin
  do
    cp -f $plugin/lib*plugin.so $pkgdir/usr/lib/psi-plus/plugins/
  done
}