Actor ShieldTrooper 24001
{
	Health 110
	Radius 16
	Height 56
	Mass 100
	PainChance 190
	Speed 8
	Monster
	+FLOORCLIP
	+NOINFIGHTING
	+DONTHARMSPECIES
	DropItem "SubMachinegun"
	SeeSound "shieldtrooper/sight"
	PainSound "shieldtrooper/pain"
	DeathSound "shieldtrooper/death"
	Tag "Shield Trooper"
	Obituary "%o got shot down by a S.T.A.B Shield Trooper."
	States
	{
	Spawn:
		SREB AB 10 A_Look
		Loop
	See:
		TNT1 A 0 A_JumpIfCloser(128, "Guard")
		SREB AABB 3  A_Chase
		TNT1 A 0 A_JumpIfCloser(128, "Guard")
		SREB CCDD 3  A_Chase
		Loop
	Guard:
		SREB EE 4 A_FaceTarget
	Missile:
		TNT1 A 0 A_JumpIfInventory("GuardCheck", 1, "ShieldMissile")
		SREB E 3 A_FaceTarget
		TNT1 A 0 A_PlaySound("trooper/fire1")
		SREB F 3 Bright A_CustomBulletAttack(3.5, 3, 1, 2)
		SREB E 3 A_FaceTarget
		TNT1 A 0 A_PlaySound("trooper/fire1")
		SREB F 3 Bright A_CustomBulletAttack(3.5, 3, 1, 2)
		SREB E 3 A_FaceTarget
		TNT1 A 0 A_PlaySound("trooper/fire1")
		SREB F 3 Bright A_CustomBulletAttack(3.5, 3, 1, 2)
		SREB E 7 A_FaceTarget
		Goto See
	ShieldMissile:
		SREB G 0 A_SetInvulnerable
		SREB G 15 A_CentaurDefend
		SREB G 0 A_UnSetInvulnerable
		SREB E 10 A_FaceTarget
		TNT1 A 0 A_PlaySound("trooper/fire1")
		SREB F 3 Bright A_CustomBulletAttack(1.5, 1, 1, 2)
		TNT1 A 0 A_JumpIfCloser(160, "ShieldMissile")
		SREB E 3 A_FaceTarget
		SREB G 0 A_UnSetInvulnerable
		SREB G 15 A_CentaurDefend
		TNT1 A 0 A_TakeInventory("GuardCheck", 1)
		Goto See
	Pain:
		SREB G 3
		SREB E 3 A_Pain
		TNT1 A 0 A_GiveInventory("GuardCheck", 1)
		TNT1 A 0 A_Jump(80, "Shield")
		Goto See
	Shield:
		SREB G 0 A_SetInvulnerable
		SREB G 35 A_CentaurDefend
		SREB G 0 A_UnSetInvulnerable
		Goto See
	Death:
		SREB H 5
		TNT1 A 0 A_CustomMissile ("Shield", 32, -24, 25)
		SREB I 5 A_Scream
		SREB J 5 A_NoBlocking
		SREB KLMN 5
		SREB O -1
		Stop
	XDeath:
		SREB P 5
		SREB Q 0 A_NoBlocking
		SREB Q 5 A_XScream
		SREB R 5
		SREB STUV 5
		SREB W -1
		Stop
	}
}

ACTOR GuardCheck : Inventory
{
	Inventory.MaxAmount 1
}

ACTOR Shield
{
	Radius 10
	Height 8
	Speed 1
	Damage 0
	PROJECTILE
	-NOGRAVITY
	BounceType "Doom"
	Gravity 0.50
	States
	{
	Spawn:
	    RSLD A 1
		Loop
	Death:
		RSLD B 4
		RSLD C 4
		RSLD D -1
		Stop
  }
}