[FS] Fraktions-Fahrzeug-System Beispielscript (Dini)

/*============================================================================================================================*
* Credits: Dieser Filterscript "Fraktions-Fahrzeug-System" wurde von Jeffry gemacht!                                          *
*                                                                                                                             *
*                                                                                                                             *
* Made in August 2015.                                                                                                        *
*                                                                                                                             *
* Rechte des Benutzers:                                                                                                       *
*                                                                                                                             *
* -Es ist erlaubt diesen Filterscript zu modifizieren, solange keine Credits entfernt werden.                                 *
* -Es ist erlaubt diesen Filterscript neu zu veröffentlichen, solange keine Credits entfernt werden.                          *
*                                                                                                                             *
* -Es ist nicht erlaubt dies als sein eigenes Werk darzustellen oder zu verkaufen.                                            *
* -Es ist nicht erlaubt Credits zu entfernen.                                                                                 *
*                                                                                                                             *
* Danke.                                                                                                                      *
* Viel Spaß.                                                                                                                  *
*                                                                                                                             *
*=============================================================================================================================*/
#include <a_samp>
#include <Dini>
#include <ocmd>

enum playerEnum {
        pFraction
};
new PlayerInfo[MAX_PLAYERS][playerEnum];

#define MAX_FRAC_VEHICLES 10
enum fracVehEnum {
    e_modelID,
    Float:e_x,
    Float:e_y,
    Float:e_z,
    Float:e_a,
    e_color1,
    e_color2,
    e_fracID,
    e_vID
};
new fracVehicle[MAX_FRAC_VEHICLES][fracVehEnum];

public OnFilterScriptInit()
{
    LoadFracVehicles();
    SetTimer("SaveAllFracVehs", 60000, true); //Timer wird alle 60 Sekunden ausgeführt
    return 1;
}

public OnFilterScriptExit()
{
    SaveAllFracVehs();
    //Schleife durch alle Fraktions-Fahrzeuge:
    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Wenn das Fahrzeug existiert
        if(fracVehicle[i][e_modelID] >= 400 && fracVehicle[i][e_modelID] <= 611)
        {
            DestroyVehicle(fracVehicle[i][e_vID]);
        }
    }
    return 1;
}

public OnPlayerExitVehicle(playerid, vehicleid)
{
    SaveFracVehCheck(vehicleid);
    return 1;
}

public OnPlayerEnterVehicle(playerid, vehicleid, ispassenger)
{
    //Eine Schleife durch alle Fraktions-Fahrzeuge
    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Wenn die vehicleid die gleiche ist, wie die des Fraktions-Fahrzeugs
        if(fracVehicle[i][e_vID] == vehicleid)
        {
            //Jetzt brauchen wir die Variable, mit der Dein vorher bereits existierendes Fraktions-System arbeitet.
            //Ich nehme jetzt einfach eine Beispiel-Variable, diese musst Du selbst mit der ersetzen,
            //die Dein System verwendet.
            //Es geht um diese Variable: PlayerInfo[playerid][pFraction]
            if(PlayerInfo[playerid][pFraction] != fracVehicle[i][e_fracID])
            {
                //Wenn der Spieler nicht in der Fraktion ist, die das Fahrzeug verwenden darf,
                //dann darf er es nicht betreten.
                TogglePlayerControllable(playerid, false);
                TogglePlayerControllable(playerid, true);
                SendClientMessage(playerid, 0xFF0000FF, "Du bist nicht in der Fraktion, die dieses Fahrzeug verwenden darf.");
            }
            break; //Es gibt ja keine zwei gleichen Fahrzeuge
        }
    }
    return 1;
}

