sndRocket.ks 7/28

function LogData {
  parameter text.

  // print to both the console and log
  print "[" + time:clock + "] " + text.
  log "[" + time:clock + "] " + text to missionlog.
  copy missionlog to 0.
}.

function Launch {
  clearscreen.
  LogData("Sounding Rocket Flight Program initiating...").

  // find all our parts
  set sre1 to ship:partstagged("sre1")[0].
  set sre2 to ship:partstagged("sre2")[0].
  set chute to ship:partstagged("chute")[0].
  set clamp to ship:partstagged("clamp")[0].
  set fairings to ship:partstagged("fairing").

  // perform pre-launch checks
  if fairings:length < 2 {
    LogData("Fairing parts missing, only found " + fairings:length).
    return false.
  }.

  // by chance, both engines should be set to the same thrust
  list engines in englist.
  for eng in englist {
    if eng:thrustlimit <> 57.5 {
      LogData("Improper thrust limiter set. Thrust set to " + eng:thrustlimit + "%").
      return false.
    }
  }

  // all good, begin the countdown
  LogData("GO for launch!").
  wait 1.
  LogData("T-10").
  wait 1.
  LogData("T-9").
  wait 1.
  LogData("T-8").
  wait 1.
  LogData("T-7").
  wait 1.
  LogData("T-6").
  wait 1.
  LogData("T-5").
  wait 1.
  LogData("T-4").
  wait 1.
  LogData("T-3").
  wait 1.
  LogData("T-2").
  wait 1.
  LogData("T-1").
  wait 1.

  // fire the engine and detach from the launch stick
  sre1:getmodule("ModuleEngines"):doevent("activate engine").
  clamp:getmodule("ModuleAnchoredDecoupler"):doevent("decouple").
  LogData("Liftoff!!").

  // wait until engine expires then stage
  until sre1:getmodule("ModuleEngines"):getfield("status") = "flame-out!" {}.
  wait 0.5.
  sre2:getmodule("ModuleEngines"):doevent("activate engine").
  LogData("Stage 1 flame out detected. Activating Stage 2").

  // wait until engine expires then stage
  until sre2:getmodule("ModuleEngines"):getfield("status") = "flame-out!" {}.
  LogData("Stage 2 flame out detected. Releasing payload fairings").
  for fairing in fairings {
    fairing:getmodule("ModuleDecouple"):doevent("decouple").
  }
  LogData("Awaiting subsonic velocity for chute deployment").
  until ship:airspeed <= 260 {}.

  // pop the chute
  LogData("Deploying chute").
  chute:getmodule("ModuleParachute"):doevent("deploy chute").

  // confirm chute is open and run science experiments
  until chute:getmodule("ModuleParachute"):hasevent("cut parachute") {}.
  LogData("Chute deployed, running experiments").
  toggle AG1.

  return true.
}

// done! All data will be stored for retrieval, as battery power will not last until landing
if Launch() {
  LogData("All events have executed. Awaiting landing & retrieval").
}.