Chase

X[t_] := Module[{\[Tau] = t - 4*Floor[t/4]},
   Piecewise[{{2 \[Tau] - 1, 0 <= \[Tau] < 1}, {1,
      1 <= \[Tau] < 2}, {1 - 2 (\[Tau] - 2), 2 <= \[Tau] < 3}, {-1,
      3 <= \[Tau] < 4}}]
   ];
Y[t_] := Module[{\[Tau] = t - 4*Floor[t/4]},
   Piecewise[{{1, 0 <= \[Tau] < 1}, {1 - 2 (\[Tau] - 1),
      1 <= \[Tau] < 2}, {-1, 2 <= \[Tau] < 3}, {2 (\[Tau] - 3) - 1,
      3 <= \[Tau] < 4}}]
   ];
Tmax = 12;
solnv[v_] :=
  NDSolve[{x'[t] ==
     2 v (X[t] - x[t])/
      Max[0.01, Sqrt[(X[t] - x[t])^2 + (Y[t] - y[t])^2]],
    y'[t] ==
     2 v (Y[t] - y[t])/
      Max[0.01, Sqrt[(X[t] - x[t])^2 + (Y[t] - y[t])^2]], x[0] == 0,
    y[0] == 0}, {x[t], y[t]}, {t, 0, Tmax}];
paths = Table[solnv[v], {v, 0.1, 1, 0.1}];
Manipulate[
 Show[Table[
   ParametricPlot[{{x[t], y[t]} /. paths[[i]] /. {t -> tt}}, {tt,
     Max[0, T - 3.5], T}, PlotRange -> 1.1,
    PlotStyle ->
     Directive[Thick, ColorData["RedBlueTones"][1 - i/Length@paths]],
    Axes -> None]
   ,
   {i, Length@paths}
   ],
  ParametricPlot[{X[tt], Y[tt]}, {tt, 0, T},
   PlotStyle -> Directive[Thick, Black]],
  Graphics[
   {
    Red,
    PointSize[Large],
    Disk[{X[T], Y[T]}, 0.06],
    Table[
     {ColorData["RedBlueTones"][1 - i/Length@paths],
      p = First[{x[t], y[t]} /. paths[[i]] /. {t -> T}];
      Point[p],
      Dotted,
      Lighter@ColorData["RedBlueTones"][1 - i/Length@paths],
      Line[{p, {X[T], Y[T]}}]
      }
     , {i, Length@paths}]
    }
   ]
  ]
 ,
 {T, 0.01, Tmax}]