LoadFracVehicles()
{
    //Deklaration neuer temporärer Variablen:
    new createdVehs, path[64];

    //Schleife durch alle Dateien:
    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Es wird geprüft, ob ein Fahrzeug mit der ID existiert, wenn nicht, wird diese ID übersprungen
        format(path, sizeof(path), "/fracVehicles/%d.ini", i);
        if(!fexist(path)) continue;

        //Fahrzeug existiert im fracVehicles-Ordner, wir laden die Daten jetzt aus der Datei.
        fracVehicle[i][e_modelID] = dini_Int(path, "modelID");
        fracVehicle[i][e_x] = floatstr(dini_Get(path, "x"));
        fracVehicle[i][e_y] = floatstr(dini_Get(path, "y"));
        fracVehicle[i][e_z] = floatstr(dini_Get(path, "z"));
        fracVehicle[i][e_a] = floatstr(dini_Get(path, "a"));
        fracVehicle[i][e_color1] = dini_Int(path, "color1");
        fracVehicle[i][e_color2] = dini_Int(path, "color2");
        fracVehicle[i][e_fracID] = dini_Int(path, "fracID");

        //Zur Sicherheit fragen wir hier nun ab, ob das angegebene Modell auch existiert,
        //sollte das nicht der Fall sein, dann wird das Fahrzeug nicht erstellt.
        if(fracVehicle[i][e_modelID] >= 400 && fracVehicle[i][e_modelID] <= 611)
        {
            //Nachdem das Fahrzeug geladen wurde, wird es erstellt.
            fracVehicle[i][e_vID] = CreateVehicle(fracVehicle[i][e_modelID], fracVehicle[i][e_x], fracVehicle[i][e_y], fracVehicle[i][e_z], fracVehicle[i][e_a], fracVehicle[i][e_color1], fracVehicle[i][e_color2], -1);
        }
        else
        {
            //Falls eine nicht existierende Model-ID angegeben wurde, geben wir eine Information aus.
            printf("[Error] Model-ID %d existiert nicht (ID: %d).", fracVehicle[i][e_modelID], i);
        }

        //Zur Sicherheit fragen wir noch ab, ob das Fahrzeug-Limit noch nicht überschritten wurde.
        //Existiert ein Fahrzeug mit der höchsten ID, dann kann kein weiteres mehr erstellt werden.
        if(GetVehicleModel(MAX_VEHICLES-1) != 0) return print("Es können keine weiteren Fahrzeuge geladen werden, Limit (MAX_VEHICLES) erreicht.");

        //Zur weiteren Sicherheit prüfen wir noch, ob die maximale Anzahl an Fraktions-Fahrzeugen erreicht ist.
        createdVehs++;
        if(createdVehs == MAX_FRAC_VEHICLES) return print("Es können keine weiteren Fahrzeuge geladen werden, Limit (MAX_FRAC_VEHICLES) erreicht.");
    }
    return 1;
}

stock SaveFracVehCheck(vehicleid)
{
    //Deklaration neuer temporärer Variablen:
    new path[64];

    //Schleife durch alle Fraktions-Fahrzeuge
    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Wenn die vehicleid die gleiche ist, wie die des Fraktions-Fahrzeugs
        if(fracVehicle[i][e_vID] == vehicleid)
        {
            //Es wird der Pfad gesetzt:
            format(path, sizeof(path), "/fracVehicles/%d.ini", i);

            //Wir fragen die Position des Fahrzeugs ab:
            GetVehiclePos(fracVehicle[i][e_vID], fracVehicle[i][e_x], fracVehicle[i][e_y], fracVehicle[i][e_z]);
            GetVehicleZAngle(fracVehicle[i][e_vID], fracVehicle[i][e_a]);

            //Und wir speichern die Daten:
            dini_IntSet(path, "modelID", fracVehicle[i][e_modelID]);
            dini_FloatSet(path, "x", fracVehicle[i][e_x]);
            dini_FloatSet(path, "y", fracVehicle[i][e_y]);
            dini_FloatSet(path, "z", fracVehicle[i][e_z]);
            dini_FloatSet(path, "a", fracVehicle[i][e_a]);
            dini_IntSet(path, "color1", fracVehicle[i][e_color1]);
            dini_IntSet(path, "color2", fracVehicle[i][e_color2]);
            dini_IntSet(path, "fracID", fracVehicle[i][e_fracID]);
            return 1; //Es gibt ja keine zwei gleichen Fahrzeuge
        }
    }
    return 0; //Fahrzeug ist kein Fraktions-Fahrzeug
}

