Ford_Lawnmower / Nonciclopedia search

;Nonciclopedia Search Script by Ford_Lawnmower -- irc.GeekShed.net #Script-Help
menu Channel,Status {
  .$iif($group(#nonciclopedia) == On,$style(1)) Nonciclopedia Nonciclopedia Trigger
  ..$iif($group(#nonciclopedia) == On,$style(2)) On: .enable #nonciclopedia
  ..$iif($group(#nonciclopedia) == Off,$style(2)) Off: .disable #nonciclopedia
}
#nonciclopedia on
On $*:Text:/^(!|@)nonciclopedia.*/Si:#: {
  if ($timer($+(nonciclopedia,$network,$nick))) { return }
  .timer $+ $+(nonciclopedia,$network,$nick) 1 4 noop
  var %method $iif($regml(1) == !,.notice $nick,$iif($regex($nick($chan,$nick).pnick,/(!|~|&|@|%)/),.msg $chan,.notice $nick))
  nonciclopediaS %method $2-
}
#nonciclopedia end
alias nonciclopedia { nonciclopediaS echo -a $1- }
alias -l nonciclopediaS {
  $1-2 Searching.......
  var %sockname $+(nonciclopediaS,$network,$2,$ticks)
  sockopen %sockname nonciclopedia.wikia.com 80
  sockmark %sockname $1-2 $iif($3,$+(/wiki/Speciale:Ricerca/,$replace($3-,$chr(32),_)),/wiki/Speciale:PaginaCasuale) 0 $iif(!$3,1,0)
}
alias -l nonciclopediaR {
  var %sockname $+(nonciclopediaR,$network,$2,$ticks)
  sockopen %sockname nonciclopedia.wikia.com 80
  sockmark %sockname $1-2 $+(/wiki/,$3) 0 $iif($4,1,0)
}
On *:sockopen:nonciclopedia*: {
  if (!$sockerr) {
    sockwrite -nt $sockname GET $gettok($sock($sockname).mark,3,32) HTTP/1.0
    sockwrite -n $sockname Host: nonciclopedia.wikia.com
    sockwrite -n $sockname $crlf
  }
  else { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
}
On *:sockread:nonciclopediaS*: {
  if ($sockerr) { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
  else {
    var %nonciclopediaS | sockread %nonciclopediaS
    if (Page title matches isincs %nonciclopediaS) { sockmark $sockname $puttok($sock($sockname).mark,1,4,32) }
    if (Page text matches isincs %nonciclopediaS) { sockmark $sockname $puttok($sock($sockname).mark,1,4,32) }
    ;if ($gettok($sock($sockname).mark,4,32)) && ($regex(%nonciclopediaS,/\Q<li><a href="/wiki/\E(.*)\Q" title="\E/)) {
    if ($regex(%nonciclopediaS,/<li><a href="(?:http://nonciclopedia.wikia.com)?/wiki/([^"]*)"/i)) {
      nonciclopediaR $gettok($sock($sockname).mark,1-2,32) $regml(1)
      sockclose $sockname
      return
    }
    if (Location: isin %nonciclopediaS) {
      nonciclopediaR $gettok($sock($sockname).mark,1-2,32) $nopath(%nonciclopediaS) $gettok($sock($sockname).mark,5,32)
      sockclose $sockname
      return
    }
  }
}
On *:sockread:nonciclopediaR*: {
  if ($sockerr) { echo -st socket error $nopath($script) }
  else {
    var %nonciclopediaR | sockread %nonciclopediaR
    if (*<p>*<b>* iswm %nonciclopediaR) {
      sockmark $sockname $puttok($sock($sockname).mark,$calc($gettok($sock($sockname).mark,4,32) + 1),4,32)
    }
    if ($gettok($sock($sockname).mark,4,32)) && ($httpstrip(%nonciclopediaR)) {
      put $gettok($sock($sockname).mark,1-2,32) $fix&#($v1) $+(,http://nonciclopedia.com,$gettok($sock($sockname).mark,3,32))
      sockclose $sockname
      return
    }
  }
}
On *:sockclose:nonciclopedia*: {
  if ($gettok($sock($sockname).mark,5,32)) && (nonciclopediaR* iswm $sockname) { nonciclopediaS $gettok($sock($sockname).mark,1-2,32) }
  else { $gettok($sock($sockname).mark,1-2,32) Sorry No results found for your Search }
}
alias -l httpstrip { var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x) | return $remove($replace(%x,&amp;,&),&nbsp;,&mdash;) }
alias -l Put {
  if (!$regex($1,/(\.|^)(msg|notice|echo)$/Si)) || (!$3) { echo -st **Put error** Syntax /Put msg #channel text - or - /Put notice nickname text  | return }
  var %tokens $0, %Tstart 3, %Dtimer 1500
  if ($timer($+(Put,$2,$network)).secs) { %Dtimer = $calc($v1 * 1000) }
  while ($len($($+($,%Tstart,-,%tokens),2)) > 430) {
    dec %tokens
    if ($len($($+($,%Tstart,-,%tokens),2)) <= 430) {
      .timer -m 1 %Dtimer $1-2 $($+($,%Tstart,-,%tokens),2))
      inc %Dtimer 1500
      %Tstart = $calc(%tokens + 1)
      %tokens = $0
    }
  }
  .timer -m 1 %Dtimer $1-2 $($+($,%Tstart,-,%tokens),2))
  .timer $+ $+(Put,$2,$network) -m 1 $calc(%Dtimer + 1500) noop
}
alias -l fix&# { return $replace($regsubex($1-,/\&\#([0-9]{1,});/g,$UTF8(\t)),&quot;,",&amp;,&,&gt;,>,&lt;,<,&#39;,',|,,$chr(9),$chr(32)) }