Sprite HSV Tint

Shader "Sprites/SpriteHSV"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        _HSVTint ("HSV Tint", Vector) = (1,1,1,1)
        _IsNight ("Is Night",Float) = 0.0
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Blend One OneMinusSrcAlpha

        Pass
        {
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma shader_feature ETC1_EXTERNAL_ALPHA
            #include "UnityCG.cginc"

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                float2 texcoord  : TEXCOORD0;
            };

            fixed4 _HSVTint;
            float _IsNight;

            v2f vert(appdata_t IN)
            {
                v2f OUT;
                OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
                OUT.texcoord = IN.texcoord;
                OUT.color = IN.color;

                return OUT;
            }

            sampler2D _MainTex;

            fixed4 SampleSpriteTexture (float2 uv)
            {
                fixed4 color = tex2D (_MainTex, uv);

                return color;
            }

            float3 hsv2rgb(float3 c)
            {
                c.x/=360.0;
                c.y/=100.0;
                c.z/=100.0;
                float4 K = float4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
                float3 p = abs(frac(c.rrr + K.rgb) * 6.0 - K.www);
                return c.b * lerp(K.rrr, clamp(p - K.rrr, 0.0, 1.0), c.g);
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 c = SampleSpriteTexture (IN.texcoord);
                c.rgb *= c.a;

                if(_IsNight>0.5){
                    float f = dot(c.rgb,float3(0.3, 0.59, 0.11));
                    c.rgb = f*hsv2rgb(_HSVTint.rgb);
                    //c.rgb = float3(1.0,1.0,0.0)*float3(f,f,f);

                }

                return c;
            }
        ENDCG
        }
    }
}