forward SaveAllFracVehs();
public SaveAllFracVehs()
{
    //Deklaration neuer temporärer Variablen:
    new path[64];

    //Schleife durch alle Fraktions-Fahrzeuge:
    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Wenn das Fahrzeug existiert
        if(fracVehicle[i][e_modelID] >= 400 && fracVehicle[i][e_modelID] <= 611)
        {
            //Es wird der Pfad gesetzt:
            format(path, sizeof(path), "/fracVehicles/%d.ini", i);

            //Wir fragen die Position des Fahrzeugs ab:
            GetVehiclePos(fracVehicle[i][e_vID], fracVehicle[i][e_x], fracVehicle[i][e_y], fracVehicle[i][e_z]);
            GetVehicleZAngle(fracVehicle[i][e_vID], fracVehicle[i][e_a]);

            //Und wir speichern die Daten:
            dini_IntSet(path, "modelID", fracVehicle[i][e_modelID]);
            dini_FloatSet(path, "x", fracVehicle[i][e_x]);
            dini_FloatSet(path, "y", fracVehicle[i][e_y]);
            dini_FloatSet(path, "z", fracVehicle[i][e_z]);
            dini_FloatSet(path, "a", fracVehicle[i][e_a]);
            dini_IntSet(path, "color1", fracVehicle[i][e_color1]);
            dini_IntSet(path, "color2", fracVehicle[i][e_color2]);
            dini_IntSet(path, "fracID", fracVehicle[i][e_fracID]);
        }
    }
    return 1;
}

stock strtok2(const string[], &index) //©Jeffry
{
    new result[20], length = strlen(string), i = index;
    while ((i < length) && (string[i] == ' ')) i++;
    strmid(result,string,i,((index = strfind(string, " ", false, i)) == -1) ? (index = length) : (index) , 20);
    index++;
    return result;
}

stock IsNumeric(string[])
{
    for (new i = 0, j = strlen(string); i < j; i++)
    {
        if ((string[i] > '9' || string[i] < '0')) return 0;
    }
    return 1;
}

ocmd:fferstellen(playerid, params[])
{
    //Zuerst fragen wir ab, ob wir noch Fahrzeuge erstellen können
    if(GetVehicleModel(MAX_VEHICLES-1) != 0) return SendClientMessage(playerid, 0xFF0000FF, "Es können keine weiteren Fahrzeuge erstellt werden, Limit (MAX_VEHICLES) erreicht.");

    //Wir deklarieren die benötigten temporären Variablen.
    new tmp[20], idx, model, fID, color1 = -1, color2 = -1;

    //Anschließend teilen wir mit strtok2 die eingegebenen Paramater auf und wandeln sie in eine Zahl um.
    //Falls etwas falsches eingegeben wurde, geben wir eine entsprechende Meldung zurück.
    tmp = strtok2(params, idx);
    if(!strlen(tmp) || !IsNumeric(tmp)) return SendClientMessage(playerid, 0xFF0000FF, "Verwendung: /fferstellen [Model] [FraktionsID] [opt:Farbe1] [opt:Farbe2]");
    model = strval(tmp);
    //Eine solche Abfrage kann man auch für nachfolgende FraktionsID (fID) machen, falls gewünscht.
    if(model < 400 || model > 611) return SendClientMessage(playerid, 0xFF0000FF, "Error: Model ID existiert nicht.");
    tmp = strtok2(params, idx);
    if(!strlen(tmp) || !IsNumeric(tmp)) return SendClientMessage(playerid, 0xFF0000FF, "Verwendung: /fferstellen [Model] [FraktionsID] [opt:Farbe1] [opt:Farbe2]");
    fID = strval(tmp);
    tmp = strtok2(params, idx);
    if(strlen(tmp) && IsNumeric(tmp)) color1 = strval(tmp);
    tmp = strtok2(params, idx);
    if(strlen(tmp) && IsNumeric(tmp)) color2 = strval(tmp);

    //Sind alle Parameter korrekt übergeben worden, dann suchen wir uns einen freien Index in den wir das Fraktions-Fahrzeug speichern können.
    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Frei:
        if(fracVehicle[i][e_vID] == 0)
        {
            //Daten werden übergeben
            new Float:x, Float:y, Float:z, Float:a;
            GetPlayerPos(playerid, x, y, z);
            GetPlayerFacingAngle(playerid, a);
            fracVehicle[i][e_modelID] = model;
            fracVehicle[i][e_x] = x;
            fracVehicle[i][e_y] = y;
            fracVehicle[i][e_z] = z;
            fracVehicle[i][e_a] = a;
            fracVehicle[i][e_color1] = color1;
            fracVehicle[i][e_color2] = color2;
            fracVehicle[i][e_fracID] = fID;

            //und anschließend wird dann das Fahrzeug erstellt und der Spieler in das Fahrzeug gesetzt.
            fracVehicle[i][e_vID] = CreateVehicle(fracVehicle[i][e_modelID], fracVehicle[i][e_x], fracVehicle[i][e_y], fracVehicle[i][e_z], fracVehicle[i][e_a], fracVehicle[i][e_color1], fracVehicle[i][e_color2], -1);
            PutPlayerInVehicle(playerid, fracVehicle[i][e_vID], 0);

            //Zuletzt wird die Datei angelegt und das Fahrzeug gespeichert.
            new path[64];
            format(path, sizeof(path), "/fracVehicles/%d.ini", i);
            dini_Create(path);
            SaveFracVehCheck(fracVehicle[i][e_vID]);

            return SendClientMessage(playerid, 0x00FF00FF, "Fahrzeug gespeichert.");
        }
    }
    return SendClientMessage(playerid, 0xFF0000FF, "Error: Limit für Fraktions-Fahrzeuge erreicht.");
}

