# Maintainer: Dennis Hamester <dennis [dot] hamester [at] gmail [dot] com>
# Contributor: J0k3r <moebius282 e4at gmail D0_T com>

pkgname=ftl
pkgver=1.03.3
pkgrel=3
pkgdesc="A spaceship simulation real-time roguelike-like (requires full copy of the game)"
url="http://www.ftlgame.com/"
license=('unknown')
# Copyright (c) 2012 by Subset Games. All rights reserved.  Unauthorized duplication of this game is prohibited.
arch=('i686' 'x86_64')
groups=("games")
depends=('sdl' 'libpng12' 'glu' 'libgl' 'gcc-libs' 'freetype2')
makedepends=('imagemagick')
_purgelibs=('libSDL-1.2.so.0' 'libfreetype.so.6' 'libpng12.so.0' 'libz.so.1' 'libstdc++.so.6')
_archivename="${pkgname^^}.Linux.${pkgver}.tar.gz"
source=("hib://${_archivename}"
        "$pkgname.desktop")
sha256sums=('a18983cac8cb0db8990d3b56c301d9983f0a8a5ad4850266922b7c5d538c178d'
            '5efa9679c437b119874927d3117d4859dbb02cc754890994aac3e9b4dc1465dd')
PKGEXT='.pkg.tar'



# You can download the Humble Indie Bundle file manually, or you can configure
# DLAGENTS in makepkg.conf to auto-download.
#
# For example, to use hib-dlagent to download files set something like this in
# your makepkg.conf (change/add -k and add -u/-p to your needs):
# DLAGENTS=('hib::/usr/bin/hib-dlagent -k 1a2b3c -o %o $(echo %u | cut -c 7-)')
#
# To auto-search through a directory containing Humble Bundle downloads, you
# could set:
# DLAGENTS=('hib::/usr/bin/find /path/to/downloads -name $(echo %u | cut -c 7-) -exec ln -s \{\} %o \; -quit')
DLAGENTS+=('hib::/usr/bin/echo "Could not find %u. Download manually to \"$(pwd)\" or setup hib:// DLAGENT in /etc/makepkg.conf."; exit 1')


package() {
  mkdir -p "${pkgdir}/opt/${pkgname}/"
  mv "${srcdir}/FTL/"* "${pkgdir}/opt/${pkgname}/"

  chmod 0644 "${pkgdir}/opt/${pkgname}/data/resources/"{data.dat,resource.dat}


  if [ "$CARCH" = "x86_64" ]; then

    rm -r "${pkgdir}/opt/${pkgname}/data/x86/"
    chmod 0755 "${pkgdir}/opt/${pkgname}/data/amd64/lib/"{libbass.so,libbassmix.so}
    for i in "${_purgelibs[@]}"; do
      rm "${pkgdir}/opt/${pkgname}/data/amd64/lib/${i}"
    done

  else

    rm -r "${pkgdir}/opt/${pkgname}/data/amd64/"
    chmod 0755 "${pkgdir}/opt/${pkgname}/data/x86/lib/"{libbass.so,libbassmix.so}
    for i in "${_purgelibs[@]}"; do
      rm "${pkgdir}/opt/${pkgname}/data/x86/lib/${i}"
    done

  fi

# fix for the included startup script

  sed -i -e 's|command="$(basename "$0")"|command="FTL"|' -e '6icd "$here"' "${pkgdir}/opt/${pkgname}/data/FTL"

# the spec only specifies png, svg and xpm..

  convert "${pkgdir}/opt/${pkgname}/data/exe_icon.bmp" "${pkgdir}/opt/${pkgname}/${pkgname}.png"

# huge amounts of errors in the console when we remove this ..
  # rm "${pkgdir}/opt/${pkgname}/data/exe_icon.bmp"

  install -Dm644 "${pkgdir}/opt/${pkgname}/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  install -Dm644 "${srcdir}/$pkgname.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"

  mkdir -p "${pkgdir}/usr/share/licenses/"
  ln -s "/opt/${pkgname}/data/licenses/" "${pkgdir}/usr/share/licenses/${pkgname}"

  mkdir -p  "${pkgdir}/usr/bin/"
  ln -s "/opt/${pkgname}/data/FTL" "${pkgdir}/usr/bin/${pkgname}"
}