tk2d Lit Sprite Shader (example)

Shader "tk2d/BlendVertexColor (lit)"
{
    Properties
    {
        _MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
    }

    SubShader
    {
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        ZWrite Off Lighting Off Cull Off Fog { Mode Off } Blend SrcAlpha OneMinusSrcAlpha
        LOD 110

        Pass
        {
            CGPROGRAM
            #pragma vertex vert_vct
            #pragma fragment frag_mult
            #pragma fragmentoption ARB_precision_hint_fastest
            #include "UnityCG.cginc"

            sampler2D _MainTex;
            float4 _MainTex_ST;

            sampler2D LIGHT_TEX;

            struct vin_vct
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f_vct
            {
                float4 vertex : POSITION;
                fixed4 color : COLOR;
                float2 texcoord : TEXCOORD0;
                float2 lightCoord : TEXCOORD1;
            };

            v2f_vct vert_vct(vin_vct v)
            {
                v2f_vct o;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.lightCoord = 0.5 * (o.vertex.xy + float2(1.0, 1.0));
                o.color = v.color;
                o.texcoord = v.texcoord;
                return o;
            }

            float4 frag_mult(v2f_vct i) : COLOR
            {
                float4 col = tex2D(_MainTex, i.texcoord) * i.color;
                float4 light = tex2D(LIGHT_TEX, i.lightCoord);
                light.a = 1.0;
                return col * light;
            }

            ENDCG
        }
    }

    SubShader
    {
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        ZWrite Off Blend SrcAlpha OneMinusSrcAlpha Cull Off Fog { Mode Off }
        LOD 100

        BindChannels
        {
            Bind "Vertex", vertex
            Bind "TexCoord", texcoord
            Bind "Color", color
        }

        Pass
        {
            Lighting Off
            SetTexture [_MainTex] { combine texture * primary }
        }
    }
}