ocmd:ffloeschen(playerid, params[])
{
    //Wir deklarieren die benötigte temporäre Variable.
    new vid;

    //Wenn der Spieler keine Vehicle-ID eingibt wird die gelöscht, in der sich der Spieler befindet,
    //ansonsten die eingegebene ID.
    if(!IsNumeric(params) || !strlen(params)) return SendClientMessage(playerid, 0xFF0000FF, "Error: Nutze: /ffloeschen [Vehicle ID]");
    vid = strval(params);

    if(vid <= 0) return SendClientMessage(playerid, 0xFF0000FF, "Error: Vehicle-ID ist kein Fraktions-Fahrzeug.");

    for(new i=0; i<MAX_FRAC_VEHICLES; i++)
    {
        //Eingegebene ID und die des Fraktions-Fahrzeugs stimmen überein.
        if(fracVehicle[i][e_vID] == vid)
        {
            //Daten werden entfernt
            fracVehicle[i][e_modelID] = 0;
            fracVehicle[i][e_x] = 0.0;
            fracVehicle[i][e_y] = 0.0;
            fracVehicle[i][e_z] = 0.0;
            fracVehicle[i][e_a] = 0.0;
            fracVehicle[i][e_color1] = 0;
            fracVehicle[i][e_color2] = 0;
            fracVehicle[i][e_fracID] = -1;

            //und anschließend in der Datenbank gelöscht.
            new path[64];
            format(path, sizeof(path), "/fracVehicles/%d.ini", i);
            dini_Remove(path);

            DestroyVehicle(fracVehicle[i][e_vID]);
            fracVehicle[i][e_vID] = 0;
            return SendClientMessage(playerid, 0x00FF00FF, "Fahrzeug gelöscht.");
        }
    }
    return SendClientMessage(playerid, 0xFF0000FF, "Error: Vehicle-ID ist kein Fraktions-Fahrzeug.");
}

ocmd:parken(playerid)
{
    if(!IsPlayerInAnyVehicle(playerid)) return SendClientMessage(playerid, 0xFF0000FF, "Du bist in keinem Fahrzeug.");
    new vehicleid = GetPlayerVehicleID(playerid);
    if(SaveFracVehCheck(vehicleid)) return SendClientMessage(playerid, 0x00FF00FF, "Fahrzeug geparkt.");
    else return SendClientMessage(playerid, 0xFF0000FF, "Dieses Fahrzeug kann nicht geparkt werden.");
}