; opcje:
          ;1 welna na przedze
          ;2 przedza na nici
          ;3 przedza na tkanine
          ;4 nici na dratwe
          ;5 nici na tkanine
set %opcja 0
; skille:
         ;0 nic
         ;1 ukrywanie
         ;2 anatomia
         ;3 madrosc
set %skill 0
;----------------------------------------------------
set #sysmsgcol 4000
event sysmessage [RJ]
wait 1s
if %opcja < 1 || %opcja > 5  || %skill < 0 || %skill > 3
{
   event sysmessage [RJ]: Nieprawidlowa konfiguracja
   halt
}
;----------------------------------------------------
set %kolowrotek LFG_GFG_XEG_IFG_MKG_JFG ;moze brakowac jakiegos typu
set %narzedziatkackie VCG_FDG_IDG       ;moze brakowac jakiegos typu
set %welna OFF
set %przedza PLF
set %nici UAG
set %npc HS_IS_AV_XU
;-----------------------------------------------------
set %scnt 0
goto opcja , %opcja
opcja0:
event sysmessage Brak opcji
halt
opcja1:
       set %item %welna
       set %narzedzie %kolowrotek
       goto koniecopcja
opcja2:
       set %item %przedza
       set %narzedzie %kolowrotek
       goto koniecopcja
opcja3:
       set %item %przedza
       set %narzedzie %narzedziatkackie
       goto koniecopcja
opcja4:
       set %item %nici
       set %narzedzie %nici
       goto koniecopcja
opcja5:
       set %item %nici
       set %narzedzie %narzedziatkackie
koniecopcja:
if %skill = 1
{
   set %delay 8
}
else
{
   if %skill > 1
   {
       set %delay 4
       set #targcurs 1
       event sysmessage Wskaz cel do skilla
       repeat
       until #targcurs = 0
       set %cel #ltargetid
   }
}
goto skill , %skill
skill0:
       goto koniecskill
skill1:
       set %skilln ukrywanie
       goto koniecskill
skill2:
       set %skilln anatomia
       goto koniecskill
skill3:
       set %skilln madrosc
koniecskill:

repeat
      finditem %item C
      if #findkind = -1
      {
           event sysmessage [RJ]: Brak przedmiotu
           wait 1s
           break
      }
      for #findindex 1 #findcnt
      {
          if #findcol = 0
             break
      }
      set #lobjectid #findid
      if %opcja <> 4
         finditem %narzedzie G_1
      else
         finditem %narzedzie C
      if #findkind = -1
      {
          event sysmessage [RJ]: Brak kolowrotka lub narzedzia tkackiego
          wait 1s
          break
      }
      for #findindex 1 #findcnt
      {
          if #findcol = 0
             break
      }
      set #ltargetkind 1
      set #ltargetid #findid
      set %ji #jindex
      event macro 17 0
      target 5s
      event macro 22 0
      repeat
            if %ji < #jindex
            {
               set %ji %ji + 1
               scanjournal %ji
            }
            if Masz_za_malo in #journal
               halt
      until Stworzyl in #journal || Zwinal in #journal || Oddalil in #journal

      if %scnt < #scnt && %skill > 0
      {
         event macro 1 0 .um %skilln
         set %scnt #scnt + %delay
         if %skill > 1
         {
           target 10s
           set #ltargetid %cel
           event macro 22 0
         }
      }
until #false

event sysmessage [RJ]: Koniec
halt