//wyjaśnienie procedur (można
//skok :x :y - przesuwa żółwia o wektor [:x,:y], np. skok 50 30 przesunie go o 50 w prawo i 30 do góry
//kwadrat :a - kwadrat o boku :a
//kwadrat_środek :a - wyśrodkowany kwadrat o boku :a
//prostokąt :a :b - kwadrat o boku pionowym :a i poziomym :b
//prostokąt_środek :a :b - analogicznie jak poprzednio
//foremny :n :a - n-kąt foremny (n >= 3) o boku :a
//foremny_środek :n :a - n-kąt foremny wyśrodkowany
//gwiazda :n :r - wyśrodkowana gwiazda n-kątna (n nieparzyste) w "kole" o promieniu :r
//koło :r - bez wyjaśnienia; żółw znajduje się na obwodzie
//koło_środek :r - żółw na początku i końcu - na środku koła


oto skok :x :y
  pod
  pw 90   np :x   lw 90
  np :y
  opu
już

oto kwadrat :a
  powtórz 4 [ np :a pw 90 ]
już

oto kwadrat_środek :a
  skok (-:a/2) (-:a/2)
  powtórz 4 [ np :a pw 90 ]
  skok :a/2 :a/2
już

oto prostokąt :a :b
  powtórz 2 [ np :a pw 90  np :b pw 90 ]
już

oto prostokąt_środek :a :b
  skok (-:b/2) (-:a/2)
  powtórz 2 [ np :a pw 90  np :b pw 90 ]
  skok :b/2 :a/2
już

oto foremny :n :a
  powtórz :n [ np :a pw 180-180*(:n-2)/:n ]
już

oto foremny_środek :n :a
  przyp "r :a/(2*sin (180/:n))
  skok (-:r * cos(180/:n)) (-:r * sin (180/:n))
  powtórz :n [ np :a pw 180-180*(:n-2)/:n ]
  skok :r*cos (180/:n) :r*sin (180/:n)
już

oto gwiazda :n :r
  skok (-:r * cos (180/:n)) (-:r * sin (180/:n))
  pw (180/:n)
  powtórz :n [ np 2*:r*sin (360/:n)  pw 180-180/:n ]
  lw (180/:n)
  skok :r*cos (180/:n) :r*sin (180/:n)
już

oto koło :r
  powtórz 360 [ np 2*3,14*:r/360  pw 1 ]
już

oto koło_środek :r
  skok (-:r) 0
  powtórz 360 [ np 2*3,14*:r/360  pw 1 ]
  skok :r 0
już