API tools faq
paste
Advertisement
Guest User

Untitled

a guest
Jul 25th, 2014
269
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 18.09 KB | None | 0 0
raw download clone embed print report
  1. //===== rAthena Script =======================================
  2. //= All-in-One NPC
  3. //===== By: ==================================================
  4. //= Euphy
  5. //===== Current Version: =====================================
  6. //= 1.6
  7. //===== Description: =========================================
  8. //= A compilation of commonly-used NPC scripts.
  9. //== Includes job changer, stylist, refiner, card remover,
  10. //== coin exchanger, rentals, resetter, platinum skills,
  11. //== sex changer, identifier, healer, buffer, and repairman.
  12. //============================================================
  13.  
  14. maintown,121,72,6 script All-in-One NPC 953,{
  15. function Get_Platinum; function Equip_Menu;
  16.  
  17. if (getarraysize(.OnClick)) {
  18. if (.OnClick[0]) { specialeffect2 313; percentheal 100,100; }
  19. if (.OnClick[1]) { specialeffect2 42; sc_start SC_BLESSING,600000,10; specialeffect2 37; sc_start SC_INCREASEAGI,600000,10; }
  20. if (.OnClick[2] && getbrokenid(1)) { specialeffect2 101; atcommand "@repairall"; } }
  21. set .@menu$,"";
  22. for (set .@i,0; .@i < getarraysize(.MainMenu$); set .@i,.@i+1) {
  23. if (.MenuOption & pow(2,.@i))
  24. set .@menu$, .@menu$+" ~ "+.MainMenu$[.@i];
  25. set .@menu$, .@menu$+":"; }
  26. switch(select(.@menu$)) {
  27. case 1:
  28. function Job_Menu; function A_An;
  29. if (Class > 4049) {
  30. message strcharinfo(0),"No more jobs are available."; end; }
  31. if (checkfalcon() || checkcart() || checkriding() || ismounting()) {
  32. message strcharinfo(0),"Please remove your "+((checkfalcon())?"falcon":"")+((checkcart())?"cart":"")+((checkriding())?"Peco":"")+((ismounting())?"mount":"")+" before proceeding.";
  33. end; }
  34. if (.SkillPointCheck && SkillPoint) { message strcharinfo(0),"Please use all your skill points before proceeding."; end; }
  35. set .@eac, eaclass();
  36. set .@i, ((.ThirdClass)?roclass(.@eac&EAJ_UPPERMASK):Class);
  37. if (.@i > 6 && .@i < 22) {
  38. if (BaseLevel < .Rebirth[0] || JobLevel < .Rebirth[1]) {
  39. set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .Rebirth[1]-JobLevel;
  40. message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";
  41. end; }
  42. if (Class > 21) { Job_Menu(roclass(.@eac|EAJL_THIRD)); end; }
  43. while(1) {
  44. set .@i, select(" ~ ^0055FFRebirth^000000:"+((.ThirdClass)?" ~ ^FF0000Third Class^000000":"")+": ~ ^777777Cancel^000000");
  45. if (.@i==3) end;
  46. Job_Menu(((.@i==1)?4001:roclass(.@eac|EAJL_THIRD))); } }
  47. set .@j1, roclass(.@eac|EAJL_2_1); set .@j2,roclass(.@eac|EAJL_2_2);
  48. if ((.@eac&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE) setarray .@exp[0],roclass(.@eac|EAJL_THIRD),99;
  49. if (.@exp[0] && .ThirdClass) {
  50. if (BaseLevel < .Rebirth[0] || JobLevel < .@exp[1]) {
  51. set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .@exp[1]-JobLevel;
  52. message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";
  53. end; }
  54. Job_Menu(.@exp[0]); end; }
  55. if (.@eac&EAJL_2)
  56. if (.@eac&(EAJL_UPPER|EAJL_BABY) || roclass(.@eac|EAJL_UPPER) == -1) {
  57. message strcharinfo(0),"No more jobs are available."; end; }
  58. if ((.@eac&EAJ_BASEMASK) == EAJ_NOVICE) {
  59. if (JobLevel < .JobReq[0]) message strcharinfo(0),"A job level of "+.JobReq[0]+" is required to change into the 1st Class.";
  60. else if (Class == 4001 && .LastJob && lastJob) Job_Menu(roclass((eaclass(lastJob)&EAJ_BASEMASK)|EAJL_UPPER));
  61. else switch(Class) {
  62. case 0: Job_Menu(1,2,3,4,5,6,23,4046,24,25,4023);
  63. case 4001: Job_Menu(4002,4003,4004,4005,4006,4007);
  64. case 4023: Job_Menu(4024,4025,4026,4027,4028,4029,4045);
  65. default: message strcharinfo(0),"An error has occurred."; break; }
  66. end; }
  67. if (.@eac&EAJL_THIRD && Upper == 0) { // Non-trans third job
  68. if (BaseLevel < .Rebirth[0] || JobLevel < .Rebirth[1]) {
  69. set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .Rebirth[1]-JobLevel;
  70. mes "You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";
  71. end;
  72. }
  73. Job_Menu(4001);
  74. end;
  75. }
  76. if (roclass(.@eac|EAJL_2_1) == -1 || roclass(.@eac|EAJL_2_2) == -1) message strcharinfo(0),"No more jobs are available.";
  77. else if (!(.@eac&EAJL_2) && JobLevel < .JobReq[1]) message strcharinfo(0),"A job level of "+.JobReq[1]+" is required to change into the 2nd Class.";
  78. else if (.LastJob && lastJob && (.@eac&EAJL_UPPER)) Job_Menu(lastJob+4001);
  79. else Job_Menu(.@j1,.@j2);
  80. end;
  81. function Job_Menu {
  82. if (getargcount() > 1) {
  83. set .@menu$,"";
  84. for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
  85. set .@menu$, .@menu$+" ~ "+jobname(getarg(.@i))+":";
  86. set .@menu$, .@menu$+" ~ ^777777Cancel^000000"; }
  87. while(1) {
  88. if (getargcount() > 1) {
  89. set .@i, getarg(select(.@menu$)-1,0);
  90. if (!.@i) end; }
  91. else set .@i, getarg(0);
  92. if ((.@i == 23 || .@i == 4045) && BaseLevel < .SNovice) {
  93. message strcharinfo(0),"A base level of "+.SNovice+" is required to turn into a "+jobname(.@i)+"."; }
  94. else if (select(" ~ Change into ^0055FF"+jobname(.@i)+"^000000 class: ~ ^777777Go back^000000")==1) {
  95. message strcharinfo(0),"Became "+A_An(jobname(.@i))+"!";
  96. if (.@i==4001 && .LastJob) set lastJob, Class;
  97. jobchange .@i;
  98. if (.@i==4001 || .@i==4023) resetlvl(1);
  99. specialeffect2 338; specialeffect2 432;
  100. if (.Platinum) Get_Platinum;
  101. end; }
  102. if (getargcount() == 1) return;
  103. } end; }
  104. function Get_Platinum {
  105. skill 142,1,0;
  106. switch(BaseClass) {
  107. case 0: if (Class !=23) skill 143,1,0; break;
  108. case 1: skill 144,1,0; skill 145,1,0; skill 146,1,0; break;
  109. case 2: skill 157,1,0; break;
  110. case 3: skill 147,1,0; skill 148,1,0; break;
  111. case 4: skill 156,1,0; break;
  112. case 5: skill 153,1,0; skill 154,1,0; skill 155,1,0; break;
  113. case 6: skill 149,1,0; skill 150,1,0; skill 151,1,0; skill 152,1,0; break;
  114. default: break; }
  115. switch(roclass(eaclass()&EAJ_UPPERMASK)) {
  116. case 7: skill 1001,1,0; break;
  117. case 8: skill 1014,1,0; break;
  118. case 9: skill 1006,1,0; break;
  119. case 10: skill 1012,1,0; skill 1013,1,0; break;
  120. case 11: skill 1009,1,0; break;
  121. case 12: skill 1003,1,0; skill 1004,1,0; break;
  122. case 14: skill 1002,1,0; break;
  123. case 15: skill 1015,1,0; skill 1016,1,0; break;
  124. case 16: skill 1007,1,0; skill 1008,1,0; skill 1017,1,0; skill 1018,1,0; skill 1019,1,0; break;
  125. case 17: skill 1005,1,0; break;
  126. case 18: skill 238,1,0; break;
  127. case 19: skill 1010,1,0; break;
  128. case 20: skill 1011,1,0; break;
  129. default: break; }
  130. return; }
  131. function A_An {
  132. setarray .@A$[0],"a","e","i","o","u";
  133. set .@B$, "_"+getarg(0);
  134. for(set .@i,0; .@i<5; set .@i,.@i+1)
  135. if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
  136. return "a "+getarg(0); }
  137. case 2:
  138. setarray .@Look[1],7,1,6;
  139. set .@s, select(" ~ Cloth color: ~ Hairstyle: ~ Hair color");
  140. set .@Revert, getlook(.@Look[.@s]); set .@Style,1;
  141. while(1) {
  142. setlook .@Look[.@s], .@Style;
  143. message strcharinfo(0),"This is style #"+.@Style+".";
  144. set .@menu$, " ~ Next (^0055FF"+((.@Style!=.Styles[.@s])?.@Style+1:1)+"^000000): ~ Previous (^0055FF"+((.@Style!=1)?.@Style-1:.Styles[.@s])+"^000000): ~ Jump to...: ~ Revert to original (^0055FF"+.@Revert+"^000000)";
  145. switch(select(.@menu$)) {
  146. case 1: set .@Style, ((.@Style!=.Styles[.@s])?.@Style+1:1); break;
  147. case 2: set .@Style, ((.@Style!=1)?.@Style-1:.Styles[.@s]); break;
  148. case 3: message strcharinfo(0),"Choose a style between 1 - "+.Styles[.@s]+".";
  149. input .@Style,0,.Styles[.@s];
  150. if (!.@Style) set .@Style, rand(1,.Styles[.@s]);
  151. break;
  152. case 4: set .@Style, .@Revert; setlook .@Look[.@s], .@Revert; break; }
  153. } end;
  154. case 3:
  155. function Refine_Item;
  156. if (.EnrichedRefine)
  157. if (select(" ~ Normal Refiner: ~ Enriched Refiner")==2) {
  158. Equip_Menu(1);
  159. setarray .@Materials[0],7619,7620,7620,7620,7620;
  160. setarray .@Safe[0],4,7,6,5,4;
  161. set .@WLv, getequipweaponlv(@i);
  162. message strcharinfo(0),"Item: +"+getequiprefinerycnt(@i)+" "+getequipname(@i);
  163. if(select(" ~ Refine item (2 * ^0055FF"+getequippercentrefinery(@i)+"^000000% success): ~ ^777777Cancel^000000")==2) end;
  164. Refine_Item(1, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv], 1);
  165. end; }
  166. Equip_Menu(1);
  167. setarray .@Materials[0],985,1010,1011,984,984;
  168. setarray .@Safe[0],4,7,6,5,4;
  169. set .@WLv, getequipweaponlv(@i);
  170. set .@SafeCount, .@Safe[.@WLv]-getequiprefinerycnt(@i);
  171. message strcharinfo(0),"Item: +"+getequiprefinerycnt(@i)+" "+getequipname(@i);
  172. switch(select(" ~ Refine once (^0055FF"+getequippercentrefinery(@i)+"^000000% success): ~ Refine multiple times (up to "+(10-getequiprefinerycnt(@i))+"): ~ Refine to safe limit ("+((.@SafeCount>0)?.@SafeCount+" refines":"^777777disabled^000000")+"): ~ ^777777Cancel^000000")) {
  173. case 1: Refine_Item(1, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]); end;
  174. case 2:
  175. input .@Refines;
  176. if (.@Refines+getequiprefinerycnt(@i) > 10 || .@Refines < 1) message strcharinfo(0),"Invalid number ("+.@Refines+").";
  177. else Refine_Item(.@Refines, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]);
  178. end;
  179. case 3:
  180. if (.@SafeCount < 1) message strcharinfo(0),"The item has already reached the safe limit.";
  181. else Refine_Item(.@SafeCount, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]);
  182. end;
  183. case 4: end; }
  184. function Equip_Menu {
  185. setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";
  186. set .@menu$,"";
  187. for (set .@i,1; .@i <= 10; set .@i,.@i+1) {
  188. if (getequipisequiped(.@i))
  189. set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@i)+"^000000]";
  190. set .@menu$, .@menu$+":"; }
  191. set @i, select(.@menu$);
  192. if (!getequipisequiped(@i)) { message strcharinfo(0),"Nothing is equipped there!"; end; }
  193. if (getarg(0)) {
  194. if (!getequipisenableref(@i)) { message strcharinfo(0),getequipname(@i)+" cannot be refined."; end; }
  195. if (getequiprefinerycnt(@i) >= 10 ) { message strcharinfo(0),"+"+getequiprefinerycnt(@i)+" "+getequipname(@i)+" cannot be refined any further."; end; } }
  196. return; }
  197. function Refine_Item {
  198. message strcharinfo(0),"I'll need "+getarg(0)+"x "+getitemname(getarg(1))+" and "+getarg(0)*getarg(2)+" Zeny.";
  199. if (countitem(getarg(1)) < getarg(0) || Zeny < getarg(0)*getarg(2)) {
  200. sleep2 500; message strcharinfo(0),"Come back when you have the required materials."; end; }
  201. if (getequiprefinerycnt(@i)+getarg(0) > getarg(3)) {
  202. sleep2 500; message strcharinfo(0),"The item will be refined above the safe limit. It may break."; }
  203. sleep2 500;
  204. if(select(" ~ ^0055FFContinue^000000: ~ ^777777Cancel^000000")==2) end;
  205. set .@j, getarg(0);
  206. while(.@j) {
  207. delitem getarg(1), 1;
  208. set Zeny, Zeny-getarg(2);
  209. if (getarg(4,0)) {
  210. if (getequippercentrefinery(@i) <= rand(100) && getequippercentrefinery(@i) <= rand(100)) {
  211. message strcharinfo(0),getequipname(@i)+" broke while refining."; failedrefitem @i; end; } }
  212. else {
  213. if (getequippercentrefinery(@i) <= rand(100)) {
  214. message strcharinfo(0),getequipname(@i)+" broke while refining."; failedrefitem @i; end; } }
  215. successrefitem @i;
  216. set .@j, .@j-1; }
  217. message strcharinfo(0),"All done!";
  218. end; }
  219. case 4:
  220. if (.Prices[0]) message strcharinfo(0),"It costs "+.Prices[0]+" Zeny to remove cards.";
  221. Equip_Menu(0);
  222. if (Zeny < .Prices[0]) { message strcharinfo(0),"You don't have enough Zeny."; end; }
  223. set .@j,getequipcardcnt(@i);
  224. if (!.@j) { message strcharinfo(0),"There are no cards compounded to "+getequipname(@i)+"."; end; }
  225. if (!checkweight(4001,(.@j+1))) { message strcharinfo(0),"You're carrying too many items!"; end; }
  226. message strcharinfo(0),"Item: "+getequipname(@i);
  227. if (select(" ~ Remove "+.@j+" card(s): ~ ^777777Cancel^000000")==2) end;
  228. set Zeny, Zeny-.Prices[0];
  229. successremovecards @i;
  230. message strcharinfo(0),"Cards successfully removed!";
  231. end;
  232. case 5:
  233. message strcharinfo(0),"Coins are worth "+.Coin[1]+" Zeny each.";
  234. switch(select(" ~ Zeny to coins: ~ Coins to Zeny: ~ end")) {
  235. case 1:
  236. message strcharinfo(0),"How many coins do you want?";
  237. input .@coins,0,(1000000000/.Coin[1]);
  238. if (.@coins*.Coin[1] > Zeny) { message strcharinfo(0),"You don't have enough Zeny."; end; }
  239. if (!checkweight(.Coin[0],.@coins)) { message strcharinfo(0),"You don't have enough inventory space."; end; }
  240. set Zeny, Zeny-(.Coin[1]*.@coins);
  241. getitem .Coin[0], .@coins;
  242. message strcharinfo(0),"Purchased "+.@coins+" coins.";
  243. end;
  244. case 2:
  245. message strcharinfo(0),"How many coins do you want to trade in?";
  246. input .@coins,0,(1000000000/.Coin[1]);
  247. if (countitem(.Coin[0]) < .@coins) { message strcharinfo(0),"You don't have that many coins!"; end; }
  248. if ((Zeny+(.Coin[1]*.@coins)) > 1000000000) { message strcharinfo(0),"You have too much Zeny!"; end; }
  249. delitem .Coin[0], .@coins;
  250. set Zeny, Zeny+(.Coin[1]*.@coins);
  251. message strcharinfo(0),"Exchanged "+.@coins+" coins.";
  252. end;
  253. case 3:
  254. end; }
  255. case 6:
  256. if (Zeny < .Prices[2]) { message strcharinfo(0),"It costs "+.Prices[2]+" Zeny to rent."; end; }
  257. if (ismounting()) { message strcharinfo(0),"You must first remove your mount."; end; }
  258. else if ((eaclass()&EAJ_THIRDMASK==EAJ_RANGER) && !countitem(6124)) {
  259. if (!checkfalcon() && getskilllv(127) && !checkwug()) {
  260. if(select(" ~ Falcon: ~ Warg")==1) setfalcon;
  261. else getitem 6124,1; }
  262. else getitem 6124,1; }
  263. else if ((eaclass()&EAJ_THIRDMASK==EAJ_MECHANIC) && !checkcart() && getskilllv(39)) {
  264. if (!checkmadogear() && getskilllv(2255)) {
  265. if(select(" ~ Cart: ~ Mado")==1) setcart;
  266. else setmadogear; }
  267. else setcart; }
  268. else if (!checkcart() && getskilllv(39)) setcart;
  269. else if (!checkfalcon() && getskilllv(127) && !checkwug()) setfalcon;
  270. else if (!checkriding() && getskilllv(63)) {
  271. if (eaclass()&EAJ_THIRDMASK==EAJ_RUNE_KNIGHT) setdragon;
  272. else setriding; }
  273. else if (!checkmadogear() && getskilllv(2255)) setmadogear;
  274. else { message strcharinfo(0),"You do not meet requirements to rent."; end; }
  275. set Zeny, Zeny-.Prices[2];
  276. specialeffect2 276;
  277. end;
  278. case 7:
  279. if (.Prices[1]) message strcharinfo(0),"It costs "+.Prices[1]+" Zeny to reset stats or skills.";
  280. set .@i, select(" ~ Stat reset: ~ Skill reset: ~ Cancel");
  281. if (.@i==3) end;
  282. if (Zeny < .Prices[1]) { message strcharinfo(0),"You don't have enough Zeny."; end; }
  283. set Zeny, Zeny-.Prices[1];
  284. if (.@i==1) ResetStatus;
  285. else { sc_end SC_ALL; ResetSkill; }
  286. message strcharinfo(0),((.@i==1)?"Stats":"Skills")+" reset!";
  287. end;
  288. case 8:
  289. Get_Platinum;
  290. specialeffect2 441;
  291. message strcharinfo(0),"Platinum skills received!";
  292. end;
  293. case 9:
  294. set .@Var$, ".SexChange"+((Sex)?"F":"M");
  295. if (getarraysize(getd(.@Var$))) {
  296. message strcharinfo(0),"To turn into a "+((Sex)?"female":"male")+" you need the following items:";
  297. sleep2 1000;
  298. for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2) {
  299. message strcharinfo(0),getd(.@Var$+"["+(.@i+1)+"]")+"x "+getitemname(getd(.@Var$+"["+.@i+"]"));
  300. if (countitem(getd(.@Var$+"["+.@i+"]")) < getd(.@Var$+"["+(.@i+1)+"]")) set .@nreq,1;
  301. sleep2 500; }
  302. if (.@nreq) end; }
  303. if(select(" ~ Change into a "+((Sex)?"female":"male")+": ~ Cancel")==2) end;
  304. if (getarraysize(getd(.@Var$)))
  305. for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2)
  306. delitem getd(.@Var$+"["+.@i+"]"), getd(.@Var$+"["+(.@i+1)+"]");
  307. changesex;
  308. end;
  309. case 10:
  310. setarray .@Total[0],0,0;
  311. getinventorylist;
  312. for(set .@i,0; .@i<@inventorylist_count; set .@i,.@i+1) {
  313. if (@inventorylist_identify[.@i]) continue;
  314. if (Zeny < .Prices[3]) {
  315. dispbottom "It costs "+.Prices[3]+" to identify an item."; break; }
  316. set Zeny, Zeny-.Prices[3];
  317. delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;
  318. getitem @inventorylist_id[.@i],1;
  319. setarray .@Total[0], .@Total[0]+1, .@Total[1]+.Prices[3]; }
  320. if (!.@Total[0]) { message strcharinfo(0),"No items identified."; end; }
  321. specialeffect2 154;
  322. message strcharinfo(0),"Identified "+.@Total[0]+" items"+((.@Total[1])?" for "+.@Total[1]+" Zeny":"")+".";
  323. end;
  324. }
  325. OnInit:
  326.  
  327. // --------------------- Config ---------------------
  328. setarray .MainMenu$[0], // Set menu options!
  329. "Change Jobs", // [1]
  330. "Stylist", // [2]
  331. "Refiner", // [4]
  332. "Remove Cards", // [8]
  333. "Exchange Coins", // [16]
  334. "Rentals", // [32]
  335. "Reset Stats/Skills", // [64]
  336. "Platinum Skills", // [128]
  337. "Change Sex", // [256]
  338. "Identify All"; // [512]
  339.  
  340. set .MenuOption,1|2|4|8|32|64|128|256|512;
  341.  
  342. setarray .OnClick[0],1,1,1; // When clicked: heal [0], buff [1], repair [2] (1: yes / 0: no)
  343. setarray .Styles[1],553,37,250; // Maximum dye, hair style, and hair color
  344. setarray .Coin[0],671,7000000; // Coin item ID, coin price
  345. setarray .Prices[0],50000,10000,0,100; // Zeny to remove cards [0], reset [1], rent [2], identify [3]
  346.  
  347. setarray .Rebirth[0],99,50; // Minimum base level, job level to rebirth OR change to third class
  348. setarray .JobReq[0],10,40; // Minimum job level to turn into 1st class, 2nd class
  349. set .ThirdClass,1; // Enable third classes? (1: yes / 0: no)
  350. set .SNovice,45; // Minimum base level to turn into Super Novice
  351. set .LastJob,0; // Enforce linear class changes? (1: yes / 0: no)
  352. set .SkillPointCheck,1; // Force player to use up all skill points? (1: yes / 0: no)
  353. set .Platinum,1; // Get platinum skills automatically? (1: yes / 0: no)
  354.  
  355. set .EnrichedRefine,0; // Allow enriched refiner option? (1: yes / 0: no)
  356. setarray .RP[0],20000,50000,20000,50000,200000; // Zeny for armor, lv1, lv2, lv3, lv4 refines
  357.  
  358. setarray .SexChangeF[0],2213,1,1558,1,7152,50; // Items to turn into Female (ID,Count)
  359. setarray .SexChangeM[0],5016,1,2241,1,1017,50; // Items to turn into Male (ID,Count)
  360. waitingroom "Job Changer ++",0;
  361.  
  362. // --------------------------------------------------
  363. end;
  364. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!