Botania Rune Crafting

//runes
val runeWater    = <Botania:rune>;
val runeFire     = <Botania:rune:1>;
val runeEarth    = <Botania:rune:2>;
val runeAir      = <Botania:rune:3>;
val runeSpring   = <Botania:rune:4>;
val runeSummer   = <Botania:rune:5>;
val runeAutumn   = <Botania:rune:6>;
val runeWinter   = <Botania:rune:7>;
val runeMana     = <Botania:rune:8>;
val runeLust     = <Botania:rune:9>;
val runeGluttony = <Botania:rune:10>;
val runeGreed    = <Botania:rune:11>;
val runeSloth    = <Botania:rune:12>;
val runeWrath    = <Botania:rune:13>;
val runeEnvy     = <Botania:rune:14>;
val runePride    = <Botania:rune:15>;

//Botania Resources

val manaSteel    = <Botania:manaResource>;
val manaPearl    = <Botania:manaResource:1>;
val manaDiamond  = <Botania:manaResource:2>;
val livingrock   = <Botania:livingrock>;





//Elements
recipes.addShaped(runeWater * 3,
	[[<minecraft:fishing_rod>, manaDiamond.giveBack(<minecraft:diamond>), manaSteel],
	[<minecraft:reeds>, null, manaSteel],
	[<minecraft:dye:15>, livingrock, manaSteel]]);


recipes.addShaped(runeFire * 3,
	[[<minecraft:nether_wart>, manaDiamond.giveBack(<minecraft:diamond>), manaSteel],
	[<minecraft:gunpowder>, null, manaSteel],
	[<minecraft:netherbrick>, livingrock, manaSteel]]);

recipes.addShaped(runeEarth * 3,
	[[<minecraft:brown_mushroom>, manaDiamond.giveBack(<minecraft:diamond>), manaSteel],
	[<minecraft:coal_block>, null, manaSteel],
	[<minecraft:stone>, livingrock, manaSteel]]);

recipes.addShaped(runeAir * 3,
	[[<minecraft:string>, manaDiamond.giveBack(<minecraft:diamond>), manaSteel],
	[<minecraft:feather>, null, manaSteel],
	[<minecraft:carpet:*>, livingrock, manaSteel]]);

//Seasons
recipes.addShaped(runeSpring * 3,
	[[<minecraft:sapling:*>, manaDiamond.giveBack(<minecraft:diamond>), <minecraft:wheat>],
	[<minecraft:sapling:*>, null, runeWater],
	[<minecraft:sapling:*>, livingrock, runeFire]]);

recipes.addShaped(runeSummer * 3,
	[[<minecraft:melon>, manaDiamond.giveBack(<minecraft:diamond>), <ore:slimeball>],
	[<ore:sand>, null, runeAir],
	[<ore:sand>, livingrock, runeEarth]]);

recipes.addShaped(runeAutumn * 3,
	[[<ore:treeLeaves>, manaDiamond.giveBack(<minecraft:diamond>), <minecraft:nether_wart>],
	[<ore:treeLeaves>, null, runeFire],
	[<ore:treeLeaves>, livingrock, runeAir]]);

recipes.addShaped(runeWinter * 3,
	[[<minecraft:cake>, manaDiamond.giveBack(<minecraft:diamond>), <minecraft:wheat>],
	[<minecraft:wool:*>, null, runeWater],
	[<minecraft:snow>, livingrock, runeEarth]]);


//Sins

recipes.addShaped(runeLust * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeAir, null, runeSummer]]);

recipes.addShaped(runeGluttony * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeFire, null, runeWinter]]);

recipes.addShaped(runeGreed * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeWater, null, runeSpring]]);

recipes.addShaped(runeSloth * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeAir, null, runeAutumn]]);

recipes.addShaped(runeWrath * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeEarth, null, runeWinter]]);

recipes.addShaped(runeEnvy * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeWater, null, runeWinter]]);

recipes.addShaped(runePride * 2,
	[[manaDiamond, manaDiamond.giveBack(<minecraft:diamond>), manaDiamond],
	[runeFire, null, runeSummer]]);

//Mana

recipes.addShaped(runeMana,
	[[ null, manaDiamond.giveBack(<minecraft:diamond>), null ],
	[manaSteel, manaPearl, manaSteel],
	[manaSteel, manaSteel, manaSteel]]);