@echo off
cls

rem Создаем файл с логом установки
set logfile=install.log
echo %date% %COMPUTERNAME%>%logfile%
echo [%time:~,8%] Установка начата>>%logfile%

rem Узнаём имя целевого компьютера, проверяем не пустое ли оно
set /p CompName="Введите имя компьютера или IP-адрес: "
rem Проверяем не пдключен ли уже диск O:
net use O: /delete /y 2> nul
rem Создаем диск O: с подключенным диском C:\, папку Install
net use O: \\%CompName%\C$ /USER:%CompName%\Администратор

echo ********       Копирую файлы                        ******
mkdir O:\install_VNC && echo [%time:~,8%] Создана папка для установки UltraVNC>>%logfile%
copy "%CD%\distr\uvnc.exe" "O:\install_VNC" /y
copy "%CD%\distr\uvnc.inf" "O:\install_VNC" /y
rem Установка UVNC
psexec \\%CompName% net stop uvnc_service 2> nul
psexec \\%CompName% "taskkill.exe" /f /im winvnc* 2> nul
psexec \\%CompName% del "C:\UltraVNC\*.*" 2> nul

echo ********       Запускаю установку сервера                  ******
psexec \\%CompName% "C:\install_VNC\uvnc.exe" /sp- /loadinf="C:\install_VNC\uvnc.inf" /verysilent 2> nul
if %errorlevel% EQU 0 (echo [%time:~,8%] Сервер UltraVNC установлен на %CompName%>>%logfile%) else (echo [%time:~,8%] Не удалось установить сервер UltraVNC на %CompName%>>%logfile%)
rem Убиваем UVNC

echo ********       Закрываю существующий процесс winvnc.exe    ******
ping 127.0.0.1 -n 2 >NUL
psexec \\%CompName% "taskkill.exe" /f /im winvnc* 2>nul
rem Копирую настройки

echo ********        Копирую настройки                    ******
ping 127.0.0.1 -n 2 >NUL
copy "%CD%\distr\ultravnc.ini" "O:\UltraVNC\" /y
if %errorlevel% EQU 0 (echo [%time:~,8%] Файл настроек сервера скопирован в папку>>%logfile%) else (echo [%time:~,8%] Не удалось скопировать файл настроек сервера>>%logfile%)
rem Перезапуск службы UVNC
echo [%time:~,8%] Останавливаем службу UVNC_Service>>%logfile%

echo ********       Останавливаю службу UVNC             ******
ping 127.0.0.1 -n 2 >NUL
psexec \\%CompName% net stop uvnc_service 2> nul

echo ********       Запускаю службу UVNC                 ******
ping 127.0.0.1 -n 2 >NUL
psexec \\%CompName% net start uvnc_service 2> nul
if %errorlevel% EQU 0 (echo [%time:~,8%] Служба UVNC_Service остановлена>>%logfile%) else (echo [%time:~,8%] Не удалось остановить службу UVNC_Service>>%logfile%)
rem Удалляем установочные файлы

echo ********       Удаляю установочные файлы           ******
ping 127.0.0.1 -n 2 >NUL
del /q O:\install_VNC\*
rd O:\install_VNC
rem Удаляем диск O
net use O: /delete /y
echo Готово!
echo Пароль для подключения: 123
pause