Ocn_NMCx

#property indicator_separate_window
#property indicator_buffers 6
#property indicator_color1 Magenta
#property indicator_color2 Lime
#property indicator_color3 Silver
#property indicator_color4 Silver
#property indicator_color5 Yellow
#property indicator_color6 Aqua
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int    NMC_period          = 40;
extern bool   Show_ZH             = true;
extern double ZH_displacement     = 1;
extern int    ZH_symbol           = 115;
extern bool   Show_SD             = true;
extern int    SD_len              = 30;
extern double SD_up               = 2;
extern double SD_dn               = 2;
extern bool   Show_SD_1line_only  = true;
extern bool   Show_SD_2lines_up   = true;
extern bool   Show_SD_2lines_dn   = true;
extern int    NMA_period          = 40;
extern int    NMA_LB_min          = 8;
extern bool   Show_NMA            = true;
extern bool   Show_FastNMA        = true;

double NMC[];
double ZH[];
double SD[];
double SD2[];
double NMC_NMA[];
double NMC_FastNMA[];

int init()
{
  string nmcname = "NMC(" + NMC_period + ")";
  IndicatorShortName(nmcname);
  IndicatorBuffers(6);
  SetIndexBuffer(0, NMC);
  SetIndexLabel(0, nmcname);
  SetIndexBuffer(1, ZH);
  SetIndexLabel(1, "NMC_ZH");
  SetIndexStyle(1, DRAW_ARROW);
  SetIndexArrow(1, ZH_symbol);
  SetIndexBuffer(2, SD);
  SetIndexBuffer(3, SD2);
  if(Show_SD_1line_only)
    {
    SetIndexLabel(2, "NMC_SD(" + SD_len + ")");
    SetIndexLabel(3, "unused");
    }
  else
    {
    if(Show_SD_2lines_up) SetIndexLabel(2, "NMC_SD_up(" + SD_len + ")");
    else                  SetIndexLabel(2, "unused");
    if(Show_SD_2lines_dn) SetIndexLabel(3, "NMC_SD_dn(" + SD_len + ")");
    else                  SetIndexLabel(3, "unused");
    }
  SetIndexBuffer(4, NMC_NMA);
  SetIndexBuffer(5, NMC_FastNMA);
  if(Show_NMA) SetIndexLabel(4, "NMC_NMA(" + NMA_period + ")");
  else         SetIndexLabel(4, "unused");
  if(Show_FastNMA) SetIndexLabel(5, "NMC_FastNMA(" + NMA_period + ", " + NMA_LB_min + ")");
  else             SetIndexLabel(5, "unused");
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();
  double nmm, nmr, nmm2, nmr2, avg, sign, sum, abssum, ratio, nmcnum, maxnmc;

  if(Bars <= NMC_period) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMC_period) limit = Bars - counted_bars;
  else                          limit = Bars - NMC_period - 1;

  for(i = limit; i >= 0; i--)
    {
    nmm2 = 0; nmr2 = 0;
    for(ii = 1; ii <= NMC_period; ii++)
      {
      nmm2 += (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
      nmr2 += (MathLog(Close[i+ii-1]) - MathLog(Close[i+ii])) * (MathSqrt(ii) - MathSqrt(ii-1));
      }
    nmm = (nmm2 / NMC_period) * 1000;
    nmr = nmr2 * 1000;
    avg = ((MathAbs(nmm) * nmr) + (MathAbs(nmr) * nmm)) / 2;
    if(avg > 0)      sign = 1;
    else if(avg < 0) sign = -1;
    else             sign = 0;
    NMC[i] = sign * MathSqrt(MathAbs(avg));
    if(Show_ZH) { if(NMC[i] == 0) ZH[i] = ZH_displacement; else ZH[i] = EMPTY_VALUE; }
    }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMC_period - 1 - SD_len)
        {
        if(Show_SD_1line_only)
          {
          if(NMC[i] == 0)     SD[i] = 0;
          else if(NMC[i] > 0) SD[i] = iBandsOnArray(NMC, 0, SD_len, SD_up, 0, MODE_UPPER, i);
          else if(NMC[i] < 0) SD[i] = iBandsOnArray(NMC, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
          }
        else
          {
          if(NMC[i] == 0)
            {
            if(Show_SD_2lines_up) SD[i] = 0;
            if(Show_SD_2lines_dn) SD2[i] = 0;
            }
          else
            {
            if(Show_SD_2lines_up) SD[i] = iBandsOnArray(NMC, 0, SD_len, SD_up, 0, MODE_UPPER, i);
            if(Show_SD_2lines_dn) SD2[i] = iBandsOnArray(NMC, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
            }
          }
        }

  if(Show_NMA)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMC_period - 1 - NMA_period)
        {
        ratio = 0;
        sum = (NMC[i] - NMC[i+1]) + (NMC[i+1] - NMC[i+2]) * (MathSqrt(2)-1);
        for(ii = 2; ii < NMA_period; ii++)
          sum += (NMC[i+ii] - NMC[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
        abssum = MathAbs(sum);
        sum = 0;
        for(ii = 0; ii < NMA_period; ii++)
          sum += MathAbs(NMC[i+ii] - NMC[i+ii+1]);
        if(sum != 0) ratio = abssum / sum;
        NMC_NMA[i] = NMC_NMA[i+1] + (NMC[i] - NMC_NMA[i+1]) * ratio;
        }

  if(Show_FastNMA)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMC_period - 1 - NMA_period)
        {
        maxnmc = 0; ratio = 0;
        int NMA_LB_max;
        for(ii = 1; ii <= NMA_period; ii++)
          {
          nmcnum = (NMC[i] - NMC[i+ii]) / MathSqrt(ii);
          if(MathAbs(nmcnum) > maxnmc) { maxnmc = MathAbs(nmcnum); NMA_LB_max = ii; }
          }
        if(NMA_LB_max < NMA_LB_min) NMA_LB_max = NMA_LB_min;
        sum = (NMC[i] - NMC[i+1]) + (NMC[i+1] - NMC[i+2]) * (MathSqrt(2)-1);
        for(ii = 2; ii < NMA_LB_max; ii++)
          sum += (NMC[i+ii] - NMC[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
        abssum = MathAbs(sum);
        sum = 0;
        for(ii = 0; ii < NMA_LB_max; ii++)
          sum += MathAbs(NMC[i+ii] - NMC[i+ii+1]);
        if(sum != 0) ratio = abssum / sum;
        NMC_FastNMA[i] = NMC_FastNMA[i+1] + (NMC[i] - NMC_FastNMA[i+1]) * ratio;
        }

  return(0